matita/matita/contribs/lambdadelta/basic_2A/multiple/fqus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/suptermstar_6.ma".
  16 include "basic_2A/substitution/fquq.ma".
  17 include "basic_2A/multiple/fqup.ma".
  18
  19 (* STAR-ITERATED SUPCLOSURE *************************************************)
  20
  21 definition fqus: tri_relation genv lenv term ≝ tri_TC … fquq.
  22
  23 interpretation "star-iterated structural successor (closure)"
  24    'SupTermStar G1 L1 T1 G2 L2 T2 = (fqus G1 L1 T1 G2 L2 T2).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma fqus_ind: ∀G1,L1,T1. ∀R:relation3 …. R G1 L1 T1 →
  29                 (∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐⸮ ⦃G2, L2, T2⦄ → R G L T → R G2 L2 T2) →
  30                 ∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ → R G2 L2 T2.
  31 #G1 #L1 #T1 #R #IH1 #IH2 #G2 #L2 #T2 #H
  32 @(tri_TC_star_ind … IH1 IH2 G2 L2 T2 H) //
  33 qed-.
  34
  35 lemma fqus_ind_dx: ∀G2,L2,T2. ∀R:relation3 …. R G2 L2 T2 →
  36                    (∀G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐* ⦃G2, L2, T2⦄ → R G L T → R G1 L1 T1) →
  37                    ∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ → R G1 L1 T1.
  38 #G2 #L2 #T2 #R #IH1 #IH2 #G1 #L1 #T1 #H
  39 @(tri_TC_star_ind_dx … IH1 IH2 G1 L1 T1 H) //
  40 qed-.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma fqus_refl: tri_reflexive … fqus.
  45 /2 width=1 by tri_inj/ qed.
  46
  47 lemma fquq_fqus: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄.
  48 /2 width=1 by tri_inj/ qed.
  49
  50 lemma fqus_strap1: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  51                    ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄.
  52 /2 width=5 by tri_step/ qed-.
  53
  54 lemma fqus_strap2: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐* ⦃G2, L2, T2⦄ →
  55                    ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄.
  56 /2 width=5 by tri_TC_strap/ qed-.
  57
  58 lemma fqus_drop: ∀G1,G2,K1,K2,T1,T2. ⦃G1, K1, T1⦄ ⊐* ⦃G2, K2, T2⦄ →
  59                   ∀L1,U1,m. ⬇[m] L1 ≡ K1 → ⬆[0, m] T1 ≡ U1 →
  60                   ⦃G1, L1, U1⦄ ⊐* ⦃G2, K2, T2⦄.
  61 #G1 #G2 #K1 #K2 #T1 #T2 #H @(fqus_ind … H) -G2 -K2 -T2
  62 /3 width=5 by fqus_strap1, fquq_fqus, fquq_drop/
  63 qed-.
  64
  65 lemma fqup_fqus: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄.
  66 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  67 /3 width=5 by fqus_strap1, fquq_fqus, fqu_fquq/
  68 qed.
  69
  70 (* Basic forward lemmas *****************************************************)
  71
  72 lemma fqus_fwd_fw: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ → ♯{G2, L2, T2} ≤ ♯{G1, L1, T1}.
  73 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqus_ind … H) -L2 -T2
  74 /3 width=3 by fquq_fwd_fw, transitive_le/
  75 qed-.
  76
  77 (* Basic inversion lemmas ***************************************************)
  78
  79 lemma fqup_inv_step_sn: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
  80                         ∃∃G,L,T. ⦃G1, L1, T1⦄ ⊐ ⦃G, L, T⦄ & ⦃G, L, T⦄ ⊐* ⦃G2, L2, T2⦄.
  81 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind_dx … H) -G1 -L1 -T1 /2 width=5 by ex2_3_intro/
  82 #G1 #G #L1 #L #T1 #T #H1 #_ * /4 width=9 by fqus_strap2, fqu_fquq, ex2_3_intro/
  83 qed-.