matita/matita/contribs/lambdadelta/basic_2A/multiple/fqus_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/fquq_alt.ma".
  16 include "basic_2A/multiple/fqus.ma".
  17
  18 (* STAR-ITERATED SUPCLOSURE *************************************************)
  19
  20 (* Advanced inversion lemmas ************************************************)
  21
  22 lemma fqus_inv_gen: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  23                     ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ ∨ (∧∧ G1 = G2 & L1 = L2 & T1 = T2).
  24 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqus_ind … H) -G2 -L2 -T2 //
  25 #G #G2 #L #L2 #T #T2 #_ #H2 * elim (fquq_inv_gen … H2) -H2
  26 [ /3 width=5 by fqup_strap1, or_introl/
  27 | * #HG #HL #HT destruct /2 width=1 by or_introl/
  28 | #H2 * #HG #HL #HT destruct /3 width=1 by fqu_fqup, or_introl/
  29 | * #H1G #H1L #H1T * #H2G #H2L #H2T destruct /2 width=1 by or_intror/
  30 ]
  31 qed-.
  32
  33 (* Advanced properties ******************************************************)
  34
  35 lemma fqus_strap1_fqu: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐ ⦃G2, L2, T2⦄ →
  36                        ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  37 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2 elim (fqus_inv_gen … H1) -H1
  38 [ /2 width=5 by fqup_strap1/
  39 | * #HG #HL #HT destruct /2 width=1 by fqu_fqup/
  40 ]
  41 qed-.
  42
  43 lemma fqus_strap2_fqu: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐* ⦃G2, L2, T2⦄ →
  44                        ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  45 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2 elim (fqus_inv_gen … H2) -H2
  46 [ /2 width=5 by fqup_strap2/
  47 | * #HG #HL #HT destruct /2 width=1 by fqu_fqup/
  48 ]
  49 qed-.
  50
  51 lemma fqus_fqup_trans: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐+ ⦃G2, L2, T2⦄ →
  52                        ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  53 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2 @(fqup_ind … H2) -H2 -G2 -L2 -T2
  54 /2 width=5 by fqus_strap1_fqu, fqup_strap1/
  55 qed-.
  56
  57 lemma fqup_fqus_trans: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G, L, T⦄ →
  58                        ⦃G, L, T⦄ ⊐* ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  59 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 @(fqup_ind_dx … H1) -H1 -G1 -L1 -T1
  60 /3 width=5 by fqus_strap2_fqu, fqup_strap2/
  61 qed-.