matita/matita/contribs/lambdadelta/basic_2A/multiple/lleq_drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/multiple/llpx_sn_drop.ma".
  16 include "basic_2A/multiple/lleq.ma".
  17
  18 (* LAZY EQUIVALENCE FOR LOCAL ENVIRONMENTS **********************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma lleq_bind_repl_O: ∀I,L1,L2,V,T. L1.ⓑ{I}V ≡[T, 0] L2.ⓑ{I}V →
  23                         ∀J,W. L1 ≡[W, 0] L2 → L1.ⓑ{J}W ≡[T, 0] L2.ⓑ{J}W.
  24 /2 width=7 by llpx_sn_bind_repl_O/ qed-.
  25
  26 lemma lleq_dec: ∀T,L1,L2,l. Decidable (L1 ≡[T, l] L2).
  27 /3 width=1 by llpx_sn_dec, eq_term_dec/ qed-.
  28
  29 lemma lleq_llpx_sn_trans: ∀R. lleq_transitive R →
  30                           ∀L1,L2,T,l. L1 ≡[T, l] L2 →
  31                           ∀L. llpx_sn R l T L2 L → llpx_sn R l T L1 L.
  32 #R #HR #L1 #L2 #T #l #H @(lleq_ind … H) -L1 -L2 -T -l
  33 [1,2,5: /4 width=6 by llpx_sn_fwd_length, llpx_sn_gref, llpx_sn_skip, llpx_sn_sort, trans_eq/
  34 |4: /4 width=6 by llpx_sn_fwd_length, llpx_sn_free, le_repl_sn_conf_aux, trans_eq/
  35 | #I #L1 #L2 #K1 #K2 #V #l #i #Hli #HLK1 #HLK2 #HK12 #IHK12 #L #H elim (llpx_sn_inv_lref_ge_sn … H … HLK2) -H -HLK2
  36   /3 width=11 by llpx_sn_lref/
  37 | #a #I #L1 #L2 #V #T #l #_ #_ #IHV #IHT #L #H elim (llpx_sn_inv_bind … H) -H
  38   /3 width=1 by llpx_sn_bind/
  39 | #I #L1 #L2 #V #T #l #_ #_ #IHV #IHT #L #H elim (llpx_sn_inv_flat … H) -H
  40   /3 width=1 by llpx_sn_flat/
  41 ]
  42 qed-.
  43
  44 lemma lleq_llpx_sn_conf: ∀R. lleq_transitive R →
  45                          ∀L1,L2,T,l. L1 ≡[T, l] L2 →
  46                          ∀L. llpx_sn R l T L1 L → llpx_sn R l T L2 L.
  47 /3 width=3 by lleq_llpx_sn_trans, lleq_sym/ qed-.
  48
  49 (* Advanced inversion lemmas ************************************************)
  50
  51 lemma lleq_inv_lref_ge_dx: ∀L1,L2,l,i. L1 ≡[#i, l] L2 → l ≤ i →
  52                            ∀I,K2,V. ⬇[i] L2 ≡ K2.ⓑ{I}V →
  53                            ∃∃K1. ⬇[i] L1 ≡ K1.ⓑ{I}V & K1 ≡[V, 0] K2.
  54 #L1 #L2 #l #i #H #Hli #I #K2 #V #HLK2 elim (llpx_sn_inv_lref_ge_dx … H … HLK2) -L2
  55 /2 width=3 by ex2_intro/
  56 qed-.
  57
  58 lemma lleq_inv_lref_ge_sn: ∀L1,L2,l,i. L1 ≡[#i, l] L2 → l ≤ i →
  59                            ∀I,K1,V. ⬇[i] L1 ≡ K1.ⓑ{I}V →
  60                            ∃∃K2. ⬇[i] L2 ≡ K2.ⓑ{I}V & K1 ≡[V, 0] K2.
  61 #L1 #L2 #l #i #H #Hli #I1 #K1 #V #HLK1 elim (llpx_sn_inv_lref_ge_sn … H … HLK1) -L1
  62 /2 width=3 by ex2_intro/
  63 qed-.
  64
  65 lemma lleq_inv_lref_ge_bi: ∀L1,L2,l,i. L1 ≡[#i, l] L2 → l ≤ i →
  66                            ∀I1,I2,K1,K2,V1,V2.
  67                            ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
  68                            ∧∧ I1 = I2 & K1 ≡[V1, 0] K2 & V1 = V2.
  69 /2 width=8 by llpx_sn_inv_lref_ge_bi/ qed-.
  70
  71 lemma lleq_inv_lref_ge: ∀L1,L2,l,i. L1 ≡[#i, l] L2 → l ≤ i →
  72                         ∀I,K1,K2,V. ⬇[i] L1 ≡ K1.ⓑ{I}V → ⬇[i] L2 ≡ K2.ⓑ{I}V →
  73                         K1 ≡[V, 0] K2.
  74 #L1 #L2 #l #i #HL12 #Hli #I #K1 #K2 #V #HLK1 #HLK2
  75 elim (lleq_inv_lref_ge_bi … HL12 … HLK1 HLK2) //
  76 qed-.
  77
  78 lemma lleq_inv_S: ∀L1,L2,T,l. L1 ≡[T, l+1] L2 →
  79                   ∀I,K1,K2,V. ⬇[l] L1 ≡ K1.ⓑ{I}V → ⬇[l] L2 ≡ K2.ⓑ{I}V →
  80                   K1 ≡[V, 0] K2 → L1 ≡[T, l] L2.
  81 /2 width=9 by llpx_sn_inv_S/ qed-.
  82
  83 lemma lleq_inv_bind_O: ∀a,I,L1,L2,V,T. L1 ≡[ⓑ{a,I}V.T, 0] L2 →
  84                        L1 ≡[V, 0] L2 ∧ L1.ⓑ{I}V ≡[T, 0] L2.ⓑ{I}V.
  85 /2 width=2 by llpx_sn_inv_bind_O/ qed-.
  86
  87 (* Advanced forward lemmas **************************************************)
  88
  89 lemma lleq_fwd_lref_dx: ∀L1,L2,l,i. L1 ≡[#i, l] L2 →
  90                         ∀I,K2,V. ⬇[i] L2 ≡ K2.ⓑ{I}V →
  91                         i < l ∨
  92                         ∃∃K1. ⬇[i] L1 ≡ K1.ⓑ{I}V & K1 ≡[V, 0] K2 & l ≤ i.
  93 #L1 #L2 #l #i #H #I #K2 #V #HLK2 elim (llpx_sn_fwd_lref_dx … H … HLK2) -L2
  94 [ | * ] /3 width=3 by ex3_intro, or_intror, or_introl/
  95 qed-.
  96
  97 lemma lleq_fwd_lref_sn: ∀L1,L2,l,i. L1 ≡[#i, l] L2 →
  98                         ∀I,K1,V. ⬇[i] L1 ≡ K1.ⓑ{I}V →
  99                         i < l ∨
 100                         ∃∃K2. ⬇[i] L2 ≡ K2.ⓑ{I}V & K1 ≡[V, 0] K2 & l ≤ i.
 101 #L1 #L2 #l #i #H #I #K1 #V #HLK1 elim (llpx_sn_fwd_lref_sn … H … HLK1) -L1
 102 [ | * ] /3 width=3 by ex3_intro, or_intror, or_introl/
 103 qed-.
 104
 105 lemma lleq_fwd_bind_O_dx: ∀a,I,L1,L2,V,T. L1 ≡[ⓑ{a,I}V.T, 0] L2 →
 106                           L1.ⓑ{I}V ≡[T, 0] L2.ⓑ{I}V.
 107 /2 width=2 by llpx_sn_fwd_bind_O_dx/ qed-.
 108
 109 (* Properties on relocation *************************************************)
 110
 111 lemma lleq_lift_le: ∀K1,K2,T,lt. K1 ≡[T, lt] K2 →
 112                     ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 113                     ∀U. ⬆[l, m] T ≡ U → lt ≤ l → L1 ≡[U, lt] L2.
 114 /3 width=10 by llpx_sn_lift_le, lift_mono/ qed-.
 115
 116 lemma lleq_lift_ge: ∀K1,K2,T,lt. K1 ≡[T, lt] K2 →
 117                     ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 118                     ∀U. ⬆[l, m] T ≡ U → l ≤ lt → L1 ≡[U, lt+m] L2.
 119 /2 width=9 by llpx_sn_lift_ge/ qed-.
 120
 121 (* Inversion lemmas on relocation *******************************************)
 122
 123 lemma lleq_inv_lift_le: ∀L1,L2,U,lt. L1 ≡[U, lt] L2 →
 124                         ∀K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 125                         ∀T. ⬆[l, m] T ≡ U → lt ≤ l → K1 ≡[T, lt] K2.
 126 /3 width=10 by llpx_sn_inv_lift_le, ex2_intro/ qed-.
 127
 128 lemma lleq_inv_lift_be: ∀L1,L2,U,lt. L1 ≡[U, lt] L2 →
 129                         ∀K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 130                         ∀T. ⬆[l, m] T ≡ U → l ≤ lt → lt ≤ yinj l + m → K1 ≡[T, l] K2.
 131 /2 width=11 by llpx_sn_inv_lift_be/ qed-.
 132
 133 lemma lleq_inv_lift_ge: ∀L1,L2,U,lt. L1 ≡[U, lt] L2 →
 134                         ∀K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 135                         ∀T. ⬆[l, m] T ≡ U → yinj l + m ≤ lt → K1 ≡[T, lt-m] K2.
 136 /2 width=9 by llpx_sn_inv_lift_ge/ qed-.
 137
 138 (* Inversion lemmas on negated lazy quivalence for local environments *******)
 139
 140 lemma nlleq_inv_bind: ∀a,I,L1,L2,V,T,l. (L1 ≡[ⓑ{a,I}V.T, l] L2 → ⊥) →
 141                       (L1 ≡[V, l] L2 → ⊥) ∨ (L1.ⓑ{I}V ≡[T, ⫯l] L2.ⓑ{I}V → ⊥).
 142 /3 width=2 by nllpx_sn_inv_bind, eq_term_dec/ qed-.
 143
 144 lemma nlleq_inv_flat: ∀I,L1,L2,V,T,l. (L1 ≡[ⓕ{I}V.T, l] L2 → ⊥) →
 145                       (L1 ≡[V, l] L2 → ⊥) ∨ (L1 ≡[T, l] L2 → ⊥).
 146 /3 width=2 by nllpx_sn_inv_flat, eq_term_dec/ qed-.
 147
 148 lemma nlleq_inv_bind_O: ∀a,I,L1,L2,V,T. (L1 ≡[ⓑ{a,I}V.T, 0] L2 → ⊥) →
 149                         (L1 ≡[V, 0] L2 → ⊥) ∨ (L1.ⓑ{I}V ≡[T, 0] L2.ⓑ{I}V → ⊥).
 150 /3 width=2 by nllpx_sn_inv_bind_O, eq_term_dec/ qed-.