matita/matita/contribs/lambdadelta/basic_2A/multiple/llpx_sn_alt_rec.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/lift_neg.ma".
  16 include "basic_2A/substitution/drop_drop.ma".
  17 include "basic_2A/multiple/llpx_sn.ma".
  18
  19 (* LAZY SN POINTWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS ****)
  20
  21 (* alternative definition of llpx_sn (recursive) *)
  22 inductive llpx_sn_alt_r (R:relation3 lenv term term): relation4 ynat term lenv lenv ≝
  23 | llpx_sn_alt_r_intro: ∀L1,L2,T,l.
  24                        (∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
  25                           ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 → I1 = I2 ∧ R K1 V1 V2
  26                        ) →
  27                        (∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
  28                           ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 → llpx_sn_alt_r R 0 V1 K1 K2
  29                        ) → |L1| = |L2| → llpx_sn_alt_r R l T L1 L2
  30 .
  31
  32 (* Compact definition of llpx_sn_alt_r **************************************)
  33
  34 lemma llpx_sn_alt_r_intro_alt: ∀R,L1,L2,T,l. |L1| = |L2| →
  35                                (∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
  36                                  ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
  37                                  ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn_alt_r R 0 V1 K1 K2
  38                                ) → llpx_sn_alt_r R l T L1 L2.
  39 #R #L1 #L2 #T #l #HL12 #IH @llpx_sn_alt_r_intro // -HL12
  40 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
  41 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /2 width=1 by conj/
  42 qed.
  43
  44 lemma llpx_sn_alt_r_ind_alt: ∀R. ∀S:relation4 ynat term lenv lenv.
  45                              (∀L1,L2,T,l. |L1| = |L2| → (
  46                                 ∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
  47                                 ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
  48                                 ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn_alt_r R 0 V1 K1 K2 & S 0 V1 K1 K2
  49                              ) → S l T L1 L2) →
  50                              ∀L1,L2,T,l. llpx_sn_alt_r R l T L1 L2 → S l T L1 L2.
  51 #R #S #IH #L1 #L2 #T #l #H elim H -L1 -L2 -T -l
  52 #L1 #L2 #T #l #H1 #H2 #HL12 #IH2 @IH -IH // -HL12
  53 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
  54 elim (H1 … HnT HLK1 HLK2) -H1 /4 width=8 by and4_intro/
  55 qed-.
  56
  57 lemma llpx_sn_alt_r_inv_alt: ∀R,L1,L2,T,l. llpx_sn_alt_r R l T L1 L2 →
  58                              |L1| = |L2| ∧
  59                              ∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
  60                                ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
  61                              ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn_alt_r R 0 V1 K1 K2.
  62 #R #L1 #L2 #T #l #H @(llpx_sn_alt_r_ind_alt … H) -L1 -L2 -T -l
  63 #L1 #L2 #T #l #HL12 #IH @conj // -HL12
  64 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
  65 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /2 width=1 by and3_intro/
  66 qed-.
  67
  68 (* Basic inversion lemmas ***************************************************)
  69
  70 lemma llpx_sn_alt_r_inv_flat: ∀R,I,L1,L2,V,T,l. llpx_sn_alt_r R l (ⓕ{I}V.T) L1 L2 →
  71                               llpx_sn_alt_r R l V L1 L2 ∧ llpx_sn_alt_r R l T L1 L2.
  72 #R #I #L1 #L2 #V #T #l #H elim (llpx_sn_alt_r_inv_alt … H) -H
  73 #HL12 #IH @conj @llpx_sn_alt_r_intro_alt // -HL12
  74 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hli #H #HLK1 #HLK2
  75 elim (IH … HLK1 HLK2) -IH -HLK1 -HLK2 //
  76 /3 width=8 by nlift_flat_sn, nlift_flat_dx, and3_intro/
  77 qed-.
  78
  79 lemma llpx_sn_alt_r_inv_bind: ∀R,a,I,L1,L2,V,T,l. llpx_sn_alt_r R l (ⓑ{a,I}V.T) L1 L2 →
  80                               llpx_sn_alt_r R l V L1 L2 ∧ llpx_sn_alt_r R (⫯l) T (L1.ⓑ{I}V) (L2.ⓑ{I}V).
  81 #R #a #I #L1 #L2 #V #T #l #H elim (llpx_sn_alt_r_inv_alt … H) -H
  82 #HL12 #IH @conj @llpx_sn_alt_r_intro_alt [1,3: normalize // ] -HL12
  83 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hli #H #HLK1 #HLK2
  84 [ elim (IH … HLK1 HLK2) -IH -HLK1 -HLK2
  85   /3 width=9 by nlift_bind_sn, and3_intro/
  86 | lapply (yle_inv_succ1 … Hli) -Hli * #Hli #Hi
  87   lapply (drop_inv_drop1_lt … HLK1 ?) -HLK1 /2 width=1 by ylt_O/ #HLK1
  88   lapply (drop_inv_drop1_lt … HLK2 ?) -HLK2 /2 width=1 by ylt_O/ #HLK2
  89   elim (IH … HLK1 HLK2) -IH -HLK1 -HLK2 /2 width=1 by and3_intro/
  90   @nlift_bind_dx <plus_minus_m_m /2 width=2 by ylt_O/
  91 ]
  92 qed-.
  93
  94 (* Basic forward lemmas *****************************************************)
  95
  96 lemma llpx_sn_alt_r_fwd_length: ∀R,L1,L2,T,l. llpx_sn_alt_r R l T L1 L2 → |L1| = |L2|.
  97 #R #L1 #L2 #T #l #H elim (llpx_sn_alt_r_inv_alt … H) -H //
  98 qed-.
  99
 100 lemma llpx_sn_alt_r_fwd_lref: ∀R,L1,L2,l,i. llpx_sn_alt_r R l (#i) L1 L2 →
 101                               ∨∨ |L1| ≤ i ∧ |L2| ≤ i
 102                                | yinj i < l
 103                                | ∃∃I,K1,K2,V1,V2. ⬇[i] L1 ≡ K1.ⓑ{I}V1 &
 104                                                   ⬇[i] L2 ≡ K2.ⓑ{I}V2 &
 105                                                   llpx_sn_alt_r R (yinj 0) V1 K1 K2 &
 106                                                   R K1 V1 V2 & l ≤ yinj i.
 107 #R #L1 #L2 #l #i #H elim (llpx_sn_alt_r_inv_alt … H) -H
 108 #HL12 #IH elim (lt_or_ge i (|L1|)) /3 width=1 by or3_intro0, conj/
 109 elim (ylt_split i l) /3 width=1 by or3_intro1/
 110 #Hli #HL1 elim (drop_O1_lt (Ⓕ) … HL1)
 111 #I1 #K1 #V1 #HLK1 elim (drop_O1_lt (Ⓕ) L2 i) //
 112 #I2 #K2 #V2 #HLK2 elim (IH … HLK1 HLK2) -IH
 113 /3 width=9 by nlift_lref_be_SO, or3_intro2, ex5_5_intro/
 114 qed-.
 115
 116 (* Basic properties *********************************************************)
 117
 118 lemma llpx_sn_alt_r_sort: ∀R,L1,L2,l,k. |L1| = |L2| → llpx_sn_alt_r R l (⋆k) L1 L2.
 119 #R #L1 #L2 #l #k #HL12 @llpx_sn_alt_r_intro_alt // -HL12
 120 #I1 #I2 #K1 #K2 #V1 #V2 #i #_ #H elim (H (⋆k)) //
 121 qed.
 122
 123 lemma llpx_sn_alt_r_gref: ∀R,L1,L2,l,p. |L1| = |L2| → llpx_sn_alt_r R l (§p) L1 L2.
 124 #R #L1 #L2 #l #p #HL12 @llpx_sn_alt_r_intro_alt // -HL12
 125 #I1 #I2 #K1 #K2 #V1 #V2 #i #_ #H elim (H (§p)) //
 126 qed.
 127
 128 lemma llpx_sn_alt_r_skip: ∀R,L1,L2,l,i. |L1| = |L2| → yinj i < l → llpx_sn_alt_r R l (#i) L1 L2.
 129 #R #L1 #L2 #l #i #HL12 #Hil @llpx_sn_alt_r_intro_alt // -HL12
 130 #I1 #I2 #K1 #K2 #V1 #V2 #j #Hlj #H elim (H (#i)) -H
 131 /4 width=3 by lift_lref_lt, ylt_yle_trans, ylt_inv_inj/
 132 qed.
 133
 134 lemma llpx_sn_alt_r_free: ∀R,L1,L2,l,i. |L1| ≤ i → |L2| ≤ i → |L1| = |L2| →
 135                           llpx_sn_alt_r R l (#i) L1 L2.
 136 #R #L1 #L2 #l #i #HL1 #_ #HL12 @llpx_sn_alt_r_intro_alt // -HL12
 137 #I1 #I2 #K1 #K2 #V1 #V2 #j #_ #H #HLK1 elim (H (#(i-1))) -H
 138 lapply (drop_fwd_length_lt2 … HLK1) -HLK1
 139 /3 width=3 by lift_lref_ge_minus, lt_to_le_to_lt/
 140 qed.
 141
 142 lemma llpx_sn_alt_r_lref: ∀R,I,L1,L2,K1,K2,V1,V2,l,i. l ≤ yinj i →
 143                           ⬇[i] L1 ≡ K1.ⓑ{I}V1 → ⬇[i] L2 ≡ K2.ⓑ{I}V2 →
 144                           llpx_sn_alt_r R 0 V1 K1 K2 → R K1 V1 V2 →
 145                           llpx_sn_alt_r R l (#i) L1 L2.
 146 #R #I #L1 #L2 #K1 #K2 #V1 #V2 #l #i #Hli #HLK1 #HLK2 #HK12 #HV12 @llpx_sn_alt_r_intro_alt
 147 [ lapply (llpx_sn_alt_r_fwd_length … HK12) -HK12 #HK12
 148   @(drop_fwd_length_eq2 … HLK1 HLK2) normalize //
 149 | #Z1 #Z2 #Y1 #Y2 #X1 #X2 #j #Hlj #H #HLY1 #HLY2
 150   elim (lt_or_eq_or_gt i j) #Hij destruct
 151   [ elim (H (#i)) -H /2 width=1 by lift_lref_lt/
 152   | lapply (drop_mono … HLY1 … HLK1) -HLY1 -HLK1 #H destruct
 153     lapply (drop_mono … HLY2 … HLK2) -HLY2 -HLK2 #H destruct /2 width=1 by and3_intro/
 154   | elim (H (#(i-1))) -H /2 width=1 by lift_lref_ge_minus/
 155   ]
 156 ]
 157 qed.
 158
 159 lemma llpx_sn_alt_r_flat: ∀R,I,L1,L2,V,T,l.
 160                           llpx_sn_alt_r R l V L1 L2 → llpx_sn_alt_r R l T L1 L2 →
 161                           llpx_sn_alt_r R l (ⓕ{I}V.T) L1 L2.
 162 #R #I #L1 #L2 #V #T #l #HV #HT
 163 elim (llpx_sn_alt_r_inv_alt … HV) -HV #HL12 #IHV
 164 elim (llpx_sn_alt_r_inv_alt … HT) -HT #_ #IHT
 165 @llpx_sn_alt_r_intro_alt // -HL12
 166 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hli #HnVT #HLK1 #HLK2
 167 elim (nlift_inv_flat … HnVT) -HnVT #H
 168 [ elim (IHV … HLK1 … HLK2) -IHV /2 width=2 by and3_intro/
 169 | elim (IHT … HLK1 … HLK2) -IHT /3 width=2 by and3_intro/
 170 ]
 171 qed.
 172
 173 lemma llpx_sn_alt_r_bind: ∀R,a,I,L1,L2,V,T,l.
 174                           llpx_sn_alt_r R l V L1 L2 →
 175                           llpx_sn_alt_r R (⫯l) T (L1.ⓑ{I}V) (L2.ⓑ{I}V) →
 176                           llpx_sn_alt_r R l (ⓑ{a,I}V.T) L1 L2.
 177 #R #a #I #L1 #L2 #V #T #l #HV #HT
 178 elim (llpx_sn_alt_r_inv_alt … HV) -HV #HL12 #IHV
 179 elim (llpx_sn_alt_r_inv_alt … HT) -HT #_ #IHT
 180 @llpx_sn_alt_r_intro_alt // -HL12
 181 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hli #HnVT #HLK1 #HLK2
 182 elim (nlift_inv_bind … HnVT) -HnVT #H
 183 [ elim (IHV … HLK1 … HLK2) -IHV /2 width=2 by and3_intro/
 184 | elim IHT -IHT /2 width=12 by drop_drop, yle_succ, and3_intro/
 185 ]
 186 qed.
 187
 188 (* Main properties **********************************************************)
 189
 190 theorem llpx_sn_lpx_sn_alt_r: ∀R,L1,L2,T,l. llpx_sn R l T L1 L2 → llpx_sn_alt_r R l T L1 L2.
 191 #R #L1 #L2 #T #l #H elim H -L1 -L2 -T -l
 192 /2 width=9 by llpx_sn_alt_r_sort, llpx_sn_alt_r_gref, llpx_sn_alt_r_skip, llpx_sn_alt_r_free, llpx_sn_alt_r_lref, llpx_sn_alt_r_flat, llpx_sn_alt_r_bind/
 193 qed.
 194
 195 (* Main inversion lemmas ****************************************************)
 196
 197 theorem llpx_sn_alt_r_inv_lpx_sn: ∀R,T,L1,L2,l. llpx_sn_alt_r R l T L1 L2 → llpx_sn R l T L1 L2.
 198 #R #T #L1 @(f2_ind … rfw … L1 T) -L1 -T #x #IH #L1 * *
 199 [1,3: /3 width=4 by llpx_sn_alt_r_fwd_length, llpx_sn_gref, llpx_sn_sort/
 200 | #i #Hx #L2 #l #H lapply (llpx_sn_alt_r_fwd_length … H)
 201   #HL12 elim (llpx_sn_alt_r_fwd_lref … H) -H
 202   [ * /2 width=1 by llpx_sn_free/
 203   | /2 width=1 by llpx_sn_skip/
 204   | * /4 width=9 by llpx_sn_lref, drop_fwd_rfw/
 205   ]
 206 | #a #I #V #T #Hx #L2 #l #H elim (llpx_sn_alt_r_inv_bind … H) -H
 207   /3 width=1 by llpx_sn_bind/
 208 | #I #V #T #Hx #L2 #l #H elim (llpx_sn_alt_r_inv_flat … H) -H
 209   /3 width=1 by llpx_sn_flat/
 210 ]
 211 qed-.
 212
 213 (* Alternative definition of llpx_sn (recursive) ****************************)
 214
 215 lemma llpx_sn_intro_alt_r: ∀R,L1,L2,T,l. |L1| = |L2| →
 216                            (∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
 217                               ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
 218                               ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn R 0 V1 K1 K2
 219                            ) → llpx_sn R l T L1 L2.
 220 #R #L1 #L2 #T #l #HL12 #IH @llpx_sn_alt_r_inv_lpx_sn
 221 @llpx_sn_alt_r_intro_alt // -HL12
 222 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
 223 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /3 width=1 by llpx_sn_lpx_sn_alt_r, and3_intro/
 224 qed.
 225
 226 lemma llpx_sn_ind_alt_r: ∀R. ∀S:relation4 ynat term lenv lenv.
 227                          (∀L1,L2,T,l. |L1| = |L2| → (
 228                             ∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
 229                             ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
 230                             ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn R 0 V1 K1 K2 & S 0 V1 K1 K2
 231                          ) → S l T L1 L2) →
 232                          ∀L1,L2,T,l. llpx_sn R l T L1 L2 → S l T L1 L2.
 233 #R #S #IH1 #L1 #L2 #T #l #H lapply (llpx_sn_lpx_sn_alt_r … H) -H
 234 #H @(llpx_sn_alt_r_ind_alt … H) -L1 -L2 -T -l
 235 #L1 #L2 #T #l #HL12 #IH2 @IH1 -IH1 // -HL12
 236 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
 237 elim (IH2 … HnT HLK1 HLK2) -IH2 -HnT -HLK1 -HLK2 /3 width=1 by llpx_sn_alt_r_inv_lpx_sn, and4_intro/
 238 qed-.
 239
 240 lemma llpx_sn_inv_alt_r: ∀R,L1,L2,T,l. llpx_sn R l T L1 L2 →
 241                          |L1| = |L2| ∧
 242                          ∀I1,I2,K1,K2,V1,V2,i. l ≤ yinj i → (∀U. ⬆[i, 1] U ≡ T → ⊥) →
 243                          ⬇[i] L1 ≡ K1.ⓑ{I1}V1 → ⬇[i] L2 ≡ K2.ⓑ{I2}V2 →
 244                          ∧∧ I1 = I2 & R K1 V1 V2 & llpx_sn R 0 V1 K1 K2.
 245 #R #L1 #L2 #T #l #H lapply (llpx_sn_lpx_sn_alt_r … H) -H
 246 #H elim (llpx_sn_alt_r_inv_alt … H) -H
 247 #HL12 #IH @conj //
 248 #I1 #I2 #K1 #K2 #V1 #V2 #i #Hil #HnT #HLK1 #HLK2
 249 elim (IH … HnT HLK1 HLK2) -IH -HnT -HLK1 -HLK2 /3 width=1 by llpx_sn_alt_r_inv_lpx_sn, and3_intro/
 250 qed-.