matita/matita/contribs/lambdadelta/basic_2A/examples/ex_fpbg_refl.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/computation/fpbg_fpbs.ma".
  16
  17 (* EXAMPLES *****************************************************************)
  18
  19 (* Reflexivity of proper qrst-computation: the term ApplOmega ***************)
  20
  21 definition ApplDelta: term → nat → term ≝ λW,k. +ⓛW.ⓐ⋆k.ⓐ#0.#0.
  22
  23 definition ApplOmega1: term → nat → term ≝ λW,k. ⓐ(ApplDelta W k).(ApplDelta W k).
  24
  25 definition ApplOmega2: term → nat → term ≝ λW,k. +ⓓⓝW.(ApplDelta W k).ⓐ⋆k.ⓐ#0.#0.
  26
  27 definition ApplOmega3: term → nat → term ≝ λW,k. ⓐ⋆k.(ApplOmega1 W k).
  28
  29 (* Basic properties *********************************************************)
  30
  31 lemma ApplDelta_lift: ∀W1,W2,k,l,m. ⬆[l, m] W1 ≡ W2 →
  32                       ⬆[l, m] (ApplDelta W1 k) ≡ (ApplDelta W2 k).
  33 /5 width=1 by lift_flat, lift_bind, lift_lref_lt/ qed.
  34
  35 lemma cpr_ApplOmega_12: ∀G,L,W,k. ⦃G, L⦄ ⊢ ApplOmega1 W k ➡ ApplOmega2 W k.
  36 /2 width=1 by cpr_beta/ qed.
  37
  38 lemma cpr_ApplOmega_23: ∀G,L,W,k. ⦃G, L⦄ ⊢ ApplOmega2 W k ➡ ApplOmega3 W k.
  39 #G #L #W1 #k elim (lift_total W1 0 1) #W2 #HW12
  40 @(cpr_zeta … (ApplOmega3 W2 k)) /4 width=1 by ApplDelta_lift, lift_flat/
  41 @cpr_flat // @cpr_flat @(cpr_delta … (ApplDelta W1 k) ? 0)
  42 [3,5,8,10: /2 width=2 by ApplDelta_lift/ |4,9: /2 width=1 by cpr_eps/ |*: skip ]
  43 qed.
  44
  45 lemma cpxs_ApplOmega_13: ∀h,g,G,L,W,k. ⦃G, L⦄ ⊢ ApplOmega1 W k ➡*[h,g] ApplOmega3 W k.
  46 /4 width=3 by cpxs_strap1, cpr_cpx/ qed.
  47
  48 lemma fqup_ApplOmega_13: ∀G,L,W,k. ⦃G, L, ApplOmega3 W k⦄ ⊐+ ⦃G, L, ApplOmega1 W k⦄.
  49 /2 width=1 by/ qed.
  50
  51 (* Main properties **********************************************************)
  52
  53 theorem fpbg_refl: ∀h,g,G,L,W,k. ⦃G, L, ApplOmega1 W k⦄ >≡[h,g] ⦃G, L, ApplOmega1 W k⦄.
  54 /3 width=5 by fpbs_fpbg_trans, fqup_fpbg, cpxs_fpbs/ qed.