matita/matita/contribs/lambdadelta/basic_2A/reduction/cpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/pred_4.ma".
  16 include "basic_2A/static/lsubr.ma".
  17 include "basic_2A/unfold/lstas.ma".
  18
  19 (* CONTEXT-SENSITIVE PARALLEL REDUCTION FOR TERMS ***************************)
  20
  21 (* activate genv *)
  22 (* Basic_1: includes: pr0_delta1 pr2_delta1 pr2_thin_dx *)
  23 (* Note: cpr_flat: does not hold in basic_1 *)
  24 inductive cpr: relation4 genv lenv term term ≝
  25 | cpr_atom : ∀I,G,L. cpr G L (⓪{I}) (⓪{I})
  26 | cpr_delta: ∀G,L,K,V,V2,W2,i.
  27              ⬇[i] L ≡ K. ⓓV → cpr G K V V2 →
  28              ⬆[0, i + 1] V2 ≡ W2 → cpr G L (#i) W2
  29 | cpr_bind : ∀a,I,G,L,V1,V2,T1,T2.
  30              cpr G L V1 V2 → cpr G (L.ⓑ{I}V1) T1 T2 →
  31              cpr G L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  32 | cpr_flat : ∀I,G,L,V1,V2,T1,T2.
  33              cpr G L V1 V2 → cpr G L T1 T2 →
  34              cpr G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  35 | cpr_zeta : ∀G,L,V,T1,T,T2. cpr G (L.ⓓV) T1 T →
  36              ⬆[0, 1] T2 ≡ T → cpr G L (+ⓓV.T1) T2
  37 | cpr_eps  : ∀G,L,V,T1,T2. cpr G L T1 T2 → cpr G L (ⓝV.T1) T2
  38 | cpr_beta : ∀a,G,L,V1,V2,W1,W2,T1,T2.
  39              cpr G L V1 V2 → cpr G L W1 W2 → cpr G (L.ⓛW1) T1 T2 →
  40              cpr G L (ⓐV1.ⓛ{a}W1.T1) (ⓓ{a}ⓝW2.V2.T2)
  41 | cpr_theta: ∀a,G,L,V1,V,V2,W1,W2,T1,T2.
  42              cpr G L V1 V → ⬆[0, 1] V ≡ V2 → cpr G L W1 W2 → cpr G (L.ⓓW1) T1 T2 →
  43              cpr G L (ⓐV1.ⓓ{a}W1.T1) (ⓓ{a}W2.ⓐV2.T2)
  44 .
  45
  46 interpretation "context-sensitive parallel reduction (term)"
  47    'PRed G L T1 T2 = (cpr G L T1 T2).
  48
  49 (* Basic properties *********************************************************)
  50
  51 lemma lsubr_cpr_trans: ∀G. lsub_trans … (cpr G) lsubr.
  52 #G #L1 #T1 #T2 #H elim H -G -L1 -T1 -T2
  53 [ //
  54 | #G #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  55   elim (lsubr_fwd_drop2_abbr … HL12 … HLK1) -L1 *
  56   /3 width=6 by cpr_delta/
  57 |3,7: /4 width=1 by lsubr_pair, cpr_bind, cpr_beta/
  58 |4,6: /3 width=1 by cpr_flat, cpr_eps/
  59 |5,8: /4 width=3 by lsubr_pair, cpr_zeta, cpr_theta/
  60 ]
  61 qed-.
  62
  63 (* Basic_1: was by definition: pr2_free *)
  64 lemma tpr_cpr: ∀G,T1,T2. ⦃G, ⋆⦄ ⊢ T1 ➡ T2 → ∀L. ⦃G, L⦄ ⊢ T1 ➡ T2.
  65 #G #T1 #T2 #HT12 #L
  66 lapply (lsubr_cpr_trans … HT12 L ?) //
  67 qed.
  68
  69 (* Basic_1: includes by definition: pr0_refl *)
  70 lemma cpr_refl: ∀G,T,L. ⦃G, L⦄ ⊢ T ➡ T.
  71 #G #T elim T -T // * /2 width=1 by cpr_bind, cpr_flat/
  72 qed.
  73
  74 (* Basic_1: was: pr2_head_1 *)
  75 lemma cpr_pair_sn: ∀I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡ V2 →
  76                    ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ➡ ②{I}V2.T.
  77 * /2 width=1 by cpr_bind, cpr_flat/ qed.
  78
  79 lemma cpr_delift: ∀G,K,V,T1,L,l. ⬇[l] L ≡ (K.ⓓV) →
  80                   ∃∃T2,T. ⦃G, L⦄ ⊢ T1 ➡ T2 & ⬆[l, 1] T ≡ T2.
  81 #G #K #V #T1 elim T1 -T1
  82 [ * /2 width=4 by cpr_atom, lift_sort, lift_gref, ex2_2_intro/
  83   #i #L #l #HLK elim (lt_or_eq_or_gt i l)
  84   #Hil [1,3: /3 width=4 by cpr_atom, lift_lref_ge_minus, lift_lref_lt, ex2_2_intro/ ]
  85   destruct
  86   elim (lift_total V 0 (i+1)) #W #HVW
  87   elim (lift_split … HVW i i) /3 width=6 by cpr_delta, ex2_2_intro/
  88 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #l #HLK
  89   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  90   [ elim (IHU1 (L. ⓑ{I}W1) (l+1)) -IHU1 /3 width=9 by drop_drop, cpr_bind, lift_bind, ex2_2_intro/
  91   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8 by cpr_flat, lift_flat, ex2_2_intro/
  92   ]
  93 ]
  94 qed-.
  95
  96 fact lstas_cpr_aux: ∀h,G,L,T1,T2,d. ⦃G, L⦄ ⊢ T1 •*[h, d] T2 →
  97                     d = 0 → ⦃G, L⦄ ⊢ T1 ➡ T2.
  98 #h #G #L #T1 #T2 #d #H elim H -G -L -T1 -T2 -d
  99 /3 width=1 by cpr_eps, cpr_flat, cpr_bind/
 100 [ #G #L #d #k #H0 destruct normalize //
 101 | #G #L #K #V1 #V2 #W2 #i #d #HLK #_ #HVW2 #IHV12 #H destruct
 102   /3 width=6 by cpr_delta/
 103 | #G #L #K #V1 #V2 #W2 #i #d #_ #_ #_ #_ <plus_n_Sm #H destruct
 104 ]
 105 qed-.
 106
 107 lemma lstas_cpr: ∀h,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 •*[h, 0] T2 → ⦃G, L⦄ ⊢ T1 ➡ T2.
 108 /2 width=4 by lstas_cpr_aux/ qed.
 109
 110 (* Basic inversion lemmas ***************************************************)
 111
 112 fact cpr_inv_atom1_aux: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ∀I. T1 = ⓪{I} →
 113                         T2 = ⓪{I} ∨
 114                         ∃∃K,V,V2,i. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 115                                     ⬆[O, i + 1] V2 ≡ T2 & I = LRef i.
 116 #G #L #T1 #T2 * -G -L -T1 -T2
 117 [ #I #G #L #J #H destruct /2 width=1 by or_introl/
 118 | #L #G #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #J #H destruct /3 width=8 by ex4_4_intro, or_intror/
 119 | #a #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 120 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 121 | #G #L #V #T1 #T #T2 #_ #_ #J #H destruct
 122 | #G #L #V #T1 #T2 #_ #J #H destruct
 123 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #J #H destruct
 124 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #J #H destruct
 125 ]
 126 qed-.
 127
 128 lemma cpr_inv_atom1: ∀I,G,L,T2. ⦃G, L⦄ ⊢ ⓪{I} ➡ T2 →
 129                      T2 = ⓪{I} ∨
 130                      ∃∃K,V,V2,i. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 131                                  ⬆[O, i + 1] V2 ≡ T2 & I = LRef i.
 132 /2 width=3 by cpr_inv_atom1_aux/ qed-.
 133
 134 (* Basic_1: includes: pr0_gen_sort pr2_gen_sort *)
 135 lemma cpr_inv_sort1: ∀G,L,T2,k. ⦃G, L⦄ ⊢ ⋆k ➡ T2 → T2 = ⋆k.
 136 #G #L #T2 #k #H
 137 elim (cpr_inv_atom1 … H) -H //
 138 * #K #V #V2 #i #_ #_ #_ #H destruct
 139 qed-.
 140
 141 (* Basic_1: includes: pr0_gen_lref pr2_gen_lref *)
 142 lemma cpr_inv_lref1: ∀G,L,T2,i. ⦃G, L⦄ ⊢ #i ➡ T2 →
 143                      T2 = #i ∨
 144                      ∃∃K,V,V2. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 145                                ⬆[O, i + 1] V2 ≡ T2.
 146 #G #L #T2 #i #H
 147 elim (cpr_inv_atom1 … H) -H /2 width=1 by or_introl/
 148 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6 by ex3_3_intro, or_intror/
 149 qed-.
 150
 151 lemma cpr_inv_gref1: ∀G,L,T2,p. ⦃G, L⦄ ⊢ §p ➡ T2 → T2 = §p.
 152 #G #L #T2 #p #H
 153 elim (cpr_inv_atom1 … H) -H //
 154 * #K #V #V2 #i #_ #_ #_ #H destruct
 155 qed-.
 156
 157 fact cpr_inv_bind1_aux: ∀G,L,U1,U2. ⦃G, L⦄ ⊢ U1 ➡ U2 →
 158                         ∀a,I,V1,T1. U1 = ⓑ{a,I}V1. T1 → (
 159                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡ T2 &
 160                                  U2 = ⓑ{a,I}V2.T2
 161                         ) ∨
 162                         ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T &
 163                              a = true & I = Abbr.
 164 #G #L #U1 #U2 * -L -U1 -U2
 165 [ #I #G #L #b #J #W1 #U1 #H destruct
 166 | #L #G #K #V #V2 #W2 #i #_ #_ #_ #b #J #W #U1 #H destruct
 167 | #a #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W #U1 #H destruct /3 width=5 by ex3_2_intro, or_introl/
 168 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W #U1 #H destruct
 169 | #G #L #V #T1 #T #T2 #HT1 #HT2 #b #J #W #U1 #H destruct /3 width=3 by ex4_intro, or_intror/
 170 | #G #L #V #T1 #T2 #_ #b #J #W #U1 #H destruct
 171 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #b #J #W #U1 #H destruct
 172 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #b #J #W #U1 #H destruct
 173 ]
 174 qed-.
 175
 176 lemma cpr_inv_bind1: ∀a,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡ U2 → (
 177                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡ T2 &
 178                               U2 = ⓑ{a,I}V2.T2
 179                      ) ∨
 180                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T &
 181                           a = true & I = Abbr.
 182 /2 width=3 by cpr_inv_bind1_aux/ qed-.
 183
 184 (* Basic_1: includes: pr0_gen_abbr pr2_gen_abbr *)
 185 lemma cpr_inv_abbr1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{a}V1.T1 ➡ U2 → (
 186                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L. ⓓV1⦄ ⊢ T1 ➡ T2 &
 187                               U2 = ⓓ{a}V2.T2
 188                      ) ∨
 189                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T & a = true.
 190 #a #G #L #V1 #T1 #U2 #H
 191 elim (cpr_inv_bind1 … H) -H *
 192 /3 width=5 by ex3_2_intro, ex3_intro, or_introl, or_intror/
 193 qed-.
 194
 195 (* Basic_1: includes: pr0_gen_abst pr2_gen_abst *)
 196 lemma cpr_inv_abst1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{a}V1.T1 ➡ U2 →
 197                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡ T2 &
 198                               U2 = ⓛ{a}V2.T2.
 199 #a #G #L #V1 #T1 #U2 #H
 200 elim (cpr_inv_bind1 … H) -H *
 201 [ /3 width=5 by ex3_2_intro/
 202 | #T #_ #_ #_ #H destruct
 203 ]
 204 qed-.
 205
 206 fact cpr_inv_flat1_aux: ∀G,L,U,U2. ⦃G, L⦄ ⊢ U ➡ U2 →
 207                         ∀I,V1,U1. U = ⓕ{I}V1.U1 →
 208                         ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 209                                     U2 = ⓕ{I} V2. T2
 210                          | (⦃G, L⦄ ⊢ U1 ➡ U2 ∧ I = Cast)
 211                          | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 212                                                ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 & U1 = ⓛ{a}W1.T1 &
 213                                                U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 214                          | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 215                                                  ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 216                                                  U1 = ⓓ{a}W1.T1 &
 217                                                  U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 218 #G #L #U #U2 * -L -U -U2
 219 [ #I #G #L #J #W1 #U1 #H destruct
 220 | #G #L #K #V #V2 #W2 #i #_ #_ #_ #J #W #U1 #H destruct
 221 | #a #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #W #U1 #H destruct
 222 | #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W #U1 #H destruct /3 width=5 by or4_intro0, ex3_2_intro/
 223 | #G #L #V #T1 #T #T2 #_ #_ #J #W #U1 #H destruct
 224 | #G #L #V #T1 #T2 #HT12 #J #W #U1 #H destruct /3 width=1 by or4_intro1, conj/
 225 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #J #W #U1 #H destruct /3 width=11 by or4_intro2, ex6_6_intro/
 226 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #J #W #U1 #H destruct /3 width=13 by or4_intro3, ex7_7_intro/
 227 ]
 228 qed-.
 229
 230 lemma cpr_inv_flat1: ∀I,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓕ{I}V1.U1 ➡ U2 →
 231                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 232                                  U2 = ⓕ{I}V2.T2
 233                       | (⦃G, L⦄ ⊢ U1 ➡ U2 ∧ I = Cast)
 234                       | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 235                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 & U1 = ⓛ{a}W1.T1 &
 236                                             U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 237                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 238                                               ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 239                                               U1 = ⓓ{a}W1.T1 &
 240                                               U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 241 /2 width=3 by cpr_inv_flat1_aux/ qed-.
 242
 243 (* Basic_1: includes: pr0_gen_appl pr2_gen_appl *)
 244 lemma cpr_inv_appl1: ∀G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐV1.U1 ➡ U2 →
 245                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 246                                  U2 = ⓐV2.T2
 247                       | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 248                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 &
 249                                             U1 = ⓛ{a}W1.T1 & U2 = ⓓ{a}ⓝW2.V2.T2
 250                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 251                                               ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 252                                               U1 = ⓓ{a}W1.T1 & U2 = ⓓ{a}W2.ⓐV2.T2.
 253 #G #L #V1 #U1 #U2 #H elim (cpr_inv_flat1 … H) -H *
 254 [ /3 width=5 by or3_intro0, ex3_2_intro/
 255 | #_ #H destruct
 256 | /3 width=11 by or3_intro1, ex5_6_intro/
 257 | /3 width=13 by or3_intro2, ex6_7_intro/
 258 ]
 259 qed-.
 260
 261 (* Note: the main property of simple terms *)
 262 lemma cpr_inv_appl1_simple: ∀G,L,V1,T1,U. ⦃G, L⦄ ⊢ ⓐV1. T1 ➡ U → 𝐒⦃T1⦄ →
 263                             ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ T1 ➡ T2 &
 264                                      U = ⓐV2. T2.
 265 #G #L #V1 #T1 #U #H #HT1
 266 elim (cpr_inv_appl1 … H) -H *
 267 [ /2 width=5 by ex3_2_intro/
 268 | #a #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #H #_ destruct
 269   elim (simple_inv_bind … HT1)
 270 | #a #V #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #_ #H #_ destruct
 271   elim (simple_inv_bind … HT1)
 272 ]
 273 qed-.
 274
 275 (* Basic_1: includes: pr0_gen_cast pr2_gen_cast *)
 276 lemma cpr_inv_cast1: ∀G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝ V1. U1 ➡ U2 → (
 277                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 278                               U2 = ⓝ V2. T2
 279                      ) ∨ ⦃G, L⦄ ⊢ U1 ➡ U2.
 280 #G #L #V1 #U1 #U2 #H elim (cpr_inv_flat1 … H) -H *
 281 [ /3 width=5 by ex3_2_intro, or_introl/
 282 | /2 width=1 by or_intror/
 283 | #a #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #H destruct
 284 | #a #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H destruct
 285 ]
 286 qed-.
 287
 288 (* Basic forward lemmas *****************************************************)
 289
 290 lemma cpr_fwd_bind1_minus: ∀I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ➡ T → ∀b.
 291                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{b,I}V1.T1 ➡ ⓑ{b,I}V2.T2 &
 292                                     T = -ⓑ{I}V2.T2.
 293 #I #G #L #V1 #T1 #T #H #b
 294 elim (cpr_inv_bind1 … H) -H *
 295 [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=4 by cpr_bind, ex2_2_intro/
 296 | #T2 #_ #_ #H destruct
 297 ]
 298 qed-.
 299
 300 (* Basic_1: removed theorems 11:
 301             pr0_subst0_back pr0_subst0_fwd pr0_subst0
 302             pr2_head_2 pr2_cflat clear_pr2_trans
 303             pr2_gen_csort pr2_gen_cflat pr2_gen_cbind
 304             pr2_gen_ctail pr2_ctail
 305 *)
 306 (* Basic_1: removed local theorems 4:
 307             pr0_delta_eps pr0_cong_delta
 308             pr2_free_free pr2_free_delta
 309 *)