matita/matita/contribs/lambdadelta/basic_2A/grammar/lenv_append.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/notation/functions/append_2.ma".
  16 include "basic_2A/notation/functions/snbind2_3.ma".
  17 include "basic_2A/notation/functions/snabbr_2.ma".
  18 include "basic_2A/notation/functions/snabst_2.ma".
  19 include "basic_2A/grammar/lenv_length.ma".
  20
  21 (* LOCAL ENVIRONMENTS *******************************************************)
  22
  23 let rec append L K on K ≝ match K with
  24 [ LAtom       ⇒ L
  25 | LPair K I V ⇒ (append L K). ⓑ{I} V
  26 ].
  27
  28 interpretation "append (local environment)" 'Append L1 L2 = (append L1 L2).
  29
  30 interpretation "local environment tail binding construction (binary)"
  31    'SnBind2 I T L = (append (LPair LAtom I T) L).
  32
  33 interpretation "tail abbreviation (local environment)"
  34    'SnAbbr T L = (append (LPair LAtom Abbr T) L).
  35
  36 interpretation "tail abstraction (local environment)"
  37    'SnAbst L T = (append (LPair LAtom Abst T) L).
  38
  39 definition d_appendable_sn: predicate (lenv→relation term) ≝ λR.
  40                             ∀K,T1,T2. R K T1 T2 → ∀L. R (L @@ K) T1 T2.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma append_atom_sn: ∀L. ⋆ @@ L = L.
  45 #L elim L -L normalize //
  46 qed.
  47
  48 lemma append_assoc: associative … append.
  49 #L1 #L2 #L3 elim L3 -L3 normalize //
  50 qed.
  51
  52 lemma append_length: ∀L1,L2. |L1 @@ L2| = |L1| + |L2|.
  53 #L1 #L2 elim L2 -L2 normalize //
  54 qed.
  55
  56 lemma ltail_length: ∀I,L,V. |ⓑ{I}V.L| = |L| + 1.
  57 #I #L #V >append_length //
  58 qed.
  59
  60 lemma lpair_ltail: ∀L,I,V. ∃∃J,K,W. L.ⓑ{I}V = ⓑ{J}W.K & |L| = |K|.
  61 #L elim L -L /2 width=5 by ex2_3_intro/
  62 #L #Z #X #IHL #I #V elim (IHL Z X) -IHL
  63 #J #K #W #H #_ >H -H >ltail_length
  64 @(ex2_3_intro … J (K.ⓑ{I}V) W) //
  65 qed-.
  66
  67 (* Basic inversion lemmas ***************************************************)
  68
  69 lemma append_inj_sn: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |K1| = |K2| →
  70                      L1 = L2 ∧ K1 = K2.
  71 #K1 elim K1 -K1
  72 [ * normalize /2 width=1 by conj/
  73   #K2 #I2 #V2 #L1 #L2 #_ <plus_n_Sm #H destruct
  74 | #K1 #I1 #V1 #IH * normalize
  75   [ #L1 #L2 #_ <plus_n_Sm #H destruct
  76   | #K2 #I2 #V2 #L1 #L2 #H1 #H2
  77     elim (destruct_lpair_lpair_aux … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  78     elim (IH … H1) -IH -H1 /2 width=1 by conj/
  79   ]
  80 ]
  81 qed-.
  82
  83 (* Note: lemma 750 *)
  84 lemma append_inj_dx: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |L1| = |L2| →
  85                      L1 = L2 ∧ K1 = K2.
  86 #K1 elim K1 -K1
  87 [ * normalize /2 width=1 by conj/
  88   #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct
  89   normalize in H2; >append_length in H2; #H
  90   elim (plus_xySz_x_false … H)
  91 | #K1 #I1 #V1 #IH * normalize
  92   [ #L1 #L2 #H1 #H2 destruct
  93     normalize in H2; >append_length in H2; #H
  94     elim (plus_xySz_x_false … (sym_eq … H))
  95   | #K2 #I2 #V2 #L1 #L2 #H1 #H2
  96     elim (destruct_lpair_lpair_aux … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  97     elim (IH … H1) -IH -H1 /2 width=1 by conj/
  98   ]
  99 ]
 100 qed-.
 101
 102 lemma append_inv_refl_dx: ∀L,K. L @@ K = L → K = ⋆.
 103 #L #K #H elim (append_inj_dx … (⋆) … H) //
 104 qed-.
 105
 106 lemma append_inv_pair_dx: ∀I,L,K,V. L @@ K = L.ⓑ{I}V → K = ⋆.ⓑ{I}V.
 107 #I #L #K #V #H elim (append_inj_dx … (⋆.ⓑ{I}V) … H) //
 108 qed-.
 109
 110 lemma length_inv_pos_dx_ltail: ∀L,l. |L| = l + 1 →
 111                                ∃∃I,K,V. |K| = l & L = ⓑ{I}V.K.
 112 #Y #l #H elim (length_inv_pos_dx … H) -H #I #L #V #Hl #HLK destruct
 113 elim (lpair_ltail L I V) /2 width=5 by ex2_3_intro/
 114 qed-.
 115
 116 lemma length_inv_pos_sn_ltail: ∀L,l. l + 1 = |L| →
 117                                ∃∃I,K,V. l = |K| & L = ⓑ{I}V.K.
 118 #Y #l #H elim (length_inv_pos_sn … H) -H #I #L #V #Hl #HLK destruct
 119 elim (lpair_ltail L I V) /2 width=5 by ex2_3_intro/
 120 qed-.
 121
 122 (* Basic eliminators ********************************************************)
 123
 124 lemma lenv_ind_alt: ∀R:predicate lenv.
 125                     R (⋆) → (∀I,L,T. R L → R (ⓑ{I}T.L)) →
 126                     ∀L. R L.
 127 #R #IH1 #IH2 #L @(f_ind … length … L) -L #x #IHx * // -IH1
 128 #L #I #V normalize #H destruct elim (lpair_ltail L I V) /3 width=1 by/
 129 qed-.