matita/matita/contribs/lambdadelta/basic_2A/reduction/crx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/predreducible_5.ma".
  16 include "basic_2A/static/sd.ma".
  17 include "basic_2A/reduction/crr.ma".
  18
  19 (* REDUCIBLE TERMS FOR CONTEXT-SENSITIVE EXTENDED REDUCTION *****************)
  20
  21 (* activate genv *)
  22 inductive crx (h) (g) (G:genv): relation2 lenv term ≝
  23 | crx_sort   : ∀L,k,d. deg h g k (d+1) → crx h g G L (⋆k)
  24 | crx_delta  : ∀I,L,K,V,i. ⬇[i] L ≡ K.ⓑ{I}V → crx h g G L (#i)
  25 | crx_appl_sn: ∀L,V,T. crx h g G L V → crx h g G L (ⓐV.T)
  26 | crx_appl_dx: ∀L,V,T. crx h g G L T → crx h g G L (ⓐV.T)
  27 | crx_ri2    : ∀I,L,V,T. ri2 I → crx h g G L (②{I}V.T)
  28 | crx_ib2_sn : ∀a,I,L,V,T. ib2 a I → crx h g G L V → crx h g G L (ⓑ{a,I}V.T)
  29 | crx_ib2_dx : ∀a,I,L,V,T. ib2 a I → crx h g G (L.ⓑ{I}V) T → crx h g G L (ⓑ{a,I}V.T)
  30 | crx_beta   : ∀a,L,V,W,T. crx h g G L (ⓐV. ⓛ{a}W.T)
  31 | crx_theta  : ∀a,L,V,W,T. crx h g G L (ⓐV. ⓓ{a}W.T)
  32 .
  33
  34 interpretation
  35    "reducibility for context-sensitive extended reduction (term)"
  36    'PRedReducible h g G L T = (crx h g G L T).
  37
  38 (* Basic properties *********************************************************)
  39
  40 lemma crr_crx: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ ➡ 𝐑⦃T⦄ → ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃T⦄.
  41 #h #g #G #L #T #H elim H -L -T
  42 /2 width=4 by crx_delta, crx_appl_sn, crx_appl_dx, crx_ri2, crx_ib2_sn, crx_ib2_dx, crx_beta, crx_theta/
  43 qed.
  44
  45 (* Basic inversion lemmas ***************************************************)
  46
  47 fact crx_inv_sort_aux: ∀h,g,G,L,T,k. ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃T⦄ → T = ⋆k →
  48                        ∃d. deg h g k (d+1).
  49 #h #g #G #L #T #k0 * -L -T
  50 [ #L #k #d #Hkd #H destruct /2 width=2 by ex_intro/
  51 | #I #L #K #V #i #HLK #H destruct
  52 | #L #V #T #_ #H destruct
  53 | #L #V #T #_ #H destruct
  54 | #I #L #V #T #_ #H destruct
  55 | #a #I #L #V #T #_ #_ #H destruct
  56 | #a #I #L #V #T #_ #_ #H destruct
  57 | #a #L #V #W #T #H destruct
  58 | #a #L #V #W #T #H destruct
  59 ]
  60 qed-.
  61
  62 lemma crx_inv_sort: ∀h,g,G,L,k. ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃⋆k⦄ → ∃d. deg h g k (d+1).
  63 /2 width=5 by crx_inv_sort_aux/ qed-.
  64
  65 fact crx_inv_lref_aux: ∀h,g,G,L,T,i. ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃T⦄ → T = #i →
  66                        ∃∃I,K,V. ⬇[i] L ≡ K.ⓑ{I}V.
  67 #h #g #G #L #T #j * -L -T
  68 [ #L #k #d #_ #H destruct
  69 | #I #L #K #V #i #HLK #H destruct /2 width=4 by ex1_3_intro/
  70 | #L #V #T #_ #H destruct
  71 | #L #V #T #_ #H destruct
  72 | #I #L #V #T #_ #H destruct
  73 | #a #I #L #V #T #_ #_ #H destruct
  74 | #a #I #L #V #T #_ #_ #H destruct
  75 | #a #L #V #W #T #H destruct
  76 | #a #L #V #W #T #H destruct
  77 ]
  78 qed-.
  79
  80 lemma crx_inv_lref: ∀h,g,G,L,i. ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃#i⦄ → ∃∃I,K,V. ⬇[i] L ≡ K.ⓑ{I}V.
  81 /2 width=6 by crx_inv_lref_aux/ qed-.
  82
  83 fact crx_inv_gref_aux: ∀h,g,G,L,T,p. ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃T⦄ → T = §p → ⊥.
  84 #h #g #G #L #T #q * -L -T
  85 [ #L #k #d #_ #H destruct
  86 | #I #L #K #V #i #HLK #H destruct
  87 | #L #V #T #_ #H destruct
  88 | #L #V #T #_ #H destruct
  89 | #I #L #V #T #_ #H destruct
  90 | #a #I #L #V #T #_ #_ #H destruct
  91 | #a #I #L #V #T #_ #_ #H destruct
  92 | #a #L #V #W #T #H destruct
  93 | #a #L #V #W #T #H destruct
  94 ]
  95 qed-.
  96
  97 lemma crx_inv_gref: ∀h,g,G,L,p. ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃§p⦄ → ⊥.
  98 /2 width=8 by crx_inv_gref_aux/ qed-.
  99
 100 lemma trx_inv_atom: ∀h,g,I,G. ⦃G, ⋆⦄ ⊢ ➡[h, g] 𝐑⦃⓪{I}⦄ →
 101                     ∃∃k,d. deg h g k (d+1) & I = Sort k.
 102 #h #g * #i #G #H
 103 [ elim (crx_inv_sort … H) -H /2 width=4 by ex2_2_intro/
 104 | elim (crx_inv_lref … H) -H #I #L #V #H
 105   elim (drop_inv_atom1 … H) -H #H destruct
 106 | elim (crx_inv_gref … H)
 107 ]
 108 qed-.
 109
 110 fact crx_inv_ib2_aux: ∀h,g,a,I,G,L,W,U,T. ib2 a I → ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃T⦄ →
 111                       T = ⓑ{a,I}W.U → ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃W⦄ ∨ ⦃G, L.ⓑ{I}W⦄ ⊢ ➡[h, g] 𝐑⦃U⦄.
 112 #h #g #b #J #G #L #W0 #U #T #HI * -L -T
 113 [ #L #k #d #_ #H destruct
 114 | #I #L #K #V #i #_ #H destruct
 115 | #L #V #T #_ #H destruct
 116 | #L #V #T #_ #H destruct
 117 | #I #L #V #T #H1 #H2 destruct
 118   elim H1 -H1 #H destruct
 119   elim HI -HI #H destruct
 120 | #a #I #L #V #T #_ #HV #H destruct /2 width=1 by or_introl/
 121 | #a #I #L #V #T #_ #HT #H destruct /2 width=1 by or_intror/
 122 | #a #L #V #W #T #H destruct
 123 | #a #L #V #W #T #H destruct
 124 ]
 125 qed-.
 126
 127 lemma crx_inv_ib2: ∀h,g,a,I,G,L,W,T. ib2 a I → ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃ⓑ{a,I}W.T⦄ →
 128                    ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃W⦄ ∨ ⦃G, L.ⓑ{I}W⦄ ⊢ ➡[h, g] 𝐑⦃T⦄.
 129 /2 width=5 by crx_inv_ib2_aux/ qed-.
 130
 131 fact crx_inv_appl_aux: ∀h,g,G,L,W,U,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃T⦄ → T = ⓐW.U →
 132                        ∨∨ ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃W⦄ | ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃U⦄ | (𝐒⦃U⦄ → ⊥).
 133 #h #g #G #L #W0 #U #T * -L -T
 134 [ #L #k #d #_ #H destruct
 135 | #I #L #K #V #i #_ #H destruct
 136 | #L #V #T #HV #H destruct /2 width=1 by or3_intro0/
 137 | #L #V #T #HT #H destruct /2 width=1 by or3_intro1/
 138 | #I #L #V #T #H1 #H2 destruct
 139   elim H1 -H1 #H destruct
 140 | #a #I #L #V #T #_ #_ #H destruct
 141 | #a #I #L #V #T #_ #_ #H destruct
 142 | #a #L #V #W #T #H destruct
 143   @or3_intro2 #H elim (simple_inv_bind … H)
 144 | #a #L #V #W #T #H destruct
 145   @or3_intro2 #H elim (simple_inv_bind … H)
 146 ]
 147 qed-.
 148
 149 lemma crx_inv_appl: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃ⓐV.T⦄ →
 150                     ∨∨ ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃V⦄ | ⦃G, L⦄ ⊢ ➡[h, g] 𝐑⦃T⦄ | (𝐒⦃T⦄ → ⊥).
 151 /2 width=3 by crx_inv_appl_aux/ qed-.