matita/matita/contribs/lambdadelta/basic_2A/reduction/cpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_4_1.ma".
  16 include "ground/xoa/ex_5_6.ma".
  17 include "ground/xoa/ex_6_6.ma".
  18 include "ground/xoa/ex_6_7.ma".
  19 include "ground/xoa/ex_7_7.ma".
  20 include "ground/xoa/or_4.ma".
  21 include "basic_2A/notation/relations/pred_4.ma".
  22 include "basic_2A/static/lsubr.ma".
  23 include "basic_2A/unfold/lstas.ma".
  24
  25 (* CONTEXT-SENSITIVE PARALLEL REDUCTION FOR TERMS ***************************)
  26
  27 (* activate genv *)
  28 (* Note: cpr_flat: does not hold in basic_1 *)
  29 inductive cpr: relation4 genv lenv term term ≝
  30 | cpr_atom : ∀I,G,L. cpr G L (⓪{I}) (⓪{I})
  31 | cpr_delta: ∀G,L,K,V,V2,W2,i.
  32              ⬇[i] L ≡ K. ⓓV → cpr G K V V2 →
  33              ⬆[0, i + 1] V2 ≡ W2 → cpr G L (#i) W2
  34 | cpr_bind : ∀a,I,G,L,V1,V2,T1,T2.
  35              cpr G L V1 V2 → cpr G (L.ⓑ{I}V1) T1 T2 →
  36              cpr G L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  37 | cpr_flat : ∀I,G,L,V1,V2,T1,T2.
  38              cpr G L V1 V2 → cpr G L T1 T2 →
  39              cpr G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  40 | cpr_zeta : ∀G,L,V,T1,T,T2. cpr G (L.ⓓV) T1 T →
  41              ⬆[0, 1] T2 ≡ T → cpr G L (+ⓓV.T1) T2
  42 | cpr_eps  : ∀G,L,V,T1,T2. cpr G L T1 T2 → cpr G L (ⓝV.T1) T2
  43 | cpr_beta : ∀a,G,L,V1,V2,W1,W2,T1,T2.
  44              cpr G L V1 V2 → cpr G L W1 W2 → cpr G (L.ⓛW1) T1 T2 →
  45              cpr G L (ⓐV1.ⓛ{a}W1.T1) (ⓓ{a}ⓝW2.V2.T2)
  46 | cpr_theta: ∀a,G,L,V1,V,V2,W1,W2,T1,T2.
  47              cpr G L V1 V → ⬆[0, 1] V ≡ V2 → cpr G L W1 W2 → cpr G (L.ⓓW1) T1 T2 →
  48              cpr G L (ⓐV1.ⓓ{a}W1.T1) (ⓓ{a}W2.ⓐV2.T2)
  49 .
  50
  51 interpretation "context-sensitive parallel reduction (term)"
  52    'PRed G L T1 T2 = (cpr G L T1 T2).
  53
  54 (* Basic properties *********************************************************)
  55
  56 lemma lsubr_cpr_trans: ∀G. lsub_trans … (cpr G) lsubr.
  57 #G #L1 #T1 #T2 #H elim H -G -L1 -T1 -T2
  58 [ //
  59 | #G #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  60   elim (lsubr_fwd_drop2_abbr … HL12 … HLK1) -L1 *
  61   /3 width=6 by cpr_delta/
  62 |3,7: /4 width=1 by lsubr_pair, cpr_bind, cpr_beta/
  63 |4,6: /3 width=1 by cpr_flat, cpr_eps/
  64 |5,8: /4 width=3 by lsubr_pair, cpr_zeta, cpr_theta/
  65 ]
  66 qed-.
  67
  68 lemma tpr_cpr: ∀G,T1,T2. ⦃G, ⋆⦄ ⊢ T1 ➡ T2 → ∀L. ⦃G, L⦄ ⊢ T1 ➡ T2.
  69 #G #T1 #T2 #HT12 #L
  70 lapply (lsubr_cpr_trans … HT12 L ?) //
  71 qed.
  72
  73 lemma cpr_refl: ∀G,T,L. ⦃G, L⦄ ⊢ T ➡ T.
  74 #G #T elim T -T // * /2 width=1 by cpr_bind, cpr_flat/
  75 qed.
  76
  77 lemma cpr_pair_sn: ∀I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡ V2 →
  78                    ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ➡ ②{I}V2.T.
  79 * /2 width=1 by cpr_bind, cpr_flat/ qed.
  80
  81 lemma cpr_delift: ∀G,K,V,T1,L,l. ⬇[l] L ≡ (K.ⓓV) →
  82                   ∃∃T2,T. ⦃G, L⦄ ⊢ T1 ➡ T2 & ⬆[l, 1] T ≡ T2.
  83 #G #K #V #T1 elim T1 -T1
  84 [ * /2 width=4 by cpr_atom, lift_sort, lift_gref, ex2_2_intro/
  85   #i #L #l #HLK elim (lt_or_eq_or_gt i l)
  86   #Hil [1,3: /3 width=4 by cpr_atom, lift_lref_ge_minus, lift_lref_lt, ex2_2_intro/ ]
  87   destruct
  88   elim (lift_total V 0 (i+1)) #W #HVW
  89   elim (lift_split … HVW i i) /3 width=6 by cpr_delta, ex2_2_intro/
  90 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #l #HLK
  91   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  92   [ elim (IHU1 (L. ⓑ{I}W1) (l+1)) -IHU1 /3 width=9 by drop_drop, cpr_bind, lift_bind, ex2_2_intro/
  93   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8 by cpr_flat, lift_flat, ex2_2_intro/
  94   ]
  95 ]
  96 qed-.
  97
  98 fact lstas_cpr_aux: ∀h,G,L,T1,T2,d. ⦃G, L⦄ ⊢ T1 •*[h, d] T2 →
  99                     d = 0 → ⦃G, L⦄ ⊢ T1 ➡ T2.
 100 #h #G #L #T1 #T2 #d #H elim H -G -L -T1 -T2 -d
 101 /3 width=1 by cpr_eps, cpr_flat, cpr_bind/
 102 [ #G #L #K #V1 #V2 #W2 #i #d #HLK #_ #HVW2 #IHV12 #H destruct
 103   /3 width=6 by cpr_delta/
 104 | #G #L #K #V1 #V2 #W2 #i #d #_ #_ #_ #_ <plus_n_Sm #H destruct
 105 ]
 106 qed-.
 107
 108 lemma lstas_cpr: ∀h,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 •*[h, 0] T2 → ⦃G, L⦄ ⊢ T1 ➡ T2.
 109 /2 width=4 by lstas_cpr_aux/ qed.
 110
 111 (* Basic inversion lemmas ***************************************************)
 112
 113 fact cpr_inv_atom1_aux: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ∀I. T1 = ⓪{I} →
 114                         T2 = ⓪{I} ∨
 115                         ∃∃K,V,V2,i. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 116                                     ⬆[O, i + 1] V2 ≡ T2 & I = LRef i.
 117 #G #L #T1 #T2 * -G -L -T1 -T2
 118 [ #I #G #L #J #H destruct /2 width=1 by or_introl/
 119 | #L #G #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #J #H destruct /3 width=8 by ex4_4_intro, or_intror/
 120 | #a #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 121 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 122 | #G #L #V #T1 #T #T2 #_ #_ #J #H destruct
 123 | #G #L #V #T1 #T2 #_ #J #H destruct
 124 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #J #H destruct
 125 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #J #H destruct
 126 ]
 127 qed-.
 128
 129 lemma cpr_inv_atom1: ∀I,G,L,T2. ⦃G, L⦄ ⊢ ⓪{I} ➡ T2 →
 130                      T2 = ⓪{I} ∨
 131                      ∃∃K,V,V2,i. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 132                                  ⬆[O, i + 1] V2 ≡ T2 & I = LRef i.
 133 /2 width=3 by cpr_inv_atom1_aux/ qed-.
 134
 135 lemma cpr_inv_sort1: ∀G,L,T2,k. ⦃G, L⦄ ⊢ ⋆k ➡ T2 → T2 = ⋆k.
 136 #G #L #T2 #k #H
 137 elim (cpr_inv_atom1 … H) -H //
 138 * #K #V #V2 #i #_ #_ #_ #H destruct
 139 qed-.
 140
 141 lemma cpr_inv_lref1: ∀G,L,T2,i. ⦃G, L⦄ ⊢ #i ➡ T2 →
 142                      T2 = #i ∨
 143                      ∃∃K,V,V2. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 144                                ⬆[O, i + 1] V2 ≡ T2.
 145 #G #L #T2 #i #H
 146 elim (cpr_inv_atom1 … H) -H /2 width=1 by or_introl/
 147 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6 by ex3_3_intro, or_intror/
 148 qed-.
 149
 150 lemma cpr_inv_gref1: ∀G,L,T2,p. ⦃G, L⦄ ⊢ §p ➡ T2 → T2 = §p.
 151 #G #L #T2 #p #H
 152 elim (cpr_inv_atom1 … H) -H //
 153 * #K #V #V2 #i #_ #_ #_ #H destruct
 154 qed-.
 155
 156 fact cpr_inv_bind1_aux: ∀G,L,U1,U2. ⦃G, L⦄ ⊢ U1 ➡ U2 →
 157                         ∀a,I,V1,T1. U1 = ⓑ{a,I}V1. T1 → (
 158                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡ T2 &
 159                                  U2 = ⓑ{a,I}V2.T2
 160                         ) ∨
 161                         ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T &
 162                              a = true & I = Abbr.
 163 #G #L #U1 #U2 * -L -U1 -U2
 164 [ #I #G #L #b #J #W1 #U1 #H destruct
 165 | #L #G #K #V #V2 #W2 #i #_ #_ #_ #b #J #W #U1 #H destruct
 166 | #a #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W #U1 #H destruct /3 width=5 by ex3_2_intro, or_introl/
 167 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W #U1 #H destruct
 168 | #G #L #V #T1 #T #T2 #HT1 #HT2 #b #J #W #U1 #H destruct /3 width=3 by ex4_intro, or_intror/
 169 | #G #L #V #T1 #T2 #_ #b #J #W #U1 #H destruct
 170 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #b #J #W #U1 #H destruct
 171 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #b #J #W #U1 #H destruct
 172 ]
 173 qed-.
 174
 175 lemma cpr_inv_bind1: ∀a,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡ U2 → (
 176                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡ T2 &
 177                               U2 = ⓑ{a,I}V2.T2
 178                      ) ∨
 179                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T &
 180                           a = true & I = Abbr.
 181 /2 width=3 by cpr_inv_bind1_aux/ qed-.
 182
 183 lemma cpr_inv_abbr1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{a}V1.T1 ➡ U2 → (
 184                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L. ⓓV1⦄ ⊢ T1 ➡ T2 &
 185                               U2 = ⓓ{a}V2.T2
 186                      ) ∨
 187                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T & a = true.
 188 #a #G #L #V1 #T1 #U2 #H
 189 elim (cpr_inv_bind1 … H) -H *
 190 /3 width=5 by ex3_2_intro, ex3_intro, or_introl, or_intror/
 191 qed-.
 192
 193 lemma cpr_inv_abst1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{a}V1.T1 ➡ U2 →
 194                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡ T2 &
 195                               U2 = ⓛ{a}V2.T2.
 196 #a #G #L #V1 #T1 #U2 #H
 197 elim (cpr_inv_bind1 … H) -H *
 198 [ /3 width=5 by ex3_2_intro/
 199 | #T #_ #_ #_ #H destruct
 200 ]
 201 qed-.
 202
 203 fact cpr_inv_flat1_aux: ∀G,L,U,U2. ⦃G, L⦄ ⊢ U ➡ U2 →
 204                         ∀I,V1,U1. U = ⓕ{I}V1.U1 →
 205                         ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 206                                     U2 = ⓕ{I} V2. T2
 207                          | (⦃G, L⦄ ⊢ U1 ➡ U2 ∧ I = Cast)
 208                          | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 209                                                ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 & U1 = ⓛ{a}W1.T1 &
 210                                                U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 211                          | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 212                                                  ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 213                                                  U1 = ⓓ{a}W1.T1 &
 214                                                  U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 215 #G #L #U #U2 * -L -U -U2
 216 [ #I #G #L #J #W1 #U1 #H destruct
 217 | #G #L #K #V #V2 #W2 #i #_ #_ #_ #J #W #U1 #H destruct
 218 | #a #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #W #U1 #H destruct
 219 | #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W #U1 #H destruct /3 width=5 by or4_intro0, ex3_2_intro/
 220 | #G #L #V #T1 #T #T2 #_ #_ #J #W #U1 #H destruct
 221 | #G #L #V #T1 #T2 #HT12 #J #W #U1 #H destruct /3 width=1 by or4_intro1, conj/
 222 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #J #W #U1 #H destruct /3 width=11 by or4_intro2, ex6_6_intro/
 223 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #J #W #U1 #H destruct /3 width=13 by or4_intro3, ex7_7_intro/
 224 ]
 225 qed-.
 226
 227 lemma cpr_inv_flat1: ∀I,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓕ{I}V1.U1 ➡ U2 →
 228                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 229                                  U2 = ⓕ{I}V2.T2
 230                       | (⦃G, L⦄ ⊢ U1 ➡ U2 ∧ I = Cast)
 231                       | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 232                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 & U1 = ⓛ{a}W1.T1 &
 233                                             U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 234                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 235                                               ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 236                                               U1 = ⓓ{a}W1.T1 &
 237                                               U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 238 /2 width=3 by cpr_inv_flat1_aux/ qed-.
 239
 240 lemma cpr_inv_appl1: ∀G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐV1.U1 ➡ U2 →
 241                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 242                                  U2 = ⓐV2.T2
 243                       | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 244                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 &
 245                                             U1 = ⓛ{a}W1.T1 & U2 = ⓓ{a}ⓝW2.V2.T2
 246                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 247                                               ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 248                                               U1 = ⓓ{a}W1.T1 & U2 = ⓓ{a}W2.ⓐV2.T2.
 249 #G #L #V1 #U1 #U2 #H elim (cpr_inv_flat1 … H) -H *
 250 [ /3 width=5 by or3_intro0, ex3_2_intro/
 251 | #_ #H destruct
 252 | /3 width=11 by or3_intro1, ex5_6_intro/
 253 | /3 width=13 by or3_intro2, ex6_7_intro/
 254 ]
 255 qed-.
 256
 257 (* Note: the main property of simple terms *)
 258 lemma cpr_inv_appl1_simple: ∀G,L,V1,T1,U. ⦃G, L⦄ ⊢ ⓐV1. T1 ➡ U → 𝐒⦃T1⦄ →
 259                             ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ T1 ➡ T2 &
 260                                      U = ⓐV2. T2.
 261 #G #L #V1 #T1 #U #H #HT1
 262 elim (cpr_inv_appl1 … H) -H *
 263 [ /2 width=5 by ex3_2_intro/
 264 | #a #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #H #_ destruct
 265   elim (simple_inv_bind … HT1)
 266 | #a #V #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #_ #H #_ destruct
 267   elim (simple_inv_bind … HT1)
 268 ]
 269 qed-.
 270
 271 lemma cpr_inv_cast1: ∀G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝ V1. U1 ➡ U2 → (
 272                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 273                               U2 = ⓝ V2. T2
 274                      ) ∨ ⦃G, L⦄ ⊢ U1 ➡ U2.
 275 #G #L #V1 #U1 #U2 #H elim (cpr_inv_flat1 … H) -H *
 276 [ /3 width=5 by ex3_2_intro, or_introl/
 277 | /2 width=1 by or_intror/
 278 | #a #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #H destruct
 279 | #a #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H destruct
 280 ]
 281 qed-.
 282
 283 (* Basic forward lemmas *****************************************************)
 284
 285 lemma cpr_fwd_bind1_minus: ∀I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ➡ T → ∀b.
 286                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{b,I}V1.T1 ➡ ⓑ{b,I}V2.T2 &
 287                                     T = -ⓑ{I}V2.T2.
 288 #I #G #L #V1 #T1 #T #H #b
 289 elim (cpr_inv_bind1 … H) -H *
 290 [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=4 by cpr_bind, ex2_2_intro/
 291 | #T2 #_ #_ #H destruct
 292 ]
 293 qed-.