matita/matita/contribs/lambdadelta/basic_2A/multiple/lleq_alt_rec.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/multiple/llpx_sn_alt_rec.ma".
  16 include "basic_2A/multiple/lleq.ma".
  17
  18 (* LAZY EQUIVALENCE FOR LOCAL ENVIRONMENTS **********************************)
  19
  20 (* Alternative definition (recursive) ***************************************)
  21
  22 theorem lleq_intro_alt_r: ∀L1,L2,T,l. |L1| = |L2| →
  23                           (∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
  24                              ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
  25                              ∧∧ I1 = I2 & V1 = V2 & K1 ≡[V1, 0] K2
  26                           ) → L1 ≡[T, l] L2.
  27 #L1 #L2 #T #l #HL12 #IH @llpx_sn_intro_alt_r // -HL12
  28 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
  29 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /2 width=1 by and3_intro/
  30 qed.
  31
  32 theorem lleq_ind_alt_r: ∀S:relation4 ynat term lenv lenv.
  33                         (∀L1,L2,T,l. |L1| = |L2| → (
  34                            ∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
  35                            ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
  36                            ∧∧ I1 = I2 & V1 = V2 & K1 ≡[V1, 0] K2 & S 0 V1 K1 K2
  37                         ) → S l T L1 L2) →
  38                         ∀L1,L2,T,l. L1 ≡[T, l] L2 → S l T L1 L2.
  39 #S #IH1 #L1 #L2 #T #l #H @(llpx_sn_ind_alt_r … H) -L1 -L2 -T -l
  40 #L1 #L2 #T #l #HL12 #IH2 @IH1 -IH1 // -HL12
  41 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
  42 elim (IH2 … HnT HLK1 HLK2) -IH2 -HnT -HLK1 -HLK2 /2 width=1 by and4_intro/
  43 qed-.
  44
  45 theorem lleq_inv_alt_r: ∀L1,L2,T,l. L1 ≡[T, l] L2 →
  46                         |L1| = |L2| ∧
  47                         ∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
  48                         ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
  49                         ∧∧ I1 = I2 & V1 = V2 & K1 ≡[V1, 0] K2.
  50 #L1 #L2 #T #l #H elim (llpx_sn_inv_alt_r … H) -H
  51 #HL12 #IH @conj //
  52 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
  53 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /2 width=1 by and3_intro/
  54 qed-.