matita/matita/contribs/lambdadelta/basic_2A/multiple/drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_4_3.ma".
  16 include "ground/relocation/mr2_minus.ma".
  17 include "basic_2A/notation/relations/rdropstar_3.ma".
  18 include "basic_2A/notation/relations/rdropstar_4.ma".
  19 include "basic_2A/substitution/drop.ma".
  20 include "basic_2A/multiple/lifts_vector.ma".
  21
  22 (* ITERATED LOCAL ENVIRONMENT SLICING ***************************************)
  23
  24 inductive drops (s:bool): mr2 → relation lenv ≝
  25 | drops_nil : ∀L. drops s (◊) L L
  26 | drops_cons: ∀L1,L,L2,cs,l,m.
  27               drops s cs L1 L → ⬇[s, l, m] L ≡ L2 → drops s (❨l, m❩; cs) L1 L2
  28 .
  29
  30 interpretation "iterated slicing (local environment) abstract"
  31    'RDropStar s cs T1 T2 = (drops s cs T1 T2).
  32 (*
  33 interpretation "iterated slicing (local environment) general"
  34    'RDropStar des T1 T2 = (drops true des T1 T2).
  35 *)
  36
  37 definition d_liftable1: relation2 lenv term → predicate bool ≝
  38                         λR,s. ∀K,T. R K T → ∀L,l,m. ⬇[s, l, m] L ≡ K →
  39                         ∀U. ⬆[l, m] T ≡ U → R L U.
  40
  41 definition d_liftables1: relation2 lenv term → predicate bool ≝
  42                          λR,s. ∀L,K,cs. ⬇*[s, cs] L ≡ K →
  43                          ∀T,U. ⬆*[cs] T ≡ U → R K T → R L U.
  44
  45 definition d_liftables1_all: relation2 lenv term → predicate bool ≝
  46                              λR,s. ∀L,K,cs. ⬇*[s, cs] L ≡ K →
  47                              ∀Ts,Us. ⬆*[cs] Ts ≡ Us →
  48                              all … (R K) Ts → all … (R L) Us.
  49
  50 (* Basic inversion lemmas ***************************************************)
  51
  52 fact drops_inv_nil_aux: ∀L1,L2,s,cs. ⬇*[s, cs] L1 ≡ L2 → cs = ◊ → L1 = L2.
  53 #L1 #L2 #s #cs * -L1 -L2 -cs //
  54 #L1 #L #L2 #l #m #cs #_ #_ #H destruct
  55 qed-.
  56
  57 lemma drops_inv_nil: ∀L1,L2,s. ⬇*[s, ◊] L1 ≡ L2 → L1 = L2.
  58 /2 width=4 by drops_inv_nil_aux/ qed-.
  59
  60 fact drops_inv_cons_aux: ∀L1,L2,s,cs. ⬇*[s, cs] L1 ≡ L2 →
  61                          ∀l,m,tl. cs = ❨l, m❩; tl →
  62                          ∃∃L. ⬇*[s, tl] L1 ≡ L & ⬇[s, l, m] L ≡ L2.
  63 #L1 #L2 #s #cs * -L1 -L2 -cs
  64 [ #L #l #m #tl #H destruct
  65 | #L1 #L #L2 #cs #l #m #HT1 #HT2 #l0 #m0 #tl #H destruct
  66   /2 width=3 by ex2_intro/
  67 ]
  68 qed-.
  69
  70 lemma drops_inv_cons: ∀L1,L2,s,l,m,cs. ⬇*[s, ❨l, m❩; cs] L1 ≡ L2 →
  71                       ∃∃L. ⬇*[s, cs] L1 ≡ L & ⬇[s, l, m] L ≡ L2.
  72 /2 width=3 by drops_inv_cons_aux/ qed-.
  73
  74 lemma drops_inv_skip2: ∀I,s,cs,cs2,i. cs ▭ i ≘ cs2 →
  75                        ∀L1,K2,V2. ⬇*[s, cs2] L1 ≡ K2. ⓑ{I} V2 →
  76                        ∃∃K1,V1,cs1. cs + 1 ▭ i + 1 ≘ cs1 + 1 &
  77                                      ⬇*[s, cs1] K1 ≡ K2 &
  78                                      ⬆*[cs1] V2 ≡ V1 &
  79                                      L1 = K1. ⓑ{I} V1.
  80 #I #s #cs #cs2 #i #H elim H -cs -cs2 -i
  81 [ #i #L1 #K2 #V2 #H
  82   >(drops_inv_nil … H) -L1 /2 width=7 by lifts_nil, minuss_nil, ex4_3_intro, drops_nil/
  83 | #cs #cs2 #l #m #i #Hil #_ #IHcs2 #L1 #K2 #V2 #H
  84   elim (drops_inv_cons … H) -H #L #HL1 #H
  85   elim (drop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ #K #V >minus_plus #HK2 #HV2 #H destruct
  86   elim (IHcs2 … HL1) -IHcs2 -HL1 #K1 #V1 #cs1 #Hcs1 #HK1 #HV1 #X destruct
  87   @(ex4_3_intro … K1 V1 … ) // [3,4: /2 width=7 by lifts_cons, drops_cons/ | skip ]
  88   normalize >plus_minus /3 width=1 by minuss_lt, lt_minus_to_plus/ (**) (* explicit constructors *)
  89 | #cs #cs2 #l #m #i #Hil #_ #IHcs2 #L1 #K2 #V2 #H
  90   elim (IHcs2 … H) -IHcs2 -H #K1 #V1 #cs1 #Hcs1 #HK1 #HV1 #X destruct
  91   /4 width=7 by minuss_ge, ex4_3_intro, le_S_S/
  92 ]
  93 qed-.
  94
  95 (* Basic properties *********************************************************)
  96
  97 lemma drops_skip: ∀L1,L2,s,cs. ⬇*[s, cs] L1 ≡ L2 → ∀V1,V2. ⬆*[cs] V2 ≡ V1 →
  98                   ∀I. ⬇*[s, cs + 1] L1.ⓑ{I}V1 ≡ L2.ⓑ{I}V2.
  99 #L1 #L2 #s #cs #H elim H -L1 -L2 -cs
 100 [ #L #V1 #V2 #HV12 #I
 101   >(lifts_inv_nil … HV12) -HV12 //
 102 | #L1 #L #L2 #cs #l #m #_ #HL2 #IHL #V1 #V2 #H #I
 103   elim (lifts_inv_cons … H) -H /3 width=5 by drop_skip, drops_cons/
 104 ].
 105 qed.
 106
 107 lemma d1_liftable_liftables: ∀R,s. d_liftable1 R s → d_liftables1 R s.
 108 #R #s #HR #L #K #cs #H elim H -L -K -cs
 109 [ #L #T #U #H #HT <(lifts_inv_nil … H) -H //
 110 | #L1 #L #L2 #cs #l #m #_ #HL2 #IHL #T2 #T1 #H #HLT2
 111   elim (lifts_inv_cons … H) -H /3 width=10 by/
 112 ]
 113 qed.
 114
 115 lemma d1_liftables_liftables_all: ∀R,s. d_liftables1 R s → d_liftables1_all R s.
 116 #R #s #HR #L #K #cs #HLK #Ts #Us #H elim H -Ts -Us normalize //
 117 #Ts #Us #T #U #HTU #_ #IHTUs * /3 width=7 by conj/
 118 qed.