matita/matita/contribs/lambdadelta/basic_2A/etc/lsubr/lpss_lpss.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lpss_cpss.ma".
  16
  17 (* SN PARALLEL SUBSTITUTION ON LOCAL ENVIRONMENTS ***************************)
  18
  19 (* Main properties on context-sensitive parallel substitution for terms *****)
  20
  21 fact cpss_conf_lpss_atom_atom:
  22    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ▶* T & L2 ⊢ ⓪{I} ▶* T.
  23 /2 width=3/ qed-.
  24
  25 fact cpss_conf_lpss_atom_delta:
  26    ∀L0,i. (
  27       ∀L,T. ⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  28       ∀T1. L ⊢ T ▶* T1 → ∀T2. L ⊢ T ▶* T2 →
  29       ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
  30       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ▶* T0
  31    ) →
  32    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  33    ∀V2. K0 ⊢ V0 ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  34    ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
  35    ∃∃T. L1 ⊢ #i ▶* T & L2 ⊢ T2 ▶* T.
  36 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  37 elim (lpss_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  38 elim (lpss_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  39 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  40 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  41 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  42 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  43 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  44 elim (lift_total V 0 (i+1)) #T #HVT
  45 lapply (cpss_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  46 qed-.
  47
  48 fact cpss_conf_lpss_delta_delta:
  49    ∀L0,i. (
  50       ∀L,T. ⦃L0, #i⦄ ⊃+ ⦃L, T⦄ →
  51       ∀T1. L ⊢ T ▶* T1 → ∀T2. L ⊢ T ▶* T2 →
  52       ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
  53       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ▶* T0
  54    ) →
  55    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  56    ∀V1. K0 ⊢ V0 ▶* V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  57    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  58    ∀V2. KX ⊢ VX ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  59    ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
  60    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ T2 ▶* T.
  61 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  62 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  63 lapply (ldrop_mono … H … HLK0) -H #H destruct
  64 elim (lpss_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  65 elim (lpss_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  66 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  67 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  68 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  69 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  70 lapply (fsupp_lref … HLK0) -HLK0 #HLK0
  71 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  72 elim (lift_total V 0 (i+1)) #T #HVT
  73 lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  74 lapply (cpss_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  75 qed-.
  76
  77 fact cpss_conf_lpss_bind_bind:
  78    ∀a,I,L0,V0,T0. (
  79       ∀L,T. ⦃L0,ⓑ{a,I}V0.T0⦄ ⊃+ ⦃L,T⦄ →
  80       ∀T1. L ⊢ T ▶* T1 → ∀T2. L ⊢ T ▶* T2 →
  81       ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
  82       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ▶* T0
  83    ) →
  84    ∀V1. L0 ⊢ V0 ▶* V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ▶* T1 →
  85    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ▶* T2 →
  86    ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
  87    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ▶* T & L2 ⊢ ⓑ{a,I}V2.T2 ▶* T.
  88 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
  89 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
  90 elim (IH … HV01 … HV02 … HL01 … HL02) //
  91 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
  92 qed-.
  93
  94 fact cpss_conf_lpss_flat_flat:
  95    ∀I,L0,V0,T0. (
  96       ∀L,T. ⦃L0,ⓕ{I}V0.T0⦄ ⊃+ ⦃L,T⦄ →
  97       ∀T1. L ⊢ T ▶* T1 → ∀T2. L ⊢ T ▶* T2 →
  98       ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
  99       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ▶* T0
 100    ) →
 101    ∀V1. L0 ⊢ V0 ▶* V1 → ∀T1. L0 ⊢ T0 ▶* T1 →
 102    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ T0 ▶* T2 →
 103    ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
 104    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ▶* T & L2 ⊢ ⓕ{I}V2.T2 ▶* T.
 105 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 106 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 107 elim (IH … HV01 … HV02 … HL01 … HL02) //
 108 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 109 qed-.
 110
 111 theorem cpss_conf_lpss: lpx_sn_confluent cpss cpss.
 112 #L0 #T0 @(fsupp_wf_ind … L0 T0) -L0 -T0 #L #T #IH #L0 * [|*]
 113 [ #I0 #HL #HT #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 114   elim (cpss_inv_atom1 … H1) -H1
 115   elim (cpss_inv_atom1 … H2) -H2
 116   [ #H2 #H1 destruct
 117     /2 width=1 by cpss_conf_lpss_atom_atom/
 118   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 119     /3 width=10 by cpss_conf_lpss_atom_delta/
 120   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 121     /4 width=10 by ex2_commute, cpss_conf_lpss_atom_delta/
 122   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 123     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 124     /3 width=17 by cpss_conf_lpss_delta_delta/
 125   ]
 126 | #a #I #V0 #T0 #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 127   elim (cpss_inv_bind1 … H1) -H1 #V1 #T1 #HV01 #HT01 #H destruct
 128   elim (cpss_inv_bind1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H destruct
 129   /3 width=10 by cpss_conf_lpss_bind_bind/
 130 | #I #V0 #T0 #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 131   elim (cpss_inv_flat1 … H1) -H1 #V1 #T1 #HV01 #HT01 #H destruct
 132   elim (cpss_inv_flat1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H destruct
 133   /3 width=10 by cpss_conf_lpss_flat_flat/
 134 ]
 135 qed-.
 136
 137 (* Basic_1: was only: subst1_confluence_eq *)
 138 theorem cpss_conf: ∀L. confluent … (cpss L).
 139 /2 width=6 by cpss_conf_lpss/ qed-.
 140
 141 (* Properties on context-sensitive parallel substitution for terms **********)
 142
 143 (* Basic_1: was only: subst1_subst1_back *)
 144 lemma lpss_cpss_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ▶* L1 →
 145                          ∃∃T. L1 ⊢ T0 ▶* T & L1 ⊢ T1 ▶* T.
 146 #L0 #T0 #T1 #HT01 #L1 #HL01
 147 elim (cpss_conf_lpss … HT01 T0 … HL01 … HL01) // -L0 /2 width=3/
 148 qed-.
 149
 150 lemma lpss_cpss_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ▶* L1 →
 151                          ∃∃T. L1 ⊢ T0 ▶* T & L0 ⊢ T1 ▶* T.
 152 #L0 #T0 #T1 #HT01 #L1 #HL01
 153 elim (cpss_conf_lpss … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 154 qed-.
 155
 156 (* Main properties **********************************************************)
 157
 158 theorem lpss_conf: confluent … lpss.
 159 /3 width=6 by lpx_sn_conf, cpss_conf_lpss/
 160 qed-.
 161
 162 theorem lpss_trans: Transitive … lpss.
 163 /3 width=5 by lpx_sn_trans, cpss_trans_lpss/
 164 qed-.
 165
 166 (* Advanced forward lemmas **************************************************)
 167
 168 lemma cpss_fwd_shift1: ∀L1,L,T1,T. L ⊢ L1 @@ T1 ▶* T →
 169                        ∃∃L2,T2. L @@ L1 ⊢ ▶* L @@ L2 & L @@ L1 ⊢ T1 ▶* T2 &
 170                                 T = L2 @@ T2.
 171 #L1 @(lenv_ind_dx … L1) -L1
 172 [ #L #T1 #T #HT1
 173   @ex3_2_intro [3: // |4,5: // |1,2: skip ] (**) (* /2 width=4/ does not work *)
 174 | #I #L1 #V1 #IH #L #T1 #T >shift_append_assoc #H <append_assoc
 175   elim (cpss_inv_bind1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct
 176   elim (IH … HT12) -IH -HT12 #L2 #T #HL12 #HT1 #H destruct
 177   lapply (lpss_trans … HL12 (L.ⓑ{I}V2@@L2) ?) -HL12 /3 width=1/ #HL12
 178   @(ex3_2_intro … (⋆.ⓑ{I}V2@@L2)) [4: /2 width=3/ | skip ] <append_assoc // (**) (* explicit constructor *)
 179 ]
 180 qed-.