matita/matita/contribs/lambdadelta/basic_2A/multiple/lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_4_4.ma".
  16 include "basic_2A/notation/relations/lazyeq_4.ma".
  17 include "basic_2A/multiple/llpx_sn.ma".
  18
  19 (* LAZY EQUIVALENCE FOR LOCAL ENVIRONMENTS **********************************)
  20
  21 definition ceq: relation3 lenv term term ≝ λL,T1,T2. T1 = T2.
  22
  23 definition lleq: relation4 ynat term lenv lenv ≝ llpx_sn ceq.
  24
  25 interpretation
  26    "lazy equivalence (local environment)"
  27    'LazyEq T l L1 L2 = (lleq l T L1 L2).
  28
  29 definition lleq_transitive: predicate (relation3 lenv term term) ≝
  30            λR. ∀L2,T1,T2. R L2 T1 T2 → ∀L1. L1 ≡[T1, 0] L2 → R L1 T1 T2.
  31
  32 (* Basic inversion lemmas ***************************************************)
  33
  34 lemma lleq_ind: ∀R:relation4 ynat term lenv lenv. (
  35                    ∀L1,L2,l,k. |L1| = |L2| → R l (⋆k) L1 L2
  36                 ) → (
  37                    ∀L1,L2,l,i. |L1| = |L2| → yinj i < l → R l (#i) L1 L2
  38                 ) → (
  39                    ∀I,L1,L2,K1,K2,V,l,i. l ≤ yinj i →
  40                    ⬇[i] L1 ≡ K1.ⓑ{I}V → ⬇[i] L2 ≡ K2.ⓑ{I}V →
  41                    K1 ≡[V, yinj O] K2 → R (yinj O) V K1 K2 → R l (#i) L1 L2
  42                 ) → (
  43                    ∀L1,L2,l,i. |L1| = |L2| → |L1| ≤ i → |L2| ≤ i → R l (#i) L1 L2
  44                 ) → (
  45                    ∀L1,L2,l,p. |L1| = |L2| → R l (§p) L1 L2
  46                 ) → (
  47                    ∀a,I,L1,L2,V,T,l.
  48                    L1 ≡[V, l]L2 → L1.ⓑ{I}V ≡[T, ↑l] L2.ⓑ{I}V →
  49                    R l V L1 L2 → R (↑l) T (L1.ⓑ{I}V) (L2.ⓑ{I}V) → R l (ⓑ{a,I}V.T) L1 L2
  50                 ) → (
  51                    ∀I,L1,L2,V,T,l.
  52                    L1 ≡[V, l]L2 → L1 ≡[T, l] L2 →
  53                    R l V L1 L2 → R l T L1 L2 → R l (ⓕ{I}V.T) L1 L2
  54                 ) →
  55                 ∀l,T,L1,L2. L1 ≡[T, l] L2 → R l T L1 L2.
  56 #R #H1 #H2 #H3 #H4 #H5 #H6 #H7 #l #T #L1 #L2 #H elim H -L1 -L2 -T -l /2 width=8 by/
  57 qed-.
  58
  59 lemma lleq_inv_bind: ∀a,I,L1,L2,V,T,l. L1 ≡[ⓑ{a,I}V.T, l] L2 →
  60                      L1 ≡[V, l] L2 ∧ L1.ⓑ{I}V ≡[T, ↑l] L2.ⓑ{I}V.
  61 /2 width=2 by llpx_sn_inv_bind/ qed-.
  62
  63 lemma lleq_inv_flat: ∀I,L1,L2,V,T,l. L1 ≡[ⓕ{I}V.T, l] L2 →
  64                      L1 ≡[V, l] L2 ∧ L1 ≡[T, l] L2.
  65 /2 width=2 by llpx_sn_inv_flat/ qed-.
  66
  67 (* Basic forward lemmas *****************************************************)
  68
  69 lemma lleq_fwd_length: ∀L1,L2,T,l. L1 ≡[T, l] L2 → |L1| = |L2|.
  70 /2 width=4 by llpx_sn_fwd_length/ qed-.
  71
  72 lemma lleq_fwd_lref: ∀L1,L2,l,i. L1 ≡[#i, l] L2 →
  73                      ∨∨ |L1| ≤ i ∧ |L2| ≤ i
  74                       | yinj i < l
  75                       | ∃∃I,K1,K2,V. ⬇[i] L1 ≡ K1.ⓑ{I}V &
  76                                      ⬇[i] L2 ≡ K2.ⓑ{I}V &
  77                                       K1 ≡[V, yinj 0] K2 & l ≤ yinj i.
  78 #L1 #L2 #l #i #H elim (llpx_sn_fwd_lref … H) /2 width=1 by or3_intro0, or3_intro1/
  79 * /3 width=7 by or3_intro2, ex4_4_intro/
  80 qed-.
  81
  82 lemma lleq_fwd_drop_sn: ∀L1,L2,T,l. L1 ≡[l, T] L2 → ∀K1,i. ⬇[i] L1 ≡ K1 →
  83                          ∃K2. ⬇[i] L2 ≡ K2.
  84 /2 width=7 by llpx_sn_fwd_drop_sn/ qed-.
  85
  86 lemma lleq_fwd_drop_dx: ∀L1,L2,T,l. L1 ≡[l, T] L2 → ∀K2,i. ⬇[i] L2 ≡ K2 →
  87                          ∃K1. ⬇[i] L1 ≡ K1.
  88 /2 width=7 by llpx_sn_fwd_drop_dx/ qed-.
  89
  90 lemma lleq_fwd_bind_sn: ∀a,I,L1,L2,V,T,l.
  91                         L1 ≡[ⓑ{a,I}V.T, l] L2 → L1 ≡[V, l] L2.
  92 /2 width=4 by llpx_sn_fwd_bind_sn/ qed-.
  93
  94 lemma lleq_fwd_bind_dx: ∀a,I,L1,L2,V,T,l.
  95                         L1 ≡[ⓑ{a,I}V.T, l] L2 → L1.ⓑ{I}V ≡[T, ↑l] L2.ⓑ{I}V.
  96 /2 width=2 by llpx_sn_fwd_bind_dx/ qed-.
  97
  98 lemma lleq_fwd_flat_sn: ∀I,L1,L2,V,T,l.
  99                         L1 ≡[ⓕ{I}V.T, l] L2 → L1 ≡[V, l] L2.
 100 /2 width=3 by llpx_sn_fwd_flat_sn/ qed-.
 101
 102 lemma lleq_fwd_flat_dx: ∀I,L1,L2,V,T,l.
 103                         L1 ≡[ⓕ{I}V.T, l] L2 → L1 ≡[T, l] L2.
 104 /2 width=3 by llpx_sn_fwd_flat_dx/ qed-.
 105
 106 (* Basic properties *********************************************************)
 107
 108 lemma lleq_sort: ∀L1,L2,l,k. |L1| = |L2| → L1 ≡[⋆k, l] L2.
 109 /2 width=1 by llpx_sn_sort/ qed.
 110
 111 lemma lleq_skip: ∀L1,L2,l,i. yinj i < l → |L1| = |L2| → L1 ≡[#i, l] L2.
 112 /2 width=1 by llpx_sn_skip/ qed.
 113
 114 lemma lleq_lref: ∀I,L1,L2,K1,K2,V,l,i. l ≤ yinj i →
 115                  ⬇[i] L1 ≡ K1.ⓑ{I}V → ⬇[i] L2 ≡ K2.ⓑ{I}V →
 116                  K1 ≡[V, 0] K2 → L1 ≡[#i, l] L2.
 117 /2 width=9 by llpx_sn_lref/ qed.
 118
 119 lemma lleq_free: ∀L1,L2,l,i. |L1| ≤ i → |L2| ≤ i → |L1| = |L2| → L1 ≡[#i, l] L2.
 120 /2 width=1 by llpx_sn_free/ qed.
 121
 122 lemma lleq_gref: ∀L1,L2,l,p. |L1| = |L2| → L1 ≡[§p, l] L2.
 123 /2 width=1 by llpx_sn_gref/ qed.
 124
 125 lemma lleq_bind: ∀a,I,L1,L2,V,T,l.
 126                  L1 ≡[V, l] L2 → L1.ⓑ{I}V ≡[T, ↑l] L2.ⓑ{I}V →
 127                  L1 ≡[ⓑ{a,I}V.T, l] L2.
 128 /2 width=1 by llpx_sn_bind/ qed.
 129
 130 lemma lleq_flat: ∀I,L1,L2,V,T,l.
 131                  L1 ≡[V, l] L2 → L1 ≡[T, l] L2 → L1 ≡[ⓕ{I}V.T, l] L2.
 132 /2 width=1 by llpx_sn_flat/ qed.
 133
 134 lemma lleq_refl: ∀l,T. reflexive … (lleq l T).
 135 /2 width=1 by llpx_sn_refl/ qed.
 136
 137 lemma lleq_Y: ∀L1,L2,T. |L1| = |L2| → L1 ≡[T, ∞] L2.
 138 /2 width=1 by llpx_sn_Y/ qed.
 139
 140 lemma lleq_sym: ∀l,T. symmetric … (lleq l T).
 141 #l #T #L1 #L2 #H @(lleq_ind … H) -l -T -L1 -L2
 142 /2 width=7 by lleq_sort, lleq_skip, lleq_lref, lleq_free, lleq_gref, lleq_bind, lleq_flat/
 143 qed-.
 144
 145 lemma lleq_ge_up: ∀L1,L2,U,lt. L1 ≡[U, lt] L2 →
 146                   ∀T,l,m. ⬆[l, m] T ≡ U →
 147                   lt ≤ l + m → L1 ≡[U, l] L2.
 148 /2 width=6 by llpx_sn_ge_up/ qed-.
 149
 150 lemma lleq_ge: ∀L1,L2,T,l1. L1 ≡[T, l1] L2 → ∀l2. l1 ≤ l2 → L1 ≡[T, l2] L2.
 151 /2 width=3 by llpx_sn_ge/ qed-.
 152
 153 lemma lleq_bind_O: ∀a,I,L1,L2,V,T. L1 ≡[V, 0] L2 → L1.ⓑ{I}V ≡[T, 0] L2.ⓑ{I}V →
 154                    L1 ≡[ⓑ{a,I}V.T, 0] L2.
 155 /2 width=1 by llpx_sn_bind_O/ qed-.
 156
 157 (* Advanceded properties on lazy pointwise extensions ************************)
 158
 159 lemma llpx_sn_lrefl: ∀R. (∀L. reflexive … (R L)) →
 160                      ∀L1,L2,T,l. L1 ≡[T, l] L2 → llpx_sn R l T L1 L2.
 161 /2 width=3 by llpx_sn_co/ qed-.