matita/matita/contribs/lambdadelta/basic_2A/grammar/lreq_lreq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2A/ynat/ynat_plus.ma".
  16 include "basic_2A/grammar/lreq.ma".
  17
  18 (* EQUIVALENCE FOR LOCAL ENVIRONMENTS ***************************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 theorem lreq_trans: ∀l,m. Transitive … (lreq l m).
  23 #l #m #L1 #L2 #H elim H -L1 -L2 -l -m
  24 [ #l #m #X #H lapply (lreq_inv_atom1 … H) -H
  25   #H destruct //
  26 | #I1 #I #L1 #L #V1 #V #_ #IHL1 #X #H elim (lreq_inv_zero1 … H) -H
  27   #I2 #L2 #V2 #HL2 #H destruct /3 width=1 by lreq_zero/
  28 | #I #L1 #L #V #m #_ #IHL1 #X #H elim (lreq_inv_pair1 … H) -H //
  29   #L2 #HL2 #H destruct /3 width=1 by lreq_pair/
  30 | #I1 #I #L1 #L #V1 #V #l #m #_ #IHL1 #X #H elim (lreq_inv_succ1 … H) -H //
  31   #I2 #L2 #V2 #HL2 #H destruct /3 width=1 by lreq_succ/
  32 ]
  33 qed-.
  34
  35 theorem lreq_canc_sn: ∀l,m,L,L1,L2. L ⩬[l, m] L1 → L ⩬[l, m] L2 → L1 ⩬[l, m] L2.
  36 /3 width=3 by lreq_trans, lreq_sym/ qed-.
  37
  38 theorem lreq_canc_dx: ∀l,m,L,L1,L2. L1 ⩬[l, m] L → L2 ⩬[l, m] L → L1 ⩬[l, m] L2.
  39 /3 width=3 by lreq_trans, lreq_sym/ qed-.
  40
  41 theorem lreq_join: ∀L1,L2,l,i. L1 ⩬[l, i] L2 →
  42                    ∀m. L1 ⩬[i+l, m] L2 → L1 ⩬[l, i+m] L2.
  43 #L1 #L2 #l #i #H elim H -L1 -L2 -l -i //
  44 [ #I #L1 #L2 #V #m #_ #IHL12 #m #H
  45   lapply (lreq_inv_succ … H ?) -H // >ypred_succ /3 width=1 by lreq_pair/
  46 | #I1 #I2 #L1 #L2 #V1 #V2 #l #m #_ #IHL12 #m #H
  47   lapply (lreq_inv_succ … H ?) -H // >yplus_succ2 >ypred_succ /3 width=1 by lreq_succ/
  48 ]
  49 qed-.