matita/matita/contribs/lambdadelta/basic_2A/grammar/lreq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2A/ynat/ynat_lt.ma".
  16 include "basic_2A/notation/relations/midiso_4.ma".
  17 include "basic_2A/grammar/lenv_length.ma".
  18
  19 (* EQUIVALENCE FOR LOCAL ENVIRONMENTS ***************************************)
  20
  21 inductive lreq: relation4 ynat ynat lenv lenv ≝
  22 | lreq_atom: ∀l,m. lreq l m (⋆) (⋆)
  23 | lreq_zero: ∀I1,I2,L1,L2,V1,V2.
  24              lreq 0 0 L1 L2 → lreq 0 0 (L1.ⓑ{I1}V1) (L2.ⓑ{I2}V2)
  25 | lreq_pair: ∀I,L1,L2,V,m. lreq 0 m L1 L2 →
  26              lreq 0 (⫯m) (L1.ⓑ{I}V) (L2.ⓑ{I}V)
  27 | lreq_succ: ∀I1,I2,L1,L2,V1,V2,l,m.
  28              lreq l m L1 L2 → lreq (⫯l) m (L1.ⓑ{I1}V1) (L2.ⓑ{I2}V2)
  29 .
  30
  31 interpretation
  32   "equivalence (local environment)"
  33   'MidIso l m L1 L2 = (lreq l m L1 L2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma lreq_pair_lt: ∀I,L1,L2,V,m. L1 ⩬[0, ⫰m] L2 → 0 < m →
  38                     L1.ⓑ{I}V ⩬[0, m] L2.ⓑ{I}V.
  39 #I #L1 #L2 #V #m #HL12 #Hm <(ylt_inv_O1 … Hm) /2 width=1 by lreq_pair/
  40 qed.
  41
  42 lemma lreq_succ_lt: ∀I1,I2,L1,L2,V1,V2,l,m. L1 ⩬[⫰l, m] L2 → 0 < l →
  43                     L1.ⓑ{I1}V1 ⩬[l, m] L2. ⓑ{I2}V2.
  44 #I1 #I2 #L1 #L2 #V1 #V2 #l #m #HL12 #Hl <(ylt_inv_O1 … Hl) /2 width=1 by lreq_succ/
  45 qed.
  46
  47 lemma lreq_pair_O_Y: ∀L1,L2. L1 ⩬[0, ∞] L2 →
  48                      ∀I,V. L1.ⓑ{I}V ⩬[0, ∞] L2.ⓑ{I}V.
  49 #L1 #L2 #HL12 #I #V lapply (lreq_pair I … V … HL12) -HL12 //
  50 qed.
  51
  52 lemma lreq_refl: ∀L,l,m. L ⩬[l, m] L.
  53 #L elim L -L //
  54 #L #I #V #IHL #l elim (ynat_cases … l) [| * #x ]
  55 #Hl destruct /2 width=1 by lreq_succ/
  56 #m elim (ynat_cases … m) [| * #x ]
  57 #Hm destruct /2 width=1 by lreq_zero, lreq_pair/
  58 qed.
  59
  60 lemma lreq_O2: ∀L1,L2,l. |L1| = |L2| → L1 ⩬[l, yinj 0] L2.
  61 #L1 elim L1 -L1 [| #L1 #I1 #V1 #IHL1 ]
  62 * // [1,3: #L2 #I2 #V2 ] #l normalize
  63 [1,3: <plus_n_Sm #H destruct ]
  64 #H lapply (injective_plus_l … H) -H #HL12
  65 elim (ynat_cases l) /3 width=1 by lreq_zero/
  66 * /3 width=1 by lreq_succ/
  67 qed.
  68
  69 lemma lreq_sym: ∀l,m. symmetric … (lreq l m).
  70 #l #m #L1 #L2 #H elim H -L1 -L2 -l -m
  71 /2 width=1 by lreq_zero, lreq_pair, lreq_succ/
  72 qed-.
  73
  74 (* Basic inversion lemmas ***************************************************)
  75
  76 fact lreq_inv_atom1_aux: ∀L1,L2,l,m. L1 ⩬[l, m] L2 → L1 = ⋆ → L2 = ⋆.
  77 #L1 #L2 #l #m * -L1 -L2 -l -m //
  78 [ #I1 #I2 #L1 #L2 #V1 #V2 #_ #H destruct
  79 | #I #L1 #L2 #V #m #_ #H destruct
  80 | #I1 #I2 #L1 #L2 #V1 #V2 #l #m #_ #H destruct
  81 ]
  82 qed-.
  83
  84 lemma lreq_inv_atom1: ∀L2,l,m. ⋆ ⩬[l, m] L2 → L2 = ⋆.
  85 /2 width=5 by lreq_inv_atom1_aux/ qed-.
  86
  87 fact lreq_inv_zero1_aux: ∀L1,L2,l,m. L1 ⩬[l, m] L2 →
  88                          ∀J1,K1,W1. L1 = K1.ⓑ{J1}W1 → l = 0 → m = 0 →
  89                          ∃∃J2,K2,W2. K1 ⩬[0, 0] K2 & L2 = K2.ⓑ{J2}W2.
  90 #L1 #L2 #l #m * -L1 -L2 -l -m
  91 [ #l #m #J1 #K1 #W1 #H destruct
  92 | #I1 #I2 #L1 #L2 #V1 #V2 #HL12 #J1 #K1 #W1 #H #_ #_ destruct
  93   /2 width=5 by ex2_3_intro/
  94 | #I #L1 #L2 #V #m #_ #J1 #K1 #W1 #_ #_ #H
  95   elim (ysucc_inv_O_dx … H)
  96 | #I1 #I2 #L1 #L2 #V1 #V2 #l #m #_ #J1 #K1 #W1 #_ #H
  97   elim (ysucc_inv_O_dx … H)
  98 ]
  99 qed-.
 100
 101 lemma lreq_inv_zero1: ∀I1,K1,L2,V1. K1.ⓑ{I1}V1 ⩬[0, 0] L2 →
 102                       ∃∃I2,K2,V2. K1 ⩬[0, 0] K2 & L2 = K2.ⓑ{I2}V2.
 103 /2 width=9 by lreq_inv_zero1_aux/ qed-.
 104
 105 fact lreq_inv_pair1_aux: ∀L1,L2,l,m. L1 ⩬[l, m] L2 →
 106                          ∀J,K1,W. L1 = K1.ⓑ{J}W → l = 0 → 0 < m →
 107                          ∃∃K2. K1 ⩬[0, ⫰m] K2 & L2 = K2.ⓑ{J}W.
 108 #L1 #L2 #l #m * -L1 -L2 -l -m
 109 [ #l #m #J #K1 #W #H destruct
 110 | #I1 #I2 #L1 #L2 #V1 #V2 #_ #J #K1 #W #_ #_ #H
 111   elim (ylt_yle_false … H) //
 112 | #I #L1 #L2 #V #m #HL12 #J #K1 #W #H #_ #_ destruct
 113   /2 width=3 by ex2_intro/
 114 | #I1 #I2 #L1 #L2 #V1 #V2 #l #m #_ #J #K1 #W #_ #H
 115   elim (ysucc_inv_O_dx … H)
 116 ]
 117 qed-.
 118
 119 lemma lreq_inv_pair1: ∀I,K1,L2,V,m. K1.ⓑ{I}V ⩬[0, m] L2 → 0 < m →
 120                       ∃∃K2. K1 ⩬[0, ⫰m] K2 & L2 = K2.ⓑ{I}V.
 121 /2 width=6 by lreq_inv_pair1_aux/ qed-.
 122
 123 lemma lreq_inv_pair: ∀I1,I2,L1,L2,V1,V2,m. L1.ⓑ{I1}V1 ⩬[0, m] L2.ⓑ{I2}V2 → 0 < m →
 124                     ∧∧ L1 ⩬[0, ⫰m] L2 & I1 = I2 & V1 = V2.
 125 #I1 #I2 #L1 #L2 #V1 #V2 #m #H #Hm elim (lreq_inv_pair1 … H) -H //
 126 #Y #HL12 #H destruct /2 width=1 by and3_intro/
 127 qed-.
 128
 129 fact lreq_inv_succ1_aux: ∀L1,L2,l,m. L1 ⩬[l, m] L2 →
 130                          ∀J1,K1,W1. L1 = K1.ⓑ{J1}W1 → 0 < l →
 131                          ∃∃J2,K2,W2. K1 ⩬[⫰l, m] K2 & L2 = K2.ⓑ{J2}W2.
 132 #L1 #L2 #l #m * -L1 -L2 -l -m
 133 [ #l #m #J1 #K1 #W1 #H destruct
 134 | #I1 #I2 #L1 #L2 #V1 #V2 #_ #J1 #K1 #W1 #_ #H
 135   elim (ylt_yle_false … H) //
 136 | #I #L1 #L2 #V #m #_ #J1 #K1 #W1 #_ #H
 137   elim (ylt_yle_false … H) //
 138 | #I1 #I2 #L1 #L2 #V1 #V2 #l #m #HL12 #J1 #K1 #W1 #H #_ destruct
 139   /2 width=5 by ex2_3_intro/
 140 ]
 141 qed-.
 142
 143 lemma lreq_inv_succ1: ∀I1,K1,L2,V1,l,m. K1.ⓑ{I1}V1 ⩬[l, m] L2 → 0 < l →
 144                       ∃∃I2,K2,V2. K1 ⩬[⫰l, m] K2 & L2 = K2.ⓑ{I2}V2.
 145 /2 width=5 by lreq_inv_succ1_aux/ qed-.
 146
 147 lemma lreq_inv_atom2: ∀L1,l,m. L1 ⩬[l, m] ⋆ → L1 = ⋆.
 148 /3 width=3 by lreq_inv_atom1, lreq_sym/
 149 qed-.
 150
 151 lemma lreq_inv_succ: ∀I1,I2,L1,L2,V1,V2,l,m. L1.ⓑ{I1}V1 ⩬[l, m] L2.ⓑ{I2}V2 → 0 < l →
 152                      L1 ⩬[⫰l, m] L2.
 153 #I1 #I2 #L1 #L2 #V1 #V2 #l #m #H #Hl elim (lreq_inv_succ1 … H) -H //
 154 #Z #Y #X #HL12 #H destruct //
 155 qed-.
 156
 157 lemma lreq_inv_zero2: ∀I2,K2,L1,V2. L1 ⩬[0, 0] K2.ⓑ{I2}V2 →
 158                       ∃∃I1,K1,V1. K1 ⩬[0, 0] K2 & L1 = K1.ⓑ{I1}V1.
 159 #I2 #K2 #L1 #V2 #H elim (lreq_inv_zero1 … (lreq_sym … H)) -H
 160 /3 width=5 by lreq_sym, ex2_3_intro/
 161 qed-.
 162
 163 lemma lreq_inv_pair2: ∀I,K2,L1,V,m. L1 ⩬[0, m] K2.ⓑ{I}V → 0 < m →
 164                       ∃∃K1. K1 ⩬[0, ⫰m] K2 & L1 = K1.ⓑ{I}V.
 165 #I #K2 #L1 #V #m #H #Hm elim (lreq_inv_pair1 … (lreq_sym … H)) -H
 166 /3 width=3 by lreq_sym, ex2_intro/
 167 qed-.
 168
 169 lemma lreq_inv_succ2: ∀I2,K2,L1,V2,l,m. L1 ⩬[l, m] K2.ⓑ{I2}V2 → 0 < l →
 170                       ∃∃I1,K1,V1. K1 ⩬[⫰l, m] K2 & L1 = K1.ⓑ{I1}V1.
 171 #I2 #K2 #L1 #V2 #l #m #H #Hl elim (lreq_inv_succ1 … (lreq_sym … H)) -H
 172 /3 width=5 by lreq_sym, ex2_3_intro/
 173 qed-.
 174
 175 (* Basic forward lemmas *****************************************************)
 176
 177 lemma lreq_fwd_length: ∀L1,L2,l,m. L1 ⩬[l, m] L2 → |L1| = |L2|.
 178 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m normalize //
 179 qed-.
 180
 181 (* Advanced inversion lemmas ************************************************)
 182
 183 fact lreq_inv_O_Y_aux: ∀L1,L2,l,m. L1 ⩬[l, m] L2 → l = 0 → m = ∞ → L1 = L2.
 184 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m //
 185 [ #I1 #I2 #L1 #L2 #V1 #V2 #_ #_ #_ #H destruct
 186 | /4 width=1 by eq_f3, ysucc_inv_Y_dx/
 187 | #I1 #I2 #L1 #L2 #V1 #V2 #l #m #_ #_ #H elim (ysucc_inv_O_dx … H)
 188 ]
 189 qed-.
 190
 191 lemma lreq_inv_O_Y: ∀L1,L2. L1 ⩬[0, ∞] L2 → L1 = L2.
 192 /2 width=5 by lreq_inv_O_Y_aux/ qed-.