matita/matita/contribs/lambdadelta/basic_2A/multiple/lleq_fqus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/multiple/fqus_alt.ma".
  16 include "basic_2A/multiple/lleq_drop.ma".
  17
  18 (* LAZY EQUIVALENCE FOR LOCAL ENVIRONMENTS **********************************)
  19
  20 (* Properties on supclosure *************************************************)
  21
  22 lemma lleq_fqu_trans: ∀G1,G2,L2,K2,T,U. ⦃G1, L2, T⦄ ⊐ ⦃G2, K2, U⦄ →
  23                       ∀L1. L1 ≡[T, 0] L2 →
  24                       ∃∃K1. ⦃G1, L1, T⦄ ⊐ ⦃G2, K1, U⦄ & K1 ≡[U, 0] K2.
  25 #G1 #G2 #L2 #K2 #T #U #H elim H -G1 -G2 -L2 -K2 -T -U
  26 [ #I #G #L2 #V #L1 #H elim (lleq_inv_lref_ge_dx … H … I L2 V) -H //
  27   #K1 #H1 #H2 lapply (drop_inv_O2 … H1) -H1
  28   #H destruct /2 width=3 by fqu_lref_O, ex2_intro/
  29 | * [ #a ] #I #G #L2 #V #T #L1 #H
  30   [ elim (lleq_inv_bind … H)
  31   | elim (lleq_inv_flat … H)
  32   ] -H
  33   /2 width=3 by fqu_pair_sn, ex2_intro/
  34 | #a #I #G #L2 #V #T #L1 #H elim (lleq_inv_bind_O … H) -H
  35   #H3 #H4 /2 width=3 by fqu_bind_dx, ex2_intro/
  36 | #I #G #L2 #V #T #L1 #H elim (lleq_inv_flat … H) -H
  37   /2 width=3 by fqu_flat_dx, ex2_intro/
  38 | #G #L2 #K2 #T #U #m #HLK2 #HTU #L1 #HL12
  39   elim (drop_O1_le (Ⓕ) (m+1) L1)
  40   [ /3 width=12 by fqu_drop, lleq_inv_lift_le, ex2_intro/
  41   | lapply (drop_fwd_length_le2 … HLK2) -K2
  42     lapply (lleq_fwd_length … HL12) -T -U //
  43   ]
  44 ]
  45 qed-.
  46
  47 lemma lleq_fquq_trans: ∀G1,G2,L2,K2,T,U. ⦃G1, L2, T⦄ ⊐⸮ ⦃G2, K2, U⦄ →
  48                        ∀L1. L1 ≡[T, 0] L2 →
  49                        ∃∃K1. ⦃G1, L1, T⦄ ⊐⸮ ⦃G2, K1, U⦄ & K1 ≡[U, 0] K2.
  50 #G1 #G2 #L2 #K2 #T #U #H #L1 #HL12 elim(fquq_inv_gen … H) -H
  51 [ #H elim (lleq_fqu_trans … H … HL12) -L2 /3 width=3 by fqu_fquq, ex2_intro/
  52 | * #HG #HL #HT destruct /2 width=3 by ex2_intro/
  53 ]
  54 qed-.
  55
  56 lemma lleq_fqup_trans: ∀G1,G2,L2,K2,T,U. ⦃G1, L2, T⦄ ⊐+ ⦃G2, K2, U⦄ →
  57                        ∀L1. L1 ≡[T, 0] L2 →
  58                        ∃∃K1. ⦃G1, L1, T⦄ ⊐+ ⦃G2, K1, U⦄ & K1 ≡[U, 0] K2.
  59 #G1 #G2 #L2 #K2 #T #U #H @(fqup_ind … H) -G2 -K2 -U
  60 [ #G2 #K2 #U #HTU #L1 #HL12 elim (lleq_fqu_trans … HTU … HL12) -L2
  61   /3 width=3 by fqu_fqup, ex2_intro/
  62 | #G #G2 #K #K2 #U #U2 #_ #HU2 #IHTU #L1 #HL12 elim (IHTU … HL12) -L2
  63   #K1 #HTU #HK1 elim (lleq_fqu_trans … HU2 … HK1) -K
  64   /3 width=5 by fqup_strap1, ex2_intro/
  65 ]
  66 qed-.
  67
  68 lemma lleq_fqus_trans: ∀G1,G2,L2,K2,T,U. ⦃G1, L2, T⦄ ⊐* ⦃G2, K2, U⦄ →
  69                        ∀L1. L1 ≡[T, 0] L2 →
  70                        ∃∃K1. ⦃G1, L1, T⦄ ⊐* ⦃G2, K1, U⦄ & K1 ≡[U, 0] K2.
  71 #G1 #G2 #L2 #K2 #T #U #H #L1 #HL12 elim(fqus_inv_gen … H) -H
  72 [ #H elim (lleq_fqup_trans … H … HL12) -L2 /3 width=3 by fqup_fqus, ex2_intro/
  73 | * #HG #HL #HT destruct /2 width=3 by ex2_intro/
  74 ]
  75 qed-.