matita/matita/contribs/lambdadelta/basic_2A/reduction/cpx_lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/multiple/lleq_drop.ma".
  16 include "basic_2A/reduction/cpx_llpx_sn.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED PARALLEL REDUCTION FOR TERMS ******************)
  19
  20 (* Properties on lazy equivalence for local environments ********************)
  21
  22 lemma lleq_cpx_trans: ∀h,g,G,L2,T1,T2. ⦃G, L2⦄ ⊢ T1 ➡[h, g] T2 →
  23                       ∀L1. L1 ≡[T1, 0] L2 → ⦃G, L1⦄ ⊢ T1 ➡[h, g] T2.
  24 #h #g #G #L2 #T1 #T2 #H elim H -G -L2 -T1 -T2 /2 width=2 by cpx_st/
  25 [ #I #G #L2 #K2 #V1 #V2 #W2 #i #HLK2 #_ #HVW2 #IHV12 #L1 #H elim (lleq_fwd_lref_dx … H … HLK2) -L2
  26   [ #H elim (ylt_yle_false … H) //
  27   | * /3 width=7 by cpx_delta/
  28   ]
  29 | #a #I #G #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #H elim (lleq_inv_bind_O … H) -H
  30   /3 width=1 by cpx_bind/
  31 | #I #G #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  32   /3 width=1 by cpx_flat/
  33 | #G #L2 #V2 #T1 #T #T2 #_ #HT2 #IHT1 #L1 #H elim (lleq_inv_bind_O … H) -H
  34   /3 width=3 by cpx_zeta/
  35 | #G #L2 #W1 #T1 #T2 #_ #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  36   /3 width=1 by cpx_eps/
  37 | #G #L2 #W1 #W2 #T1 #_ #IHW12 #L1 #H elim (lleq_inv_flat … H) -H
  38   /3 width=1 by cpx_ct/
  39 | #a #G #L1 #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  40   #HV1 #H elim (lleq_inv_bind_O … H) -H /3 width=1 by cpx_beta/
  41 | #a #G #L1 #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #L1 #H elim (lleq_inv_flat … H) -H
  42   #HV1 #H elim (lleq_inv_bind_O … H) -H /3 width=3 by cpx_theta/
  43 ]
  44 qed-.
  45
  46 lemma cpx_lleq_conf: ∀h,g,G,L2,T1,T2. ⦃G, L2⦄ ⊢ T1 ➡[h, g] T2 →
  47                      ∀L1. L2 ≡[T1, 0] L1 → ⦃G, L1⦄ ⊢ T1 ➡[h, g] T2.
  48 /3 width=3 by lleq_cpx_trans, lleq_sym/ qed-.
  49
  50 lemma cpx_lleq_conf_sn: ∀h,g,G. s_r_confluent1 … (cpx h g G) (lleq 0).
  51 /3 width=6 by cpx_llpx_sn_conf, lift_mono, ex2_intro/ qed-.
  52
  53 lemma cpx_lleq_conf_dx: ∀h,g,G,L2,T1,T2. ⦃G, L2⦄ ⊢ T1 ➡[h, g] T2 →
  54                         ∀L1. L1 ≡[T1, 0] L2 → L1 ≡[T2, 0] L2.
  55 /4 width=6 by cpx_lleq_conf_sn, lleq_sym/ qed-.