matita/matita/contribs/lambdadelta/basic_2A/reduction/lpr_drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/lpx_sn_drop.ma".
  16 include "basic_2A/substitution/fquq_alt.ma".
  17 include "basic_2A/reduction/cpr_lift.ma".
  18 include "basic_2A/reduction/lpr.ma".
  19
  20 (* SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS *****************************)
  21
  22 (* Properties on local environment slicing ***********************************)
  23
  24 lemma lpr_drop_conf: ∀G. dropable_sn (lpr G).
  25 /3 width=6 by lpx_sn_deliftable_dropable, cpr_inv_lift1/ qed-.
  26
  27 lemma drop_lpr_trans: ∀G. dedropable_sn (lpr G).
  28 /3 width=10 by lpx_sn_liftable_dedropable, cpr_lift/ qed-.
  29
  30 lemma lpr_drop_trans_O1: ∀G. dropable_dx (lpr G).
  31 /2 width=3 by lpx_sn_dropable/ qed-.
  32
  33 (* Properties on context-sensitive parallel reduction for terms *************)
  34
  35 lemma fqu_cpr_trans_dx: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  36                         ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡ U2 →
  37                         ∃∃L,U1. ⦃G1, L1⦄ ⊢ ➡ L & ⦃G1, L⦄ ⊢ T1 ➡ U1 & ⦃G1, L, U1⦄ ⊐ ⦃G2, L2, U2⦄.
  38 #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  39 /3 width=5 by fqu_lref_O, fqu_pair_sn, fqu_bind_dx, fqu_flat_dx, lpr_pair, cpr_pair_sn, cpr_atom, cpr_bind, cpr_flat, ex3_2_intro/
  40 #G #L #K #U #T #m #HLK #HUT #U2 #HU2
  41 elim (lift_total U2 0 (m+1)) #T2 #HUT2
  42 lapply (cpr_lift … HU2 … HLK … HUT … HUT2) -HU2 -HUT /3 width=9 by fqu_drop, ex3_2_intro/
  43 qed-.
  44
  45 lemma fquq_cpr_trans_dx: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  46                          ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡ U2 →
  47                          ∃∃L,U1. ⦃G1, L1⦄ ⊢ ➡ L & ⦃G1, L⦄ ⊢ T1 ➡ U1 & ⦃G1, L, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
  48 #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fquq_inv_gen … H) -H
  49 [ #HT12 elim (fqu_cpr_trans_dx … HT12 … HTU2) /3 width=5 by fqu_fquq, ex3_2_intro/
  50 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  51 ]
  52 qed-.
  53
  54 lemma fqu_cpr_trans_sn: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  55                         ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡ U2 →
  56                         ∃∃L,U1. ⦃G1, L1⦄ ⊢ ➡ L & ⦃G1, L1⦄ ⊢ T1 ➡ U1 & ⦃G1, L, U1⦄ ⊐ ⦃G2, L2, U2⦄.
  57 #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  58 /3 width=5 by fqu_lref_O, fqu_pair_sn, fqu_bind_dx, fqu_flat_dx, lpr_pair, cpr_pair_sn, cpr_atom, cpr_bind, cpr_flat, ex3_2_intro/
  59 #G #L #K #U #T #m #HLK #HUT #U2 #HU2
  60 elim (lift_total U2 0 (m+1)) #T2 #HUT2
  61 lapply (cpr_lift … HU2 … HLK … HUT … HUT2) -HU2 -HUT /3 width=9 by fqu_drop, ex3_2_intro/
  62 qed-.
  63
  64 lemma fquq_cpr_trans_sn: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  65                          ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡ U2 →
  66                          ∃∃L,U1. ⦃G1, L1⦄ ⊢ ➡ L & ⦃G1, L1⦄ ⊢ T1 ➡ U1 & ⦃G1, L, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
  67 #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fquq_inv_gen … H) -H
  68 [ #HT12 elim (fqu_cpr_trans_sn … HT12 … HTU2) /3 width=5 by fqu_fquq, ex3_2_intro/
  69 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  70 ]
  71 qed-.
  72
  73 lemma fqu_lpr_trans: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  74                      ∀K2. ⦃G2, L2⦄ ⊢ ➡ K2 →
  75                      ∃∃K1,T. ⦃G1, L1⦄ ⊢ ➡ K1 & ⦃G1, L1⦄ ⊢ T1 ➡ T & ⦃G1, K1, T⦄ ⊐ ⦃G2, K2, T2⦄.
  76 #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  77 /3 width=5 by fqu_lref_O, fqu_pair_sn, fqu_flat_dx, lpr_pair, ex3_2_intro/
  78 [ #a #I #G2 #L2 #V2 #T2 #X #H elim (lpr_inv_pair1 … H) -H
  79   #K2 #W2 #HLK2 #HVW2 #H destruct
  80   /3 width=5 by fqu_fquq, cpr_pair_sn, fqu_bind_dx, ex3_2_intro/
  81 | #G #L1 #K1 #T1 #U1 #m #HLK1 #HTU1 #K2 #HK12
  82   elim (drop_lpr_trans … HLK1 … HK12) -HK12
  83   /3 width=7 by fqu_drop, ex3_2_intro/
  84 ]
  85 qed-.
  86
  87 lemma fquq_lpr_trans: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  88                       ∀K2. ⦃G2, L2⦄ ⊢ ➡ K2 →
  89                       ∃∃K1,T. ⦃G1, L1⦄ ⊢ ➡ K1 & ⦃G1, L1⦄ ⊢ T1 ➡ T & ⦃G1, K1, T⦄ ⊐⸮ ⦃G2, K2, T2⦄.
  90 #G1 #G2 #L1 #L2 #T1 #T2 #H #K2 #HLK2 elim (fquq_inv_gen … H) -H
  91 [ #HT12 elim (fqu_lpr_trans … HT12 … HLK2) /3 width=5 by fqu_fquq, ex3_2_intro/
  92 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  93 ]
  94 qed-.