matita/matita/contribs/lambdadelta/basic_2A/grammar/tsts.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_1_2.ma".
  16 include "basic_2A/notation/relations/topiso_2.ma".
  17 include "basic_2A/grammar/term_simple.ma".
  18
  19 (* SAME TOP TERM STRUCTURE **************************************************)
  20
  21 inductive tsts: relation term ≝
  22    | tsts_atom: ∀I. tsts (⓪{I}) (⓪{I})
  23    | tsts_pair: ∀I,V1,V2,T1,T2. tsts (②{I}V1.T1) (②{I}V2.T2)
  24 .
  25
  26 interpretation "same top structure (term)" 'TopIso T1 T2 = (tsts T1 T2).
  27
  28 (* Basic inversion lemmas ***************************************************)
  29
  30 fact tsts_inv_atom1_aux: ∀T1,T2. T1 ≂ T2 → ∀I. T1 = ⓪{I} → T2 = ⓪{I}.
  31 #T1 #T2 * -T1 -T2 //
  32 #J #V1 #V2 #T1 #T2 #I #H destruct
  33 qed-.
  34
  35 lemma tsts_inv_atom1: ∀I,T2. ⓪{I} ≂ T2 → T2 = ⓪{I}.
  36 /2 width=3 by tsts_inv_atom1_aux/ qed-.
  37
  38 fact tsts_inv_pair1_aux: ∀T1,T2. T1 ≂ T2 → ∀I,W1,U1. T1 = ②{I}W1.U1 →
  39                          ∃∃W2,U2. T2 = ②{I}W2. U2.
  40 #T1 #T2 * -T1 -T2
  41 [ #J #I #W1 #U1 #H destruct
  42 | #J #V1 #V2 #T1 #T2 #I #W1 #U1 #H destruct /2 width=3 by ex1_2_intro/
  43 ]
  44 qed-.
  45
  46 lemma tsts_inv_pair1: ∀I,W1,U1,T2. ②{I}W1.U1 ≂ T2 →
  47                       ∃∃W2,U2. T2 = ②{I}W2. U2.
  48 /2 width=5 by tsts_inv_pair1_aux/ qed-.
  49
  50 fact tsts_inv_atom2_aux: ∀T1,T2. T1 ≂ T2 → ∀I. T2 = ⓪{I} → T1 = ⓪{I}.
  51 #T1 #T2 * -T1 -T2 //
  52 #J #V1 #V2 #T1 #T2 #I #H destruct
  53 qed-.
  54
  55 lemma tsts_inv_atom2: ∀I,T1. T1 ≂ ⓪{I} → T1 = ⓪{I}.
  56 /2 width=3 by tsts_inv_atom2_aux/ qed-.
  57
  58 fact tsts_inv_pair2_aux: ∀T1,T2. T1 ≂ T2 → ∀I,W2,U2. T2 = ②{I}W2.U2 →
  59                          ∃∃W1,U1. T1 = ②{I}W1.U1.
  60 #T1 #T2 * -T1 -T2
  61 [ #J #I #W2 #U2 #H destruct
  62 | #J #V1 #V2 #T1 #T2 #I #W2 #U2 #H destruct /2 width=3 by ex1_2_intro/
  63 ]
  64 qed-.
  65
  66 lemma tsts_inv_pair2: ∀I,T1,W2,U2. T1 ≂ ②{I}W2.U2 →
  67                       ∃∃W1,U1. T1 = ②{I}W1.U1.
  68 /2 width=5 by tsts_inv_pair2_aux/ qed-.
  69
  70 (* Basic properties *********************************************************)
  71
  72 lemma tsts_refl: reflexive … tsts.
  73 #T elim T -T //
  74 qed.
  75
  76 lemma tsts_sym: symmetric … tsts.
  77 #T1 #T2 #H elim H -T1 -T2 //
  78 qed-.
  79
  80 lemma tsts_dec: ∀T1,T2. Decidable (T1 ≂ T2).
  81 * #I1 [2: #V1 #T1 ] * #I2 [2,4: #V2 #T2 ]
  82 [ elim (eq_item2_dec I1 I2) #HI12
  83   [ destruct /2 width=1 by tsts_pair, or_introl/
  84   | @or_intror #H
  85     elim (tsts_inv_pair1 … H) -H #V #T #H destruct /2 width=1 by/
  86   ]
  87 | @or_intror #H
  88   lapply (tsts_inv_atom1 … H) -H #H destruct
  89 | @or_intror #H
  90   lapply (tsts_inv_atom2 … H) -H #H destruct
  91 | elim (eq_item0_dec I1 I2) #HI12
  92   [ destruct /2 width=1 by or_introl/
  93   | @or_intror #H
  94     lapply (tsts_inv_atom2 … H) -H #H destruct /2 width=1 by/
  95   ]
  96 ]
  97 qed.
  98
  99 lemma simple_tsts_repl_dx: ∀T1,T2. T1 ≂ T2 → 𝐒⦃T1⦄ → 𝐒⦃T2⦄.
 100 #T1 #T2 * -T1 -T2 //
 101 #I #V1 #V2 #T1 #T2 #H
 102 elim (simple_inv_pair … H) -H #J #H destruct //
 103 qed-.
 104
 105 lemma simple_tsts_repl_sn: ∀T1,T2. T1 ≂ T2 → 𝐒⦃T2⦄ → 𝐒⦃T1⦄.
 106 /3 width=3 by simple_tsts_repl_dx, tsts_sym/ qed-.