matita/matita/contribs/lambdadelta/basic_2A/multiple/mr2.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/rat_3.ma".
  16 include "basic_2A/grammar/term_vector.ma".
  17
  18 (* MULTIPLE RELOCATION WITH PAIRS *******************************************)
  19
  20 inductive at: list2 nat nat → relation nat ≝
  21 | at_nil: ∀i. at (◊) i i
  22 | at_lt : ∀cs,l,m,i1,i2. i1 < l →
  23           at cs i1 i2 → at ({l, m} @ cs) i1 i2
  24 | at_ge : ∀cs,l,m,i1,i2. l ≤ i1 →
  25           at cs (i1 + m) i2 → at ({l, m} @ cs) i1 i2
  26 .
  27
  28 interpretation "application (multiple relocation with pairs)"
  29    'RAt i1 cs i2 = (at cs i1 i2).
  30
  31 (* Basic inversion lemmas ***************************************************)
  32
  33 fact at_inv_nil_aux: ∀cs,i1,i2. @⦃i1, cs⦄ ≡ i2 → cs = ◊ → i1 = i2.
  34 #cs #i1 #i2 * -cs -i1 -i2
  35 [ //
  36 | #cs #l #m #i1 #i2 #_ #_ #H destruct
  37 | #cs #l #m #i1 #i2 #_ #_ #H destruct
  38 ]
  39 qed-.
  40
  41 lemma at_inv_nil: ∀i1,i2. @⦃i1, ◊⦄ ≡ i2 → i1 = i2.
  42 /2 width=3 by at_inv_nil_aux/ qed-.
  43
  44 fact at_inv_cons_aux: ∀cs,i1,i2. @⦃i1, cs⦄ ≡ i2 →
  45                       ∀l,m,cs0. cs = {l, m} @ cs0 →
  46                       i1 < l ∧ @⦃i1, cs0⦄ ≡ i2 ∨
  47                       l ≤ i1 ∧ @⦃i1 + m, cs0⦄ ≡ i2.
  48 #cs #i1 #i2 * -cs -i1 -i2
  49 [ #i #l #m #cs #H destruct
  50 | #cs1 #l1 #m1 #i1 #i2 #Hil1 #Hi12 #l2 #m2 #cs2 #H destruct /3 width=1 by or_introl, conj/
  51 | #cs1 #l1 #m1 #i1 #i2 #Hli1 #Hi12 #l2 #m2 #cs2 #H destruct /3 width=1 by or_intror, conj/
  52 ]
  53 qed-.
  54
  55 lemma at_inv_cons: ∀cs,l,m,i1,i2. @⦃i1, {l, m} @ cs⦄ ≡ i2 →
  56                    i1 < l ∧ @⦃i1, cs⦄ ≡ i2 ∨
  57                    l ≤ i1 ∧ @⦃i1 + m, cs⦄ ≡ i2.
  58 /2 width=3 by at_inv_cons_aux/ qed-.
  59
  60 lemma at_inv_cons_lt: ∀cs,l,m,i1,i2. @⦃i1, {l, m} @ cs⦄ ≡ i2 →
  61                       i1 < l → @⦃i1, cs⦄ ≡ i2.
  62 #cs #l #m #i1 #m2 #H
  63 elim (at_inv_cons … H) -H * // #Hli1 #_ #Hi1l
  64 lapply (le_to_lt_to_lt … Hli1 Hi1l) -Hli1 -Hi1l #Hl
  65 elim (lt_refl_false … Hl)
  66 qed-.
  67
  68 lemma at_inv_cons_ge: ∀cs,l,m,i1,i2. @⦃i1, {l, m} @ cs⦄ ≡ i2 →
  69                       l ≤ i1 → @⦃i1 + m, cs⦄ ≡ i2.
  70 #cs #l #m #i1 #m2 #H
  71 elim (at_inv_cons … H) -H * // #Hi1l #_ #Hli1
  72 lapply (le_to_lt_to_lt … Hli1 Hi1l) -Hli1 -Hi1l #Hl
  73 elim (lt_refl_false … Hl)
  74 qed-.