matita/matita/contribs/lambdadelta/basic_2A/reduction/cpr_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/drop_drop.ma".
  16 include "basic_2A/reduction/cpr.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL REDUCTION FOR TERMS ***************************)
  19
  20 (* Relocation properties ****************************************************)
  21
  22 (* Basic_1: includes: pr0_lift pr2_lift *)
  23 lemma cpr_lift: ∀G. d_liftable (cpr G).
  24 #G #K #T1 #T2 #H elim H -G -K -T1 -T2
  25 [ #I #G #K #L #s #l #m #_ #U1 #H1 #U2 #H2
  26   >(lift_mono … H1 … H2) -H1 -H2 //
  27 | #G #K #KV #V #V2 #W2 #i #HKV #HV2 #HVW2 #IHV2 #L #s #l #m #HLK #U1 #H #U2 #HWU2
  28   elim (lift_inv_lref1 … H) * #Hil #H destruct
  29   [ elim (lift_trans_ge … HVW2 … HWU2) -W2 // <minus_plus #W2 #HVW2 #HWU2
  30     elim (drop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  31     elim (drop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hil
  32     #K #Y #HKV #HVY #H destruct /3 width=9 by cpr_delta/
  33   | lapply (lift_trans_be … HVW2 … HWU2 ? ?) -W2 /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  34     lapply (drop_trans_ge_comm … HLK … HKV ?) -K // -Hil /3 width=6 by cpr_delta, drop_inv_gen/
  35   ]
  36 | #a #I #G #K #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #s #l #m #HLK #U1 #H1 #U2 #H2
  37   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1 destruct
  38   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct /4 width=6 by cpr_bind, drop_skip/
  39 | #I #G #K #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #s #l #m #HLK #U1 #H1 #U2 #H2
  40   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1 destruct
  41   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct /3 width=6 by cpr_flat/
  42 | #G #K #V #T1 #T #T2 #_ #HT2 #IHT1 #L #s #l #m #HLK #U1 #H #U2 #HTU2
  43   elim (lift_inv_bind1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct
  44   elim (lift_conf_O1 … HTU2 … HT2) -T2 /4 width=6 by cpr_zeta, drop_skip/
  45 | #G #K #V #T1 #T2 #_ #IHT12 #L #s #l #m #HLK #U1 #H #U2 #HTU2
  46   elim (lift_inv_flat1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct /3 width=6 by cpr_eps/
  47 | #a #G #K #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #L #s #l #m #HLK #X1 #HX1 #X2 #HX2
  48   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct
  49   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct
  50   elim (lift_inv_bind1 … HX2) -HX2 #X #T3 #HX #HT23 #HX2 destruct
  51   elim (lift_inv_flat1 … HX) -HX #W3 #V3 #HW23 #HV23 #HX destruct /4 width=6 by cpr_beta, drop_skip/
  52 | #a #G #K #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #L #s #l #m #HLK #X1 #HX1 #X2 #HX2
  53   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct
  54   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct
  55   elim (lift_inv_bind1 … HX2) -HX2 #W3 #X #HW23 #HX #HX2 destruct
  56   elim (lift_inv_flat1 … HX) -HX #V3 #T3 #HV3 #HT23 #HX destruct
  57   elim (lift_trans_ge … HV2 … HV3) -V2 /4 width=6 by cpr_theta, drop_skip/
  58 ]
  59 qed.
  60
  61 (* Basic_1: includes: pr0_gen_lift pr2_gen_lift *)
  62 lemma cpr_inv_lift1: ∀G. d_deliftable_sn (cpr G).
  63 #G #L #U1 #U2 #H elim H -G -L -U1 -U2
  64 [ * #i #G #L #K #s #l #m #_ #T1 #H
  65   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
  66   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
  67   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
  68   ]
  69 | #G #L #LV #V #V2 #W2 #i #HLV #HV2 #HVW2 #IHV2 #K #s #l #m #HLK #T1 #H
  70   elim (lift_inv_lref2 … H) -H * #Hil #H destruct
  71   [ elim (drop_conf_lt … HLK … HLV) -L // #L #U #HKL #HLV #HUV
  72     elim (IHV2 … HLV … HUV) -V #U2 #HUV2 #HU2
  73     elim (lift_trans_le … HUV2 … HVW2) -V2 // >minus_plus <plus_minus_m_m /3 width=8 by cpr_delta, ex2_intro/
  74   | elim (le_inv_plus_l … Hil) #Hlim #Hmi
  75     lapply (drop_conf_ge … HLK … HLV ?) -L // #HKLV
  76     elim (lift_split … HVW2 l (i - m + 1)) -HVW2 [2,3,4: /2 width=1 by le_S_S, le_S/ ] -Hil -Hlim
  77     #V1 #HV1 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O
  78     /3 width=8 by cpr_delta, ex2_intro/
  79   ]
  80 | #a #I #G #L #V1 #V2 #U1 #U2 #_ #_ #IHV12 #IHU12 #K #s #l #m #HLK #X #H
  81   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
  82   elim (IHV12 … HLK … HWV1) -IHV12 #W2 #HW12 #HWV2
  83   elim (IHU12 … HTU1) -IHU12 -HTU1 /3 width=6 by cpr_bind, drop_skip, lift_bind, ex2_intro/
  84 | #I #G #L #V1 #V2 #U1 #U2 #_ #_ #IHV12 #IHU12 #K #s #l #m #HLK #X #H
  85   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
  86   elim (IHV12 … HLK … HWV1) -V1
  87   elim (IHU12 … HLK … HTU1) -U1 -HLK /3 width=6 by cpr_flat, lift_flat, ex2_intro/
  88 | #G #L #V #U1 #U #U2 #_ #HU2 #IHU1 #K #s #l #m #HLK #X #H
  89   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
  90   elim (IHU1 (K.ⓓW1) s  … HTU1) /2 width=1 by drop_skip/ -L -U1 #T #HTU #HT1
  91   elim (lift_div_le … HU2 … HTU) -U /3 width=6 by cpr_zeta, ex2_intro/
  92 | #G #L #V #U1 #U2 #_ #IHU12 #K #s #l #m #HLK #X #H
  93   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
  94   elim (IHU12 … HLK … HTU1) -L -U1 /3 width=3 by cpr_eps, ex2_intro/
  95 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #K #s #l #m #HLK #X #HX
  96   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct
  97   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct
  98   elim (IHV12 … HLK … HV01) -V1
  99   elim (IHT12 (K.ⓛW0) s … HT01) -T1 /2 width=1 by drop_skip/
 100   elim (IHW12 … HLK … HW01) -W1 /4 width=7 by cpr_beta, lift_flat, lift_bind, ex2_intro/
 101 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #K #s #l #m #HLK #X #HX
 102   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct
 103   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct
 104   elim (IHV1 … HLK … HV01) -V1 #V3 #HV3 #HV03
 105   elim (IHT12 (K.ⓓW0) s … HT01) -T1 /2 width=1 by drop_skip/ #T3 #HT32 #HT03
 106   elim (IHW12 … HLK … HW01) -W1
 107   elim (lift_trans_le … HV3 … HV2) -V
 108   /4 width=9 by cpr_theta, lift_flat, lift_bind, ex2_intro/
 109 ]
 110 qed-.