matita/matita/contribs/lambdadelta/basic_2A/grammar/lenv_append.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2A/notation/functions/append_2.ma".
  16 include "basic_2A/notation/functions/snbind2_3.ma".
  17 include "basic_2A/notation/functions/snabbr_2.ma".
  18 include "basic_2A/notation/functions/snabst_2.ma".
  19 include "basic_2A/grammar/lenv_length.ma".
  20
  21 (* LOCAL ENVIRONMENTS *******************************************************)
  22
  23 let rec append L K on K ≝ match K with
  24 [ LAtom       ⇒ L
  25 | LPair K I V ⇒ (append L K). ⓑ{I} V
  26 ].
  27
  28 interpretation "append (local environment)" 'Append L1 L2 = (append L1 L2).
  29
  30 interpretation "local environment tail binding construction (binary)"
  31    'SnBind2 I T L = (append (LPair LAtom I T) L).
  32
  33 interpretation "tail abbreviation (local environment)"
  34    'SnAbbr T L = (append (LPair LAtom Abbr T) L).
  35
  36 interpretation "tail abstraction (local environment)"
  37    'SnAbst L T = (append (LPair LAtom Abst T) L).
  38
  39 definition d_appendable_sn: predicate (lenv→relation term) ≝ λR.
  40                             ∀K,T1,T2. R K T1 T2 → ∀L. R (L @@ K) T1 T2.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma append_atom_sn: ∀L. ⋆ @@ L = L.
  45 #L elim L -L normalize //
  46 qed.
  47
  48 lemma append_assoc: associative … append.
  49 #L1 #L2 #L3 elim L3 -L3 normalize //
  50 qed.
  51
  52 lemma append_length: ∀L1,L2. |L1 @@ L2| = |L1| + |L2|.
  53 #L1 #L2 elim L2 -L2 normalize //
  54 qed.
  55
  56 lemma ltail_length: ∀I,L,V. |ⓑ{I}V.L| = |L| + 1.
  57 #I #L #V >append_length //
  58 qed.
  59
  60 (* Basic_1: was just: chead_ctail *)
  61 lemma lpair_ltail: ∀L,I,V. ∃∃J,K,W. L.ⓑ{I}V = ⓑ{J}W.K & |L| = |K|.
  62 #L elim L -L /2 width=5 by ex2_3_intro/
  63 #L #Z #X #IHL #I #V elim (IHL Z X) -IHL
  64 #J #K #W #H #_ >H -H >ltail_length
  65 @(ex2_3_intro … J (K.ⓑ{I}V) W) //
  66 qed-.
  67
  68 (* Basic inversion lemmas ***************************************************)
  69
  70 lemma append_inj_sn: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |K1| = |K2| →
  71                      L1 = L2 ∧ K1 = K2.
  72 #K1 elim K1 -K1
  73 [ * normalize /2 width=1 by conj/
  74   #K2 #I2 #V2 #L1 #L2 #_ <plus_n_Sm #H destruct
  75 | #K1 #I1 #V1 #IH * normalize
  76   [ #L1 #L2 #_ <plus_n_Sm #H destruct
  77   | #K2 #I2 #V2 #L1 #L2 #H1 #H2
  78     elim (destruct_lpair_lpair_aux … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  79     elim (IH … H1) -IH -H1 /2 width=1 by conj/
  80   ]
  81 ]
  82 qed-.
  83
  84 (* Note: lemma 750 *)
  85 lemma append_inj_dx: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |L1| = |L2| →
  86                      L1 = L2 ∧ K1 = K2.
  87 #K1 elim K1 -K1
  88 [ * normalize /2 width=1 by conj/
  89   #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct
  90   normalize in H2; >append_length in H2; #H
  91   elim (plus_xySz_x_false … H)
  92 | #K1 #I1 #V1 #IH * normalize
  93   [ #L1 #L2 #H1 #H2 destruct
  94     normalize in H2; >append_length in H2; #H
  95     elim (plus_xySz_x_false … (sym_eq … H))
  96   | #K2 #I2 #V2 #L1 #L2 #H1 #H2
  97     elim (destruct_lpair_lpair_aux … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  98     elim (IH … H1) -IH -H1 /2 width=1 by conj/
  99   ]
 100 ]
 101 qed-.
 102
 103 lemma append_inv_refl_dx: ∀L,K. L @@ K = L → K = ⋆.
 104 #L #K #H elim (append_inj_dx … (⋆) … H) //
 105 qed-.
 106
 107 lemma append_inv_pair_dx: ∀I,L,K,V. L @@ K = L.ⓑ{I}V → K = ⋆.ⓑ{I}V.
 108 #I #L #K #V #H elim (append_inj_dx … (⋆.ⓑ{I}V) … H) //
 109 qed-.
 110
 111 lemma length_inv_pos_dx_ltail: ∀L,l. |L| = l + 1 →
 112                                ∃∃I,K,V. |K| = l & L = ⓑ{I}V.K.
 113 #Y #l #H elim (length_inv_pos_dx … H) -H #I #L #V #Hl #HLK destruct
 114 elim (lpair_ltail L I V) /2 width=5 by ex2_3_intro/
 115 qed-.
 116
 117 lemma length_inv_pos_sn_ltail: ∀L,l. l + 1 = |L| →
 118                                ∃∃I,K,V. l = |K| & L = ⓑ{I}V.K.
 119 #Y #l #H elim (length_inv_pos_sn … H) -H #I #L #V #Hl #HLK destruct
 120 elim (lpair_ltail L I V) /2 width=5 by ex2_3_intro/
 121 qed-.
 122
 123 (* Basic eliminators ********************************************************)
 124
 125 (* Basic_1: was: c_tail_ind *)
 126 lemma lenv_ind_alt: ∀R:predicate lenv.
 127                     R (⋆) → (∀I,L,T. R L → R (ⓑ{I}T.L)) →
 128                     ∀L. R L.
 129 #R #IH1 #IH2 #L @(f_ind … length … L) -L #x #IHx * // -IH1
 130 #L #I #V normalize #H destruct elim (lpair_ltail L I V) /3 width=1 by/
 131 qed-.