matita/matita/contribs/lambdadelta/basic_2A/multiple/fqup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/suptermplus_6.ma".
  16 include "basic_2A/substitution/fqu.ma".
  17
  18 (* PLUS-ITERATED SUPCLOSURE *************************************************)
  19
  20 definition fqup: tri_relation genv lenv term ≝ tri_TC … fqu.
  21
  22 interpretation "plus-iterated structural successor (closure)"
  23    'SupTermPlus G1 L1 T1 G2 L2 T2 = (fqup G1 L1 T1 G2 L2 T2).
  24
  25 (* Basic properties *********************************************************)
  26
  27 lemma fqu_fqup: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  28 /2 width=1 by tri_inj/ qed.
  29
  30 lemma fqup_strap1: ∀G1,G,G2,L1,L,L2,T1,T,T2.
  31                    ⦃G1, L1, T1⦄ ⊐+ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐ ⦃G2, L2, T2⦄ →
  32                    ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  33 /2 width=5 by tri_step/ qed.
  34
  35 lemma fqup_strap2: ∀G1,G,G2,L1,L,L2,T1,T,T2.
  36                    ⦃G1, L1, T1⦄ ⊐ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐+ ⦃G2, L2, T2⦄ →
  37                    ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  38 /2 width=5 by tri_TC_strap/ qed.
  39
  40 lemma fqup_drop: ∀G1,G2,L1,K1,K2,T1,T2,U1,m. ⬇[m] L1 ≡ K1 → ⬆[0, m] T1 ≡ U1 →
  41                   ⦃G1, K1, T1⦄ ⊐+ ⦃G2, K2, T2⦄ → ⦃G1, L1, U1⦄ ⊐+ ⦃G2, K2, T2⦄.
  42 #G1 #G2 #L1 #K1 #K2 #T1 #T2 #U1 #m #HLK1 #HTU1 #HT12 elim (eq_or_gt … m) #H destruct
  43 [ >(drop_inv_O2 … HLK1) -L1 <(lift_inv_O2 … HTU1) -U1 //
  44 | /3 width=5 by fqup_strap2, fqu_drop_lt/
  45 ]
  46 qed-.
  47
  48 lemma fqup_lref: ∀I,G,L,K,V,i. ⬇[i] L ≡ K.ⓑ{I}V → ⦃G, L, #i⦄ ⊐+ ⦃G, K, V⦄.
  49 /3 width=6 by fqu_lref_O, fqu_fqup, lift_lref_ge, fqup_drop/ qed.
  50
  51 lemma fqup_pair_sn: ∀I,G,L,V,T. ⦃G, L, ②{I}V.T⦄ ⊐+ ⦃G, L, V⦄.
  52 /2 width=1 by fqu_pair_sn, fqu_fqup/ qed.
  53
  54 lemma fqup_bind_dx: ∀a,I,G,L,V,T. ⦃G, L, ⓑ{a,I}V.T⦄ ⊐+ ⦃G, L.ⓑ{I}V, T⦄.
  55 /2 width=1 by fqu_bind_dx, fqu_fqup/ qed.
  56
  57 lemma fqup_flat_dx: ∀I,G,L,V,T. ⦃G, L, ⓕ{I}V.T⦄ ⊐+ ⦃G, L, T⦄.
  58 /2 width=1 by fqu_flat_dx, fqu_fqup/ qed.
  59
  60 lemma fqup_flat_dx_pair_sn: ∀I1,I2,G,L,V1,V2,T. ⦃G, L, ⓕ{I1}V1.②{I2}V2.T⦄ ⊐+ ⦃G, L, V2⦄.
  61 /2 width=5 by fqu_pair_sn, fqup_strap1/ qed.
  62
  63 lemma fqup_bind_dx_flat_dx: ∀a,G,I1,I2,L,V1,V2,T. ⦃G, L, ⓑ{a,I1}V1.ⓕ{I2}V2.T⦄ ⊐+ ⦃G, L.ⓑ{I1}V1, T⦄.
  64 /2 width=5 by fqu_flat_dx, fqup_strap1/ qed.
  65
  66 lemma fqup_flat_dx_bind_dx: ∀a,I1,I2,G,L,V1,V2,T. ⦃G, L, ⓕ{I1}V1.ⓑ{a,I2}V2.T⦄ ⊐+ ⦃G, L.ⓑ{I2}V2, T⦄.
  67 /2 width=5 by fqu_bind_dx, fqup_strap1/ qed.
  68
  69 (* Basic eliminators ********************************************************)
  70
  71 lemma fqup_ind: ∀G1,L1,T1. ∀R:relation3 ….
  72                 (∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ → R G2 L2 T2) →
  73                 (∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐ ⦃G2, L2, T2⦄ → R G L T → R G2 L2 T2) →
  74                 ∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → R G2 L2 T2.
  75 #G1 #L1 #T1 #R #IH1 #IH2 #G2 #L2 #T2 #H
  76 @(tri_TC_ind … IH1 IH2 G2 L2 T2 H)
  77 qed-.
  78
  79 lemma fqup_ind_dx: ∀G2,L2,T2. ∀R:relation3 ….
  80                    (∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ → R G1 L1 T1) →
  81                    (∀G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ⊐ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐+ ⦃G2, L2, T2⦄ → R G L T → R G1 L1 T1) →
  82                    ∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → R G1 L1 T1.
  83 #G2 #L2 #T2 #R #IH1 #IH2 #G1 #L1 #T1 #H
  84 @(tri_TC_ind_dx … IH1 IH2 G1 L1 T1 H)
  85 qed-.
  86
  87 (* Basic forward lemmas *****************************************************)
  88
  89 lemma fqup_fwd_fw: ∀G1,G2,L1,L2,T1,T2.
  90                    ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → ♯{G2, L2, T2} < ♯{G1, L1, T1}.
  91 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  92 /3 width=3 by fqu_fwd_fw, transitive_lt/
  93 qed-.
  94
  95 (* Advanced eliminators *****************************************************)
  96
  97 lemma fqup_wf_ind: ∀R:relation3 …. (
  98                       ∀G1,L1,T1. (∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → R G2 L2 T2) →
  99                       R G1 L1 T1
 100                    ) → ∀G1,L1,T1. R G1 L1 T1.
 101 #R #HR @(f3_ind … fw) #x #IHx #G1 #L1 #T1 #H destruct /4 width=1 by fqup_fwd_fw/
 102 qed-.
 103
 104 lemma fqup_wf_ind_eq: ∀R:relation3 …. (
 105                          ∀G1,L1,T1. (∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → R G2 L2 T2) →
 106                          ∀G2,L2,T2. G1 = G2 → L1 = L2 → T1 = T2 → R G2 L2 T2
 107                       ) → ∀G1,L1,T1. R G1 L1 T1.
 108 #R #HR @(f3_ind … fw) #x #IHx #G1 #L1 #T1 #H destruct /4 width=7 by fqup_fwd_fw/
 109 qed-.