matita/matita/contribs/lambdadelta/basic_2A/etc/sta/lstas_alt.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/statictypestaralt_6.ma".
  16 include "basic_2/unfold/lstas_lift.ma".
  17
  18 (* NAT-ITERATED STATIC TYPE ASSIGNMENT FOR TERMS ****************************)
  19
  20 (* alternative definition of lstas *)
  21 inductive lstasa (h): genv → relation4 lenv nat term term ≝
  22 | lstasa_O   : ∀G,L,T. lstasa h G L 0 T T
  23 | lstasa_sort: ∀G,L,l,k. lstasa h G L l (⋆k) (⋆((next h)^l k))
  24 | lstasa_ldef: ∀G,L,K,V,W,U,i,l. ⇩[i] L ≡ K.ⓓV → lstasa h G K (l+1) V W →
  25                ⇧[0, i+1] W ≡ U → lstasa h G L (l+1) (#i) U
  26 | lstasa_ldec: ∀G,L,K,W,V,V0,U,i,l. ⇩[i] L ≡ K.ⓛW → ⦃G, K⦄ ⊢ W •[h] V0 →
  27                lstasa h G K l W V → ⇧[0, i+1] V ≡ U → lstasa h G L (l+1) (#i) U
  28 | lstasa_bind: ∀a,I,G,L,V,T,U,l. lstasa h G (L.ⓑ{I}V) l T U →
  29                lstasa h G L l (ⓑ{a,I}V.T) (ⓑ{a,I}V.U)
  30 | lstasa_appl: ∀G,L,V,T,U,l. lstasa h G L l T U → lstasa h G L l (ⓐV.T) (ⓐV.U)
  31 | lstasa_cast: ∀G,L,W,T,U,l. lstasa h G L (l+1) T U → lstasa h G L (l+1) (ⓝW.T) U
  32 .
  33
  34 interpretation "nat-iterated static type assignment (term) alternative"
  35    'StaticTypeStarAlt h G L l T U = (lstasa h G L l T U).
  36
  37 (* Base properties **********************************************************)
  38
  39 lemma sta_lstasa: ∀h,G,L,T,U. ⦃G, L⦄ ⊢ T •[h] U → ⦃G, L⦄ ⊢ T ••*[h, 1] U.
  40 #h #G #L #T #U #H elim H -G -L -T -U
  41 /2 width=8 by lstasa_O, lstasa_sort, lstasa_ldef, lstasa_ldec, lstasa_bind, lstasa_appl, lstasa_cast/
  42 qed.
  43
  44 lemma lstasa_step_dx: ∀h,G,L,T1,T,l. ⦃G, L⦄ ⊢ T1 ••*[h, l] T →
  45                       ∀T2. ⦃G, L⦄ ⊢ T •[h] T2 → ⦃G, L⦄ ⊢ T1 ••*[h, l+1] T2.
  46 #h #G #L #T1 #T #l #H elim H -G -L -T1 -T -l
  47 [ /2 width=1 by sta_lstasa/
  48 | #G #L #l #k #X #H >(sta_inv_sort1 … H) -X >commutative_plus //
  49 | #G #L #K #V #W #U #i #l #HLK #_ #HWU #IHVW #U2 #HU2
  50   lapply (drop_fwd_drop2 … HLK) #H
  51   elim (sta_inv_lift1 … HU2 … H … HWU) -H -U /3 width=6 by lstasa_ldef/
  52 | #G #L #K #W #V #V0 #U #i #l #HLK #HWl0 #_ #HVU #IHWV #U2 #HU2
  53   lapply (drop_fwd_drop2 … HLK) #H
  54   elim (sta_inv_lift1 … HU2 … H … HVU) -H -U /3 width=8 by lstasa_ldec/
  55 | #a #I #G #L #V #T1 #U1 #l #_ #IHTU1 #X #H
  56   elim (sta_inv_bind1 … H) -H #U #HU1 #H destruct /3 width=1 by lstasa_bind/
  57 | #G #L #V #T1 #U1 #l #_ #IHTU1 #X #H
  58   elim (sta_inv_appl1 … H) -H #U #HU1 #H destruct /3 width=1 by lstasa_appl/
  59 | /3 width=1 by lstasa_cast/
  60 ]
  61 qed.
  62
  63 (* Main properties **********************************************************)
  64
  65 theorem lstas_lstasa: ∀h,G,L,T,U,l. ⦃G, L⦄ ⊢ T •*[h, l] U → ⦃G, L⦄ ⊢ T ••*[h, l] U.
  66 #h #G #L #T #U #l #H @(lstas_ind_dx … H) -U -l /2 width=3 by lstasa_step_dx, lstasa_O/
  67 qed.
  68
  69 (* Main inversion lemmas ****************************************************)
  70
  71 theorem lstasa_inv_lstas: ∀h,G,L,T,U,l. ⦃G, L⦄ ⊢ T ••*[h, l] U → ⦃G, L⦄ ⊢ T •*[h, l] U.
  72 #h #G #L #T #U #l #H elim H -G -L -T -U -l
  73 /2 width=8 by lstas_inv_SO, lstas_ldec, lstas_ldef, lstas_cast, lstas_appl, lstas_bind/
  74 qed-.
  75
  76 (* Advanced eliminators *****************************************************)
  77
  78 lemma lstas_ind_alt: ∀h. ∀R:genv→relation4 lenv nat term term.
  79                      (∀G,L,T. R G L O T T) →
  80                      (∀G,L,l,k. R G L l (⋆k) (⋆((next h)^l k))) → (
  81                         ∀G,L,K,V,W,U,i,l.
  82                         ⇩[i] L ≡ K.ⓓV → ⦃G, K⦄ ⊢ V •*[h, l+1] W → ⇧[O, i+1] W ≡ U →
  83                         R G K (l+1) V W → R G L (l+1) (#i) U
  84                      ) → (
  85                         ∀G,L,K,W,V,V0,U,i,l.
  86                         ⇩[i] L ≡ K.ⓛW → ⦃G, K⦄ ⊢ W •[h] V0 →
  87                         ⦃G, K⦄ ⊢ W •*[h, l]V → ⇧[O, i+1] V ≡ U →
  88                         R G K l W V → R G L (l+1) (#i) U
  89                      ) → (
  90                         ∀a,I,G,L,V,T,U,l. ⦃G, L.ⓑ{I}V⦄ ⊢ T •*[h, l] U →
  91                         R G (L.ⓑ{I}V) l T U → R G L l (ⓑ{a,I}V.T) (ⓑ{a,I}V.U)
  92                      ) → (
  93                         ∀G,L,V,T,U,l. ⦃G, L⦄ ⊢ T •*[h, l] U →
  94                         R G L l T U → R G L l (ⓐV.T) (ⓐV.U)
  95                      ) → (
  96                         ∀G,L,W,T,U,l. ⦃G, L⦄⊢ T •*[h, l+1] U →
  97                         R G L (l+1) T U → R G L (l+1) (ⓝW.T) U
  98                      ) →
  99                      ∀G,L,l,T,U. ⦃G, L⦄ ⊢ T •*[h, l] U → R G L l T U.
 100 #h #R #IH1 #IH2 #IH3 #IH4 #IH5 #IH6 #IH7 #G #L #l #T #U #H
 101 elim (lstas_lstasa … H) /3 width=10 by lstasa_inv_lstas/
 102 qed-.