matita/matita/contribs/lambdadelta/basic_2A/reduction/cpx_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/drop_drop.ma".
  16 include "basic_2A/multiple/fqus_alt.ma".
  17 include "basic_2A/static/da.ma".
  18 include "basic_2A/reduction/cpx.ma".
  19
  20 (* CONTEXT-SENSITIVE EXTENDED PARALLEL REDUCTION FOR TERMS ******************)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 fact sta_cpx_aux: ∀h,g,G,L,T1,T2,d2,d1. ⦃G, L⦄ ⊢ T1 •*[h, d2] T2 → d2 = 1 →
  25                   ⦃G, L⦄ ⊢ T1 ▪[h, g] d1+1 → ⦃G, L⦄ ⊢ T1 ➡[h, g] T2.
  26 #h #g #G #L #T1 #T2 #d2 #d1 #H elim H -G -L -T1 -T2 -d2
  27 [ #G #L #d2 #k #H0 destruct normalize
  28   /3 width=4 by cpx_st, da_inv_sort/
  29 | #G #L #K #V1 #V2 #W2 #i #d2 #HLK #_ #HVW2 #IHV12 #H0 #H destruct
  30   elim (da_inv_lref … H) -H * #K0 #V0 [| #d0 ] #HLK0
  31   lapply (drop_mono … HLK0 … HLK) -HLK0 #H destruct /3 width=7 by cpx_delta/
  32 | #G #L #K #V1 #V2 #i #_ #_ #_ #H destruct
  33 | #G #L #K #V1 #V2 #W2 #i #d2 #HLK #HV12 #HVW2 #_ #H0 #H
  34   lapply (discr_plus_xy_y … H0) -H0 #H0 destruct
  35   elim (da_inv_lref … H) -H * #K0 #V0 [| #d0 ] #HLK0
  36   lapply (drop_mono … HLK0 … HLK) -HLK0 #H destruct
  37   /4 width=7 by cpx_delta, cpr_cpx, lstas_cpr/
  38 | /4 width=2 by cpx_bind, da_inv_bind/
  39 | /4 width=3 by cpx_flat, da_inv_flat/
  40 | /4 width=3 by cpx_eps, da_inv_flat/
  41 ]
  42 qed-.
  43
  44 lemma sta_cpx: ∀h,g,G,L,T1,T2,d. ⦃G, L⦄ ⊢ T1 •*[h, 1] T2 →
  45                ⦃G, L⦄ ⊢ T1 ▪[h, g] d+1 → ⦃G, L⦄ ⊢ T1 ➡[h, g] T2.
  46 /2 width=3 by sta_cpx_aux/ qed.
  47
  48 (* Relocation properties ****************************************************)
  49
  50 lemma cpx_lift: ∀h,g,G. d_liftable (cpx h g G).
  51 #h #g #G #K #T1 #T2 #H elim H -G -K -T1 -T2
  52 [ #I #G #K #L #s #l #m #_ #U1 #H1 #U2 #H2
  53   >(lift_mono … H1 … H2) -H1 -H2 //
  54 | #G #K #k #d #Hkd #L #s #l #m #_ #U1 #H1 #U2 #H2
  55   >(lift_inv_sort1 … H1) -U1
  56   >(lift_inv_sort1 … H2) -U2 /2 width=2 by cpx_st/
  57 | #I #G #K #KV #V #V2 #W2 #i #HKV #HV2 #HVW2 #IHV2 #L #s #l #m #HLK #U1 #H #U2 #HWU2
  58   elim (lift_inv_lref1 … H) * #Hil #H destruct
  59   [ elim (lift_trans_ge … HVW2 … HWU2) -W2 // <minus_plus #W2 #HVW2 #HWU2
  60     elim (drop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  61     elim (drop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hil
  62     #K #Y #HKV #HVY #H destruct /3 width=10 by cpx_delta/
  63   | lapply (lift_trans_be … HVW2 … HWU2 ? ?) -W2 /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  64     lapply (drop_trans_ge_comm … HLK … HKV ?) -K /3 width=7 by cpx_delta, drop_inv_gen/
  65   ]
  66 | #a #I #G #K #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #s #l #m #HLK #U1 #H1 #U2 #H2
  67   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1 destruct
  68   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct /4 width=6 by cpx_bind, drop_skip/
  69 | #I #G #K #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #s #l #m #HLK #U1 #H1 #U2 #H2
  70   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1 destruct
  71   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct /3 width=6 by cpx_flat/
  72 | #G #K #V #T1 #T #T2 #_ #HT2 #IHT1 #L #s #l #m #HLK #U1 #H #U2 #HTU2
  73   elim (lift_inv_bind1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct
  74   elim (lift_conf_O1 … HTU2 … HT2) -T2 /4 width=6 by cpx_zeta, drop_skip/
  75 | #G #K #V #T1 #T2 #_ #IHT12 #L #s #l #m #HLK #U1 #H #U2 #HTU2
  76   elim (lift_inv_flat1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct /3 width=6 by cpx_eps/
  77 | #G #K #V1 #V2 #T #_ #IHV12 #L #s #l #m #HLK #U1 #H #U2 #HVU2
  78   elim (lift_inv_flat1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct /3 width=6 by cpx_ct/
  79 | #a #G #K #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #L #s #l #m #HLK #X1 #HX1 #X2 #HX2
  80   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct
  81   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct
  82   elim (lift_inv_bind1 … HX2) -HX2 #X #T3 #HX #HT23 #HX2 destruct
  83   elim (lift_inv_flat1 … HX) -HX #W3 #V3 #HW23 #HV23 #HX destruct /4 width=6 by cpx_beta, drop_skip/
  84 | #a #G #K #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #L #s #l #m #HLK #X1 #HX1 #X2 #HX2
  85   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct
  86   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct
  87   elim (lift_inv_bind1 … HX2) -HX2 #W3 #X #HW23 #HX #HX2 destruct
  88   elim (lift_inv_flat1 … HX) -HX #V3 #T3 #HV3 #HT23 #HX destruct
  89   elim (lift_trans_ge … HV2 … HV3) -V2 /4 width=6 by cpx_theta, drop_skip/
  90 ]
  91 qed.
  92
  93 lemma cpx_inv_lift1: ∀h,g,G. d_deliftable_sn (cpx h g G).
  94 #h #g #G #L #U1 #U2 #H elim H -G -L -U1 -U2
  95 [ * #i #G #L #K #s #l #m #_ #T1 #H
  96   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by cpx_atom, lift_sort, ex2_intro/
  97   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by cpx_atom, lift_lref_ge_minus, lift_lref_lt, ex2_intro/
  98   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by cpx_atom, lift_gref, ex2_intro/
  99   ]
 100 | #G #L #k #d #Hkd #K #s #l #m #_ #T1 #H
 101   lapply (lift_inv_sort2 … H) -H #H destruct /3 width=3 by cpx_st, lift_sort, ex2_intro/
 102 | #I #G #L #LV #V #V2 #W2 #i #HLV #HV2 #HVW2 #IHV2 #K #s #l #m #HLK #T1 #H
 103   elim (lift_inv_lref2 … H) -H * #Hil #H destruct
 104   [ elim (drop_conf_lt … HLK … HLV) -L // #L #U #HKL #HLV #HUV
 105     elim (IHV2 … HLV … HUV) -V #U2 #HUV2 #HU2
 106     elim (lift_trans_le … HUV2 … HVW2) -V2 // >minus_plus <plus_minus_m_m /3 width=9 by cpx_delta, ex2_intro/
 107   | elim (le_inv_plus_l … Hil) #Hlim #Hmi
 108     lapply (drop_conf_ge … HLK … HLV ?) -L // #HKLV
 109     elim (lift_split … HVW2 l (i - m + 1)) -HVW2 /3 width=1 by le_S, le_S_S/ -Hil -Hlim
 110     #V1 #HV1 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O /3 width=9 by cpx_delta, ex2_intro/
 111   ]
 112 | #a #I #G #L #V1 #V2 #U1 #U2 #_ #_ #IHV12 #IHU12 #K #s #l #m #HLK #X #H
 113   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 114   elim (IHV12 … HLK … HWV1) -IHV12 #W2 #HW12 #HWV2
 115   elim (IHU12 … HTU1) -IHU12 -HTU1 /3 width=6 by cpx_bind, drop_skip, lift_bind, ex2_intro/
 116 | #I #G #L #V1 #V2 #U1 #U2 #_ #_ #IHV12 #IHU12 #K #s #l #m #HLK #X #H
 117   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 118   elim (IHV12 … HLK … HWV1) -V1
 119   elim (IHU12 … HLK … HTU1) -U1 -HLK /3 width=5 by cpx_flat, lift_flat, ex2_intro/
 120 | #G #L #V #U1 #U #U2 #_ #HU2 #IHU1 #K #s #l #m #HLK #X #H
 121   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 122   elim (IHU1 (K.ⓓW1) s … HTU1) /2 width=1 by drop_skip/ -L -U1 #T #HTU #HT1
 123   elim (lift_div_le … HU2 … HTU) -U /3 width=5 by cpx_zeta, ex2_intro/
 124 | #G #L #V #U1 #U2 #_ #IHU12 #K #s #l #m #HLK #X #H
 125   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 126   elim (IHU12 … HLK … HTU1) -L -U1 /3 width=3 by cpx_eps, ex2_intro/
 127 | #G #L #V1 #V2 #U1 #_ #IHV12 #K #s #l #m #HLK #X #H
 128   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct
 129   elim (IHV12 … HLK … HWV1) -L -V1 /3 width=3 by cpx_ct, ex2_intro/
 130 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #K #s #l #m #HLK #X #HX
 131   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct
 132   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct
 133   elim (IHV12 … HLK … HV01) -V1 #V3 #HV32 #HV03
 134   elim (IHT12 (K.ⓛW0) s … HT01) -T1 /2 width=1 by drop_skip/ #T3 #HT32 #HT03
 135   elim (IHW12 … HLK … HW01) -W1
 136   /4 width=7 by cpx_beta, lift_bind, lift_flat, ex2_intro/
 137 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #K #s #l #m #HLK #X #HX
 138   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct
 139   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct
 140   elim (IHV1 … HLK … HV01) -V1 #V3 #HV3 #HV03
 141   elim (IHT12 (K.ⓓW0) s … HT01) -T1 /2 width=1 by drop_skip/ #T3 #HT32 #HT03
 142   elim (IHW12 … HLK … HW01) -W1 #W3 #HW32 #HW03
 143   elim (lift_trans_le … HV3 … HV2) -V
 144   /4 width=9 by cpx_theta, lift_bind, lift_flat, ex2_intro/
 145 ]
 146 qed-.
 147
 148 (* Properties on supclosure *************************************************)
 149
 150 lemma fqu_cpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
 151                      ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 →
 152                      ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
 153 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
 154 /3 width=3 by fqu_pair_sn, fqu_bind_dx, fqu_flat_dx, cpx_pair_sn, cpx_bind, cpx_flat, ex2_intro/
 155 [ #I #G #L #V2 #U2 #HVU2
 156   elim (lift_total U2 0 1)
 157   /4 width=7 by fqu_drop, cpx_delta, drop_pair, drop_drop, ex2_intro/
 158 | #G #L #K #T1 #U1 #m #HLK1 #HTU1 #T2 #HTU2
 159   elim (lift_total T2 0 (m+1))
 160   /3 width=11 by cpx_lift, fqu_drop, ex2_intro/
 161 ]
 162 qed-.
 163
 164 lemma fqu_sta_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
 165                      ∀U2. ⦃G2, L2⦄ ⊢ T2 •*[h, 1] U2 →
 166                      ∀d. ⦃G2, L2⦄ ⊢ T2 ▪[h, g] d+1 →
 167                      ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
 168 /3 width=5 by fqu_cpx_trans, sta_cpx/ qed-.
 169
 170 lemma fquq_cpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 171                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 →
 172                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
 173 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fquq_inv_gen … H) -H
 174 [ #HT12 elim (fqu_cpx_trans … HT12 … HTU2) /3 width=3 by fqu_fquq, ex2_intro/
 175 | * #H1 #H2 #H3 destruct /2 width=3 by ex2_intro/
 176 ]
 177 qed-.
 178
 179 lemma fquq_sta_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 180                       ∀U2. ⦃G2, L2⦄ ⊢ T2 •*[h, 1] U2 →
 181                       ∀d. ⦃G2, L2⦄ ⊢ T2 ▪[h, g] d+1 →
 182                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
 183 /3 width=5 by fquq_cpx_trans, sta_cpx/ qed-.
 184
 185 lemma fqup_cpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
 186                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 →
 187                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐+ ⦃G2, L2, U2⦄.
 188 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
 189 [ #G2 #L2 #T2 #H12 #U2 #HTU2 elim (fqu_cpx_trans … H12 … HTU2) -T2
 190   /3 width=3 by fqu_fqup, ex2_intro/
 191 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #U2 #HTU2
 192   elim (fqu_cpx_trans … HT2 … HTU2) -T2 #T2 #HT2 #HTU2
 193   elim (IHT1 … HT2) -T /3 width=7 by fqup_strap1, ex2_intro/
 194 ]
 195 qed-.
 196
 197 lemma fqus_cpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 198                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 →
 199                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & ⦃G1, L1, U1⦄ ⊐* ⦃G2, L2, U2⦄.
 200 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fqus_inv_gen … H) -H
 201 [ #HT12 elim (fqup_cpx_trans … HT12 … HTU2) /3 width=3 by fqup_fqus, ex2_intro/
 202 | * #H1 #H2 #H3 destruct /2 width=3 by ex2_intro/
 203 ]
 204 qed-.
 205
 206 lemma fqu_cpx_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
 207                          ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 → (T2 = U2 → ⊥) →
 208                          ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
 209 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
 210 [ #I #G #L #V1 #V2 #HV12 #_ elim (lift_total V2 0 1)
 211   #U2 #HVU2 @(ex3_intro … U2)
 212   [1,3: /3 width=7 by fqu_drop, cpx_delta, drop_pair, drop_drop/
 213   | #H destruct /2 width=7 by lift_inv_lref2_be/
 214   ]
 215 | #I #G #L #V1 #T #V2 #HV12 #H @(ex3_intro … (②{I}V2.T))
 216   [1,3: /2 width=4 by fqu_pair_sn, cpx_pair_sn/
 217   | #H0 destruct /2 width=1 by/
 218   ]
 219 | #a #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓑ{a,I}V.T2))
 220   [1,3: /2 width=4 by fqu_bind_dx, cpx_bind/
 221   | #H0 destruct /2 width=1 by/
 222   ]
 223 | #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓕ{I}V.T2))
 224   [1,3: /2 width=4 by fqu_flat_dx, cpx_flat/
 225   | #H0 destruct /2 width=1 by/
 226   ]
 227 | #G #L #K #T1 #U1 #m #HLK #HTU1 #T2 #HT12 #H elim (lift_total T2 0 (m+1))
 228   #U2 #HTU2 @(ex3_intro … U2)
 229   [1,3: /2 width=10 by cpx_lift, fqu_drop/
 230   | #H0 destruct /3 width=5 by lift_inj/
 231 ]
 232 qed-.
 233
 234 lemma fquq_cpx_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 235                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 → (T2 = U2 → ⊥) →
 236                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
 237 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fquq_inv_gen … H12) -H12
 238 [ #H12 elim (fqu_cpx_trans_neq … H12 … HTU2 H) -T2
 239   /3 width=4 by fqu_fquq, ex3_intro/
 240 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 241 ]
 242 qed-.
 243
 244 lemma fqup_cpx_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
 245                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 → (T2 = U2 → ⊥) →
 246                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐+ ⦃G2, L2, U2⦄.
 247 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind_dx … H) -G1 -L1 -T1
 248 [ #G1 #L1 #T1 #H12 #U2 #HTU2 #H elim (fqu_cpx_trans_neq … H12 … HTU2 H) -T2
 249   /3 width=4 by fqu_fqup, ex3_intro/
 250 | #G #G1 #L #L1 #T #T1 #H1 #_ #IH12 #U2 #HTU2 #H elim (IH12 … HTU2 H) -T2
 251   #U1 #HTU1 #H #H12 elim (fqu_cpx_trans_neq … H1 … HTU1 H) -T1
 252   /3 width=8 by fqup_strap2, ex3_intro/
 253 ]
 254 qed-.
 255
 256 lemma fqus_cpx_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 257                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡[h, g] U2 → (T2 = U2 → ⊥) →
 258                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐* ⦃G2, L2, U2⦄.
 259 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fqus_inv_gen … H12) -H12
 260 [ #H12 elim (fqup_cpx_trans_neq … H12 … HTU2 H) -T2
 261   /3 width=4 by fqup_fqus, ex3_intro/
 262 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 263 ]
 264 qed-.