matita/matita/contribs/lambdadelta/basic_2A/etc/lsubr/lpr_lpss.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lpx_sn_lpx_sn.ma".
  16 include "basic_2/substitution/fsupp.ma".
  17 include "basic_2/substitution/lpss_ldrop.ma".
  18 include "basic_2/reduction/lpr_ldrop.ma".
  19
  20 (* SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS *****************************)
  21
  22 (* Properties on context-sensitive parallel substitution for terms **********)
  23
  24 fact cpr_cpss_conf_lpr_lpss_atom_atom:
  25    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ▶* T & L2 ⊢ ⓪{I} ➡ T.
  26 /2 width=3/ qed-.
  27
  28 fact cpr_cpss_conf_lpr_lpss_atom_delta:
  29    ∀L0,i. (
  30       ∀L,T. ⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  31       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  32       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  33       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  34    ) →
  35    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  36    ∀V2. K0 ⊢ V0 ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  37    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  38    ∃∃T. L1 ⊢ #i ▶* T & L2 ⊢ T2 ➡ T.
  39 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  40 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  41 elim (lpr_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  42 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  43 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  44 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  45 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  46 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  47 elim (lift_total V 0 (i+1)) #T #HVT
  48 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  49 qed-.
  50
  51 fact cpr_cpss_conf_lpr_lpss_delta_atom:
  52    ∀L0,i. (
  53       ∀L,T.⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  54       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  55       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  56       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  57    ) →
  58    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  59    ∀V1. K0 ⊢ V0 ➡ V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  60    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  61    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ #i ➡ T.
  62 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1 #L1 #HL01 #L2 #HL02
  63 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  64 elim (lpss_inv_pair1 … H2) -H2 #K2 #V2 #HK02 #HV02 #H destruct
  65 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  66 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  67 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  68 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  69 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  70 elim (lift_total V 0 (i+1)) #T #HVT
  71 lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1 /3 width=9/
  72 qed-.
  73
  74 fact cpr_cpss_conf_lpr_lpss_delta_delta:
  75    ∀L0,i. (
  76       ∀L,T. ⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  77       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
  78       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
  79       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
  80    ) →
  81    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  82    ∀V1. K0 ⊢ V0 ➡ V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  83    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  84    ∀V2. KX ⊢ VX ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  85    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
  86    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ T2 ➡ T.
  87 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  88 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  89 lapply (ldrop_mono … H … HLK0) -H #H destruct
  90 elim (lpr_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  91 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  92 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  93 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  94 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  95 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  96 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  97 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  98 elim (lift_total V 0 (i+1)) #T #HVT
  99 lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
 100 lapply (cpr_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
 101 qed-.
 102
 103 fact cpr_cpss_conf_lpr_lpss_bind_bind:
 104    ∀a,I,L0,V0,T0. (
 105       ∀L,T. ⦃L0,ⓑ{a,I}V0.T0⦄ ⊃+ ⦃L, T⦄ →
 106       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 107       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 108       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 109    ) →
 110    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ➡ T1 →
 111    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ▶* T2 →
 112    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 113    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ▶* T & L2 ⊢ ⓑ{a,I}V2.T2 ➡ T.
 114 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 115 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 116 elim (IH … HV01 … HV02 … HL01 … HL02) //
 117 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
 118 qed-.
 119
 120 fact cpr_cpss_conf_lpr_lpss_bind_zeta:
 121    ∀L0,V0,T0. (
 122       ∀L,T. ⦃L0,+ⓓV0.T0⦄ ⊃+ ⦃L, T⦄ →
 123       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 124       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 125       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 126    ) →
 127    ∀T1. L0.ⓓV0 ⊢ T0 ➡ T1 → ∀X1. ⇧[O, 1] X1 ≡ T1 →
 128    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0.ⓓV0 ⊢ T0 ▶* T2 →
 129    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 130    ∃∃T. L1 ⊢ X1 ▶* T & L2 ⊢ +ⓓV2.T2 ➡ T.
 131 #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 132 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 133 elim (IH … HT01 … HT02 (L1.ⓓV2) … (L2.ⓓV2)) -IH -HT01 -HT02 // /2 width=1/ /3 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 134 elim (cpss_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=1/ /3 width=9/
 135 qed-.
 136
 137 fact cpr_cpss_conf_lpr_lpss_flat_flat:
 138    ∀I,L0,V0,T0. (
 139       ∀L,T. ⦃L0,ⓕ{I}V0.T0⦄ ⊃+ ⦃L, T⦄ →
 140       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 141       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 142       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 143    ) →
 144    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0 ⊢ T0 ➡ T1 →
 145    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ T0 ▶* T2 →
 146    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 147    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ▶* T & L2 ⊢ ⓕ{I}V2.T2 ➡ T.
 148 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 149 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 150 elim (IH … HV01 … HV02 … HL01 … HL02) //
 151 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 152 qed-.
 153
 154 fact cpr_cpss_conf_lpr_lpss_flat_tau:
 155    ∀L0,V0,T0. (
 156       ∀L,T. ⦃L0,ⓝV0.T0⦄ ⊃+ ⦃L, T⦄ →
 157       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 158       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 159       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 160    ) →
 161    ∀T1. L0 ⊢ T0 ➡ T1 → ∀V2,T2. L0 ⊢ T0 ▶* T2 →
 162    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 163    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ ⓝV2.T2 ➡ T.
 164 #L0 #V0 #T0 #IH #T1 #HT01
 165 #V2 #T2 #HT02 #L1 #HL01 #L2 #HL02
 166 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3/
 167 qed-.
 168
 169 fact cpr_cpss_conf_lpr_lpss_flat_beta:
 170    ∀a,L0,V0,W0,T0. (
 171       ∀L,T. ⦃L0,ⓐV0.ⓛ{a}W0.T0⦄ ⊃+ ⦃L, T⦄ →
 172       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 173       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 174       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 175    ) →
 176    ∀V1. L0 ⊢ V0 ➡ V1 → ∀T1. L0.ⓛW0 ⊢ T0 ➡ T1 →
 177    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ ⓛ{a}W0.T0 ▶* T2 →
 178    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 179    ∃∃T. L1 ⊢ ⓓ{a}V1.T1 ▶* T & L2 ⊢ ⓐV2.T2 ➡ T.
 180 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #T1 #HT01
 181 #V2 #HV02 #X #H #L1 #HL01 #L2 #HL02
 182 elim (cpss_inv_bind1 … H) -H #W2 #T2 #HW02 #HT02 #H destruct
 183 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 184 elim (IH … HT01 … HT02 (L1.ⓛW2) … (L2.ⓛW2)) /2 width=1/ /3 width=1/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 185 lapply (cpss_lsubr_trans … HT1 (L1.ⓓV1) ?) -HT1 /2 width=1/ /3 width=5/
 186 qed-.
 187
 188 fact cpr_cpss_conf_lpr_lpss_flat_theta:
 189    ∀a,L0,V0,W0,T0. (
 190       ∀L,T. ⦃L0,ⓐV0.ⓓ{a}W0.T0⦄ ⊃+ ⦃L, T⦄ →
 191       ∀T1. L ⊢ T ➡ T1 → ∀T2. L ⊢ T ▶* T2 →
 192       ∀L1. L ⊢ ➡ L1 → ∀L2. L ⊢ ▶* L2 →
 193       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ➡ T0
 194    ) →
 195    ∀V1. L0 ⊢ V0 ➡ V1 → ∀U1. ⇧[O, 1] V1 ≡ U1 →
 196    ∀W1. L0 ⊢ W0 ➡ W1 → ∀T1. L0.ⓓW0 ⊢ T0 ➡ T1 →
 197    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ ⓓ{a}W0.T0 ▶* T2 →
 198    ∀L1. L0 ⊢ ➡ L1 → ∀L2. L0 ⊢ ▶* L2 →
 199    ∃∃T. L1 ⊢ ⓓ{a}W1.ⓐU1.T1 ▶* T & L2 ⊢ ⓐV2.T2 ➡ T.
 200 #a #L0 #V0 #W0 #T0 #IH #V1 #HV01 #U1 #HVU1 #W1 #HW01 #T1 #HT01
 201 #V2 #HV02 #X #H #L1 #HL01 #L2 #HL02
 202 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1/ #V #HV1 #HV2
 203 elim (lift_total V 0 1) #U #HVU
 204 lapply (cpss_lift … HV1 (L1.ⓓW1) … HVU1 … HVU) -HVU1 /2 width=1/ #HU1
 205 elim (cpss_inv_bind1 … H) -H #W2 #T2 #HW02 #HT02 #H destruct
 206 elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1/
 207 elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1/ -L0 -V0 -W0 -T0
 208 /4 width=9 by ex2_intro, cpr_theta, cpss_bind, cpss_flat/ (**) (* auto too slow without trace *)
 209 qed-.
 210
 211 lemma cpr_cpss_conf_lpr_lpss: lpx_sn_confluent cpr cpss.
 212 #L0 #T0 @(fsupp_wf_ind … L0 T0) -L0 -T0 #L #T #IH #L0 * [|*]
 213 [ #I0 #HL #HT #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 214   elim (cpr_inv_atom1 … H1) -H1
 215   elim (cpss_inv_atom1 … H2) -H2
 216   [ #H2 #H1 destruct
 217     /2 width=1 by cpr_cpss_conf_lpr_lpss_atom_atom/
 218   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 219     /3 width=10 by cpr_cpss_conf_lpr_lpss_atom_delta/
 220   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 221     /3 width=10 by cpr_cpss_conf_lpr_lpss_delta_atom/
 222   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 223     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 224     /3 width=17 by cpr_cpss_conf_lpr_lpss_delta_delta/
 225   ]
 226 | #a #I #V0 #T0 #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 227   elim (cpss_inv_bind1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H2
 228   elim (cpr_inv_bind1 … H1) -H1 *
 229   [ #V1 #T1 #HV01 #HT01 #H1
 230   | #T1 #HT01 #HXT1 #H11 #H12
 231   ] destruct
 232   [ /3 width=10 by cpr_cpss_conf_lpr_lpss_bind_bind/
 233   | /3 width=11 by cpr_cpss_conf_lpr_lpss_bind_zeta/
 234   ]
 235 | #I #V0 #T0 #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 236   elim (cpss_inv_flat1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H2
 237   elim (cpr_inv_flat1 … H1) -H1 *
 238   [ #V1 #T1 #HV01 #HT01 #H1
 239   | #HX1 #H1
 240   | #a1 #V1 #Y1 #Z1 #T1 #HV01 #HZT1 #H11 #H12 #H13
 241   | #a1 #V1 #U1 #Y1 #W1 #Z1 #T1 #HV01 #HVU1 #HYW1 #HZT1 #H11 #H12 #H13
 242   ] destruct
 243   [ /3 width=10 by cpr_cpss_conf_lpr_lpss_flat_flat/
 244   | /3 width=8 by cpr_cpss_conf_lpr_lpss_flat_tau/
 245   | /3 width=11 by cpr_cpss_conf_lpr_lpss_flat_beta/
 246   | /3 width=14 by cpr_cpss_conf_lpr_lpss_flat_theta/
 247   ]
 248 ]
 249 qed-.
 250
 251 (* Basic_1: includes: pr0_subst1 *)
 252 (* Basic_1: was: pr2_subst1 *)
 253 lemma cpr_cpss_conf: ∀L. confluent2 … (cpr L) (cpss L).
 254 /2 width=6 by cpr_cpss_conf_lpr_lpss/ qed-.
 255
 256 lemma cpr_lpss_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ▶* L1 →
 257                         ∃∃T. L1 ⊢ T1 ▶* T & L1 ⊢ T0 ➡ T.
 258 #L0 #T0 #T1 #HT01 #L1 #HL01
 259 elim (cpr_cpss_conf_lpr_lpss … HT01 T0 … L1 … HL01) // /2 width=1/ -L0 /2 width=3/
 260 qed-.
 261
 262 lemma cpr_lpss_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➡ T1 → ∀L1. L0 ⊢ ▶* L1 →
 263                         ∃∃T. L0 ⊢ T1 ▶* T & L1 ⊢ T0 ➡ T.
 264 #L0 #T0 #T1 #HT01 #L1 #HL01
 265 elim (cpr_cpss_conf_lpr_lpss … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 266 qed-.
 267
 268 (* Basic_1: includes: pr0_subst1_fwd *)
 269 lemma lpr_cpss_conf: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ➡ L1 →
 270                      ∃∃T. L1 ⊢ T0 ▶* T & L0 ⊢ T1 ➡ T.
 271 #L0 #T0 #T1 #HT01 #L1 #HL01
 272 elim (cpr_cpss_conf_lpr_lpss ?? T0 … HT01 … HL01 L0) // -HT01 -HL01 /2 width=3/
 273 qed-.
 274
 275 (* Properties on sn parallel substitution on local environments *************)
 276
 277 lemma lpr_lpss_conf: confluent2 … lpr lpss.
 278 /3 width=6 by lpx_sn_conf, cpr_cpss_conf_lpr_lpss/
 279 qed-.