matita/matita/contribs/lambdadelta/basic_2A/multiple/drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_4_3.ma".
  16 include "ground/relocation/mr2_minus.ma".
  17 include "basic_2A/notation/relations/rdropstar_3.ma".
  18 include "basic_2A/notation/relations/rdropstar_4.ma".
  19 include "basic_2A/substitution/drop.ma".
  20 include "basic_2A/multiple/lifts_vector.ma".
  21
  22 (* ITERATED LOCAL ENVIRONMENT SLICING ***************************************)
  23
  24 inductive drops (s:bool): mr2 → relation lenv ≝
  25 | drops_nil : ∀L. drops s (◊) L L
  26 | drops_cons: ∀L1,L,L2,cs,l,m.
  27               drops s cs L1 L → ⬇[s, l, m] L ≡ L2 → drops s (❨l, m❩; cs) L1 L2
  28 .
  29
  30 interpretation "iterated slicing (local environment) abstract"
  31    'RDropStar s cs T1 T2 = (drops s cs T1 T2).
  32 (*
  33 interpretation "iterated slicing (local environment) general"
  34    'RDropStar des T1 T2 = (drops true des T1 T2).
  35 *)
  36
  37 definition d_liftable1: relation2 lenv term → predicate bool ≝
  38                         λR,s. ∀K,T. R K T → ∀L,l,m. ⬇[s, l, m] L ≡ K →
  39                         ∀U. ⬆[l, m] T ≡ U → R L U.
  40
  41 definition d_liftables1: relation2 lenv term → predicate bool ≝
  42                          λR,s. ∀L,K,cs. ⬇*[s, cs] L ≡ K →
  43                          ∀T,U. ⬆*[cs] T ≡ U → R K T → R L U.
  44
  45 definition d_liftables1_all: relation2 lenv term → predicate bool ≝
  46                              λR,s. ∀L,K,cs. ⬇*[s, cs] L ≡ K →
  47                              ∀Ts,Us. ⬆*[cs] Ts ≡ Us →
  48                              all … (R K) Ts → all … (R L) Us.
  49
  50 (* Basic inversion lemmas ***************************************************)
  51
  52 fact drops_inv_nil_aux: ∀L1,L2,s,cs. ⬇*[s, cs] L1 ≡ L2 → cs = ◊ → L1 = L2.
  53 #L1 #L2 #s #cs * -L1 -L2 -cs //
  54 #L1 #L #L2 #l #m #cs #_ #_ #H destruct
  55 qed-.
  56
  57 (* Basic_1: was: drop1_gen_pnil *)
  58 lemma drops_inv_nil: ∀L1,L2,s. ⬇*[s, ◊] L1 ≡ L2 → L1 = L2.
  59 /2 width=4 by drops_inv_nil_aux/ qed-.
  60
  61 fact drops_inv_cons_aux: ∀L1,L2,s,cs. ⬇*[s, cs] L1 ≡ L2 →
  62                          ∀l,m,tl. cs = ❨l, m❩; tl →
  63                          ∃∃L. ⬇*[s, tl] L1 ≡ L & ⬇[s, l, m] L ≡ L2.
  64 #L1 #L2 #s #cs * -L1 -L2 -cs
  65 [ #L #l #m #tl #H destruct
  66 | #L1 #L #L2 #cs #l #m #HT1 #HT2 #l0 #m0 #tl #H destruct
  67   /2 width=3 by ex2_intro/
  68 ]
  69 qed-.
  70
  71 (* Basic_1: was: drop1_gen_pcons *)
  72 lemma drops_inv_cons: ∀L1,L2,s,l,m,cs. ⬇*[s, ❨l, m❩; cs] L1 ≡ L2 →
  73                       ∃∃L. ⬇*[s, cs] L1 ≡ L & ⬇[s, l, m] L ≡ L2.
  74 /2 width=3 by drops_inv_cons_aux/ qed-.
  75
  76 lemma drops_inv_skip2: ∀I,s,cs,cs2,i. cs ▭ i ≘ cs2 →
  77                        ∀L1,K2,V2. ⬇*[s, cs2] L1 ≡ K2. ⓑ{I} V2 →
  78                        ∃∃K1,V1,cs1. cs + 1 ▭ i + 1 ≘ cs1 + 1 &
  79                                      ⬇*[s, cs1] K1 ≡ K2 &
  80                                      ⬆*[cs1] V2 ≡ V1 &
  81                                      L1 = K1. ⓑ{I} V1.
  82 #I #s #cs #cs2 #i #H elim H -cs -cs2 -i
  83 [ #i #L1 #K2 #V2 #H
  84   >(drops_inv_nil … H) -L1 /2 width=7 by lifts_nil, minuss_nil, ex4_3_intro, drops_nil/
  85 | #cs #cs2 #l #m #i #Hil #_ #IHcs2 #L1 #K2 #V2 #H
  86   elim (drops_inv_cons … H) -H #L #HL1 #H
  87   elim (drop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ #K #V >minus_plus #HK2 #HV2 #H destruct
  88   elim (IHcs2 … HL1) -IHcs2 -HL1 #K1 #V1 #cs1 #Hcs1 #HK1 #HV1 #X destruct
  89   @(ex4_3_intro … K1 V1 … ) // [3,4: /2 width=7 by lifts_cons, drops_cons/ | skip ]
  90   normalize >plus_minus /3 width=1 by minuss_lt, lt_minus_to_plus/ (**) (* explicit constructors *)
  91 | #cs #cs2 #l #m #i #Hil #_ #IHcs2 #L1 #K2 #V2 #H
  92   elim (IHcs2 … H) -IHcs2 -H #K1 #V1 #cs1 #Hcs1 #HK1 #HV1 #X destruct
  93   /4 width=7 by minuss_ge, ex4_3_intro, le_S_S/
  94 ]
  95 qed-.
  96
  97 (* Basic properties *********************************************************)
  98
  99 (* Basic_1: was: drop1_skip_bind *)
 100 lemma drops_skip: ∀L1,L2,s,cs. ⬇*[s, cs] L1 ≡ L2 → ∀V1,V2. ⬆*[cs] V2 ≡ V1 →
 101                   ∀I. ⬇*[s, cs + 1] L1.ⓑ{I}V1 ≡ L2.ⓑ{I}V2.
 102 #L1 #L2 #s #cs #H elim H -L1 -L2 -cs
 103 [ #L #V1 #V2 #HV12 #I
 104   >(lifts_inv_nil … HV12) -HV12 //
 105 | #L1 #L #L2 #cs #l #m #_ #HL2 #IHL #V1 #V2 #H #I
 106   elim (lifts_inv_cons … H) -H /3 width=5 by drop_skip, drops_cons/
 107 ].
 108 qed.
 109
 110 lemma d1_liftable_liftables: ∀R,s. d_liftable1 R s → d_liftables1 R s.
 111 #R #s #HR #L #K #cs #H elim H -L -K -cs
 112 [ #L #T #U #H #HT <(lifts_inv_nil … H) -H //
 113 | #L1 #L #L2 #cs #l #m #_ #HL2 #IHL #T2 #T1 #H #HLT2
 114   elim (lifts_inv_cons … H) -H /3 width=10 by/
 115 ]
 116 qed.
 117
 118 lemma d1_liftables_liftables_all: ∀R,s. d_liftables1 R s → d_liftables1_all R s.
 119 #R #s #HR #L #K #cs #HLK #Ts #Us #H elim H -Ts -Us normalize //
 120 #Ts #Us #T #U #HTU #_ #IHTUs * /3 width=7 by conj/
 121 qed.
 122
 123 (* Basic_1: removed theorems 1: drop1_getl_trans *)