matita/matita/contribs/lambdadelta/basic_2A/etc/lsubr/aaa_lpss.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lpss_ldrop.ma".
  16 include "basic_2/static/aaa_lift.ma".
  17
  18 (* ATONIC ARITY ASSIGNMENT ON TERMS *****************************************)
  19
  20 (* Properties about sn parallel substitution ********************************)
  21
  22 (* Note: lemma 500 *)
  23 lemma aaa_cpss_lpss_conf: ∀L1,T1,A. L1 ⊢ T1 ⁝ A → ∀T2. L1 ⊢ T1 ▶* T2 →
  24                           ∀L2. L1 ⊢ ▶* L2 → L2 ⊢ T2 ⁝ A.
  25 #L1 #T1 #A #H elim H -L1 -T1 -A
  26 [ #L1 #k #X #H
  27   >(cpss_inv_sort1 … H) -H //
  28 | #I #L1 #K1 #V1 #B #i #HLK1 #_ #IHV1 #X #H #L2 #HL12
  29   elim (cpss_inv_lref1 … H) -H
  30   [ #H destruct
  31     elim (lpss_ldrop_conf … HLK1 … HL12) -L1 #X #H #HLK2
  32     elim (lpss_inv_pair1 … H) -H #K2 #V2 #HK12 #HV12 #H destruct /3 width=6/
  33   | * #Y #Z #V2 #H #HV12 #HV2
  34     lapply (ldrop_mono … H … HLK1) -H #H destruct
  35     elim (lpss_ldrop_conf … HLK1 … HL12) -L1 #Z #H #HLK2
  36     elim (lpss_inv_pair1 … H) -H #K2 #V0 #HK12 #_ #H destruct
  37     lapply (ldrop_fwd_ldrop2 … HLK2) -V0 /3 width=7/
  38   ]
  39 | #a #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  40   elim (cpss_inv_bind1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct /4 width=2/
  41 | #a #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  42   elim (cpss_inv_bind1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct /4 width=1/
  43 | #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  44   elim (cpss_inv_flat1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct /3 width=3/
  45 | #L1 #V1 #T1 #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  46   elim (cpss_inv_flat1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct /3 width=1/
  47 ]
  48 qed-.
  49
  50 lemma aaa_cpss_conf: ∀L,T1,A. L ⊢ T1 ⁝ A → ∀T2. L ⊢ T1 ▶* T2 → L ⊢ T2 ⁝ A.
  51 /2 width=5 by aaa_cpss_lpss_conf/ qed-.
  52
  53 lemma aaa_lpss_conf: ∀L1,T,A. L1 ⊢ T ⁝ A → ∀L2. L1 ⊢ ▶* L2 → L2 ⊢ T ⁝ A.
  54 /2 width=5 by aaa_cpss_lpss_conf/ qed-.