matita/matita/contribs/lambdadelta/basic_2A/multiple/llor_drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/multiple/frees_lift.ma".
  16 include "basic_2A/multiple/llor_alt.ma".
  17
  18 (* POINTWISE UNION FOR LOCAL ENVIRONMENTS ***********************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma llor_skip: ∀L1,L2,U,l. |L1| = |L2| → yinj (|L1|) ≤ l → L1 ⋓[U, l] L2 ≡ L1.
  23 #L1 #L2 #U #l #HL12 #Hl @and3_intro // -HL12
  24 #I1 #I2 #I #K1 #K2 #K #W1 #W2 #W #i #HLK1 #_ #HLK -L2 -K2
  25 lapply (drop_mono … HLK … HLK1) -HLK #H destruct
  26 lapply (drop_fwd_length_lt2 … HLK1) -K1
  27 /5 width=3 by ylt_yle_trans, ylt_inj, or3_intro0, and3_intro/
  28 qed.
  29
  30 (* Note: lemma 1400 concludes the "big tree" theorem *)
  31 lemma llor_total: ∀L1,L2,T,l. |L1| = |L2| → ∃L. L1 ⋓[T, l] L2 ≡ L.
  32 #L1 @(lenv_ind_alt … L1) -L1
  33 [ #L2 #T #l #H >(length_inv_zero_sn … H) -L2 /2 width=2 by ex_intro/
  34 | #I1 #L1 #V1 #IHL1 #Y #T #l >ltail_length #H
  35   elim (length_inv_pos_sn_ltail … H) -H #I2 #L2 #V2 #HL12 #H destruct
  36   elim (ylt_split l (|ⓑ{I1}V1.L1|))
  37   [ elim (frees_dec (ⓑ{I1}V1.L1) T l (|L1|)) #HnU
  38     elim (IHL1 L2 T l) // -IHL1 -HL12
  39     [ #L #HL12 >ltail_length /4 width=2 by llor_tail_frees, ylt_fwd_succ2, ex_intro/
  40     | /4 width=2 by llor_tail_cofrees, ex_intro/
  41     ]
  42   | -IHL1 /4 width=2 by llor_skip, plus_minus_m_m, ex_intro/
  43   ]
  44 ]
  45 qed-.