matita/matita/contribs/lambdadelta/basic_2A/reduction/lpr_lpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/lpx_sn_lpx_sn.ma".
  16 include "basic_2A/multiple/fqup.ma".
  17 include "basic_2A/reduction/lpr_drop.ma".
  18
  19 (* SN PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS *****************************)
  20
  21 (* Main properties on context-sensitive parallel reduction for terms ********)
  22
  23 fact cpr_conf_lpr_atom_atom:
  24    ∀I,G,L1,L2. ∃∃T. ⦃G, L1⦄ ⊢ ⓪{I} ➡ T & ⦃G, L2⦄ ⊢ ⓪{I} ➡ T.
  25 /2 width=3 by cpr_atom, ex2_intro/ qed-.
  26
  27 fact cpr_conf_lpr_atom_delta:
  28    ∀G,L0,i. (
  29       ∀L,T. ⦃G, L0, #i⦄ ⊐+ ⦃G, L, T⦄ →
  30       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
  31       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
  32       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
  33    ) →
  34    ∀K0,V0. ⬇[i] L0 ≡ K0.ⓓV0 →
  35    ∀V2. ⦃G, K0⦄ ⊢ V0 ➡ V2 → ∀T2. ⬆[O, i + 1] V2 ≡ T2 →
  36    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
  37    ∃∃T. ⦃G, L1⦄ ⊢ #i ➡ T & ⦃G, L2⦄ ⊢ T2 ➡ T.
  38 #G #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  39 elim (lpr_drop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  40 elim (lpr_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  41 elim (lpr_drop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  42 elim (lpr_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  43 lapply (drop_fwd_drop2 … HLK2) -W2 #HLK2
  44 lapply (fqup_lref … G … HLK0) -HLK0 #HLK0
  45 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  46 elim (lift_total V 0 (i+1))
  47 /3 width=12 by cpr_lift, cpr_delta, ex2_intro/
  48 qed-.
  49
  50 (* Basic_1: includes: pr0_delta_delta pr2_delta_delta *)
  51 fact cpr_conf_lpr_delta_delta:
  52    ∀G,L0,i. (
  53       ∀L,T. ⦃G, L0, #i⦄ ⊐+ ⦃G, L, T⦄ →
  54       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
  55       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
  56       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
  57    ) →
  58    ∀K0,V0. ⬇[i] L0 ≡ K0.ⓓV0 →
  59    ∀V1. ⦃G, K0⦄ ⊢ V0 ➡ V1 → ∀T1. ⬆[O, i + 1] V1 ≡ T1 →
  60    ∀KX,VX. ⬇[i] L0 ≡ KX.ⓓVX →
  61    ∀V2. ⦃G, KX⦄ ⊢ VX ➡ V2 → ∀T2. ⬆[O, i + 1] V2 ≡ T2 →
  62    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
  63    ∃∃T. ⦃G, L1⦄ ⊢ T1 ➡ T & ⦃G, L2⦄ ⊢ T2 ➡ T.
  64 #G #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  65 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  66 lapply (drop_mono … H … HLK0) -H #H destruct
  67 elim (lpr_drop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  68 elim (lpr_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  69 lapply (drop_fwd_drop2 … HLK1) -W1 #HLK1
  70 elim (lpr_drop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  71 elim (lpr_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  72 lapply (drop_fwd_drop2 … HLK2) -W2 #HLK2
  73 lapply (fqup_lref … G … HLK0) -HLK0 #HLK0
  74 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  75 elim (lift_total V 0 (i+1)) /3 width=12 by cpr_lift, ex2_intro/
  76 qed-.
  77
  78 fact cpr_conf_lpr_bind_bind:
  79    ∀a,I,G,L0,V0,T0. (
  80       ∀L,T. ⦃G, L0, ⓑ{a,I}V0.T0⦄ ⊐+ ⦃G, L, T⦄ →
  81       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
  82       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
  83       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
  84    ) →
  85    ∀V1. ⦃G, L0⦄ ⊢ V0 ➡ V1 → ∀T1. ⦃G, L0.ⓑ{I}V0⦄ ⊢ T0 ➡ T1 →
  86    ∀V2. ⦃G, L0⦄ ⊢ V0 ➡ V2 → ∀T2. ⦃G, L0.ⓑ{I}V0⦄ ⊢ T0 ➡ T2 →
  87    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
  88    ∃∃T. ⦃G, L1⦄ ⊢ ⓑ{a,I}V1.T1 ➡ T & ⦃G, L2⦄ ⊢ ⓑ{a,I}V2.T2 ➡ T.
  89 #a #I #G #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
  90 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
  91 elim (IH … HV01 … HV02 … HL01 … HL02) //
  92 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH
  93 /3 width=5 by lpr_pair, cpr_bind, ex2_intro/
  94 qed-.
  95
  96 fact cpr_conf_lpr_bind_zeta:
  97    ∀G,L0,V0,T0. (
  98       ∀L,T. ⦃G, L0, +ⓓV0.T0⦄ ⊐+ ⦃G, L, T⦄ →
  99       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 100       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 101       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 102    ) →
 103    ∀V1. ⦃G, L0⦄ ⊢ V0 ➡ V1 → ∀T1. ⦃G, L0.ⓓV0⦄ ⊢ T0 ➡ T1 →
 104    ∀T2. ⦃G, L0.ⓓV0⦄ ⊢ T0 ➡ T2 → ∀X2. ⬆[O, 1] X2 ≡ T2 →
 105    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 106    ∃∃T. ⦃G, L1⦄ ⊢ +ⓓV1.T1 ➡ T & ⦃G, L2⦄ ⊢ X2 ➡ T.
 107 #G #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 108 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 109 elim (IH … HT01 … HT02 (L1.ⓓV1) … (L2.ⓓV1)) -IH -HT01 -HT02 /2 width=1 by lpr_pair/ -L0 -V0 -T0 #T #HT1 #HT2
 110 elim (cpr_inv_lift1 … HT2 L2 … HXT2) -T2 /3 width=3 by cpr_zeta, drop_drop, ex2_intro/
 111 qed-.
 112
 113 fact cpr_conf_lpr_zeta_zeta:
 114    ∀G,L0,V0,T0. (
 115       ∀L,T. ⦃G, L0, +ⓓV0.T0⦄ ⊐+ ⦃G, L, T⦄ →
 116       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 117       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 118       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 119    ) →
 120    ∀T1. ⦃G, L0.ⓓV0⦄ ⊢ T0 ➡ T1 → ∀X1. ⬆[O, 1] X1 ≡ T1 →
 121    ∀T2. ⦃G, L0.ⓓV0⦄ ⊢ T0 ➡ T2 → ∀X2. ⬆[O, 1] X2 ≡ T2 →
 122    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 123    ∃∃T. ⦃G, L1⦄ ⊢ X1 ➡ T & ⦃G, L2⦄ ⊢ X2 ➡ T.
 124 #G #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 125 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 126 elim (IH … HT01 … HT02 (L1.ⓓV0) … (L2.ⓓV0)) -IH -HT01 -HT02 /2 width=1 by lpr_pair/ -L0 -T0 #T #HT1 #HT2
 127 elim (cpr_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=2 by drop_drop/ #T1 #HT1 #HXT1
 128 elim (cpr_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=2 by drop_drop/ #T2 #HT2 #HXT2
 129 lapply (lift_inj … HT2 … HT1) -T #H destruct /2 width=3 by ex2_intro/
 130 qed-.
 131
 132 fact cpr_conf_lpr_flat_flat:
 133    ∀I,G,L0,V0,T0. (
 134       ∀L,T. ⦃G, L0, ⓕ{I}V0.T0⦄ ⊐+ ⦃G, L, T⦄ →
 135       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 136       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 137       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 138    ) →
 139    ∀V1. ⦃G, L0⦄ ⊢ V0 ➡ V1 → ∀T1. ⦃G, L0⦄ ⊢ T0 ➡ T1 →
 140    ∀V2. ⦃G, L0⦄ ⊢ V0 ➡ V2 → ∀T2. ⦃G, L0⦄ ⊢ T0 ➡ T2 →
 141    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 142    ∃∃T. ⦃G, L1⦄ ⊢ ⓕ{I}V1.T1 ➡ T & ⦃G, L2⦄ ⊢ ⓕ{I}V2.T2 ➡ T.
 143 #I #G #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 144 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 145 elim (IH … HV01 … HV02 … HL01 … HL02) //
 146 elim (IH … HT01 … HT02 … HL01 … HL02) /3 width=5 by cpr_flat, ex2_intro/
 147 qed-.
 148
 149 fact cpr_conf_lpr_flat_eps:
 150    ∀G,L0,V0,T0. (
 151       ∀L,T. ⦃G, L0, ⓝV0.T0⦄ ⊐+ ⦃G, L, T⦄ →
 152       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 153       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 154       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 155    ) →
 156    ∀V1,T1. ⦃G, L0⦄ ⊢ T0 ➡ T1 → ∀T2. ⦃G, L0⦄ ⊢ T0 ➡ T2 →
 157    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 158    ∃∃T. ⦃G, L1⦄ ⊢ ⓝV1.T1 ➡ T & ⦃G, L2⦄ ⊢ T2 ➡ T.
 159 #G #L0 #V0 #T0 #IH #V1 #T1 #HT01
 160 #T2 #HT02 #L1 #HL01 #L2 #HL02
 161 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3 by cpr_eps, ex2_intro/
 162 qed-.
 163
 164 fact cpr_conf_lpr_eps_eps:
 165    ∀G,L0,V0,T0. (
 166       ∀L,T. ⦃G, L0, ⓝV0.T0⦄ ⊐+ ⦃G, L, T⦄ →
 167       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 168       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 169       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 170    ) →
 171    ∀T1. ⦃G, L0⦄ ⊢ T0 ➡ T1 → ∀T2. ⦃G, L0⦄ ⊢ T0 ➡ T2 →
 172    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 173    ∃∃T. ⦃G, L1⦄ ⊢ T1 ➡ T & ⦃G, L2⦄ ⊢ T2 ➡ T.
 174 #G #L0 #V0 #T0 #IH #T1 #HT01
 175 #T2 #HT02 #L1 #HL01 #L2 #HL02
 176 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /2 width=3 by ex2_intro/
 177 qed-.
 178
 179 fact cpr_conf_lpr_flat_beta:
 180    ∀a,G,L0,V0,W0,T0. (
 181       ∀L,T. ⦃G, L0, ⓐV0.ⓛ{a}W0.T0⦄ ⊐+ ⦃G, L, T⦄ →
 182       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 183       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 184       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 185    ) →
 186    ∀V1. ⦃G, L0⦄ ⊢ V0 ➡ V1 → ∀T1. ⦃G, L0⦄ ⊢ ⓛ{a}W0.T0 ➡ T1 →
 187    ∀V2. ⦃G, L0⦄ ⊢ V0 ➡ V2 → ∀W2. ⦃G, L0⦄ ⊢ W0 ➡ W2 → ∀T2. ⦃G, L0.ⓛW0⦄ ⊢ T0 ➡ T2 →
 188    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 189    ∃∃T. ⦃G, L1⦄ ⊢ ⓐV1.T1 ➡ T & ⦃G, L2⦄ ⊢ ⓓ{a}ⓝW2.V2.T2 ➡ T.
 190 #a #G #L0 #V0 #W0 #T0 #IH #V1 #HV01 #X #H
 191 #V2 #HV02 #W2 #HW02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 192 elim (cpr_inv_abst1 … H) -H #W1 #T1 #HW01 #HT01 #H destruct
 193 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1 by/ #V #HV1 #HV2
 194 elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1 by/ #W #HW1 #HW2
 195 elim (IH … HT01 … HT02 (L1.ⓛW1) … (L2.ⓛW2)) /2 width=1 by lpr_pair/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 196 lapply (lsubr_cpr_trans … HT2 (L2.ⓓⓝW2.V2) ?) -HT2 /2 width=1 by lsubr_beta/ (**) (* full auto not tried *)
 197 /4 width=5 by cpr_bind, cpr_flat, cpr_beta, ex2_intro/
 198 qed-.
 199
 200 (* Basic-1: includes:
 201             pr0_cong_upsilon_refl pr0_cong_upsilon_zeta
 202             pr0_cong_upsilon_cong pr0_cong_upsilon_delta
 203 *)
 204 fact cpr_conf_lpr_flat_theta:
 205    ∀a,G,L0,V0,W0,T0. (
 206       ∀L,T. ⦃G, L0, ⓐV0.ⓓ{a}W0.T0⦄ ⊐+ ⦃G, L, T⦄ →
 207       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 208       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 209       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 210    ) →
 211    ∀V1. ⦃G, L0⦄ ⊢ V0 ➡ V1 → ∀T1. ⦃G, L0⦄ ⊢ ⓓ{a}W0.T0 ➡ T1 →
 212    ∀V2. ⦃G, L0⦄ ⊢ V0 ➡ V2 → ∀U2. ⬆[O, 1] V2 ≡ U2 →
 213    ∀W2. ⦃G, L0⦄ ⊢ W0 ➡ W2 → ∀T2. ⦃G, L0.ⓓW0⦄ ⊢ T0 ➡ T2 →
 214    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 215    ∃∃T. ⦃G, L1⦄ ⊢ ⓐV1.T1 ➡ T & ⦃G, L2⦄ ⊢ ⓓ{a}W2.ⓐU2.T2 ➡ T.
 216 #a #G #L0 #V0 #W0 #T0 #IH #V1 #HV01 #X #H
 217 #V2 #HV02 #U2 #HVU2 #W2 #HW02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 218 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1 by/ #V #HV1 #HV2
 219 elim (lift_total V 0 1) #U #HVU
 220 lapply (cpr_lift … HV2 (L2.ⓓW2) … HVU2 … HVU) -HVU2 /2 width=2 by drop_drop/ #HU2
 221 elim (cpr_inv_abbr1 … H) -H *
 222 [ #W1 #T1 #HW01 #HT01 #H destruct
 223   elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1 by/
 224   elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1 by lpr_pair/ -L0 -V0 -W0 -T0
 225   /4 width=7 by cpr_bind, cpr_flat, cpr_theta, ex2_intro/
 226 | #T1 #HT01 #HXT1 #H destruct
 227   elim (IH … HT01 … HT02 (L1.ⓓW2) … (L2.ⓓW2)) /2 width=1 by lpr_pair/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 228   elim (cpr_inv_lift1 … HT1 L1 … HXT1) -HXT1
 229   /4 width=9 by cpr_flat, cpr_zeta, drop_drop, lift_flat, ex2_intro/
 230 ]
 231 qed-.
 232
 233 fact cpr_conf_lpr_beta_beta:
 234    ∀a,G,L0,V0,W0,T0. (
 235       ∀L,T. ⦃G, L0, ⓐV0.ⓛ{a}W0.T0⦄ ⊐+ ⦃G, L, T⦄ →
 236       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 237       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 238       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 239    ) →
 240    ∀V1. ⦃G, L0⦄ ⊢ V0 ➡ V1 → ∀W1. ⦃G, L0⦄ ⊢ W0 ➡ W1 → ∀T1. ⦃G, L0.ⓛW0⦄ ⊢ T0 ➡ T1 →
 241    ∀V2. ⦃G, L0⦄ ⊢ V0 ➡ V2 → ∀W2. ⦃G, L0⦄ ⊢ W0 ➡ W2 → ∀T2. ⦃G, L0.ⓛW0⦄ ⊢ T0 ➡ T2 →
 242    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 243    ∃∃T. ⦃G, L1⦄ ⊢ ⓓ{a}ⓝW1.V1.T1 ➡ T & ⦃G, L2⦄ ⊢ ⓓ{a}ⓝW2.V2.T2 ➡ T.
 244 #a #G #L0 #V0 #W0 #T0 #IH #V1 #HV01 #W1 #HW01 #T1 #HT01
 245 #V2 #HV02 #W2 #HW02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 246 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1 by/ #V #HV1 #HV2
 247 elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1 by/ #W #HW1 #HW2
 248 elim (IH … HT01 … HT02 (L1.ⓛW1) … (L2.ⓛW2)) /2 width=1 by lpr_pair/ -L0 -V0 -W0 -T0 #T #HT1 #HT2
 249 lapply (lsubr_cpr_trans … HT1 (L1.ⓓⓝW1.V1) ?) -HT1 /2 width=1 by lsubr_beta/
 250 lapply (lsubr_cpr_trans … HT2 (L2.ⓓⓝW2.V2) ?) -HT2 /2 width=1 by lsubr_beta/
 251 /4 width=5 by cpr_bind, cpr_flat, ex2_intro/ (**) (* full auto not tried *)
 252 qed-.
 253
 254 (* Basic_1: was: pr0_upsilon_upsilon *)
 255 fact cpr_conf_lpr_theta_theta:
 256    ∀a,G,L0,V0,W0,T0. (
 257       ∀L,T. ⦃G, L0, ⓐV0.ⓓ{a}W0.T0⦄ ⊐+ ⦃G, L, T⦄ →
 258       ∀T1. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 →
 259       ∀L1. ⦃G, L⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L⦄ ⊢ ➡ L2 →
 260       ∃∃T0. ⦃G, L1⦄ ⊢ T1 ➡ T0 & ⦃G, L2⦄ ⊢ T2 ➡ T0
 261    ) →
 262    ∀V1. ⦃G, L0⦄ ⊢ V0 ➡ V1 → ∀U1. ⬆[O, 1] V1 ≡ U1 →
 263    ∀W1. ⦃G, L0⦄ ⊢ W0 ➡ W1 → ∀T1. ⦃G, L0.ⓓW0⦄ ⊢ T0 ➡ T1 →
 264    ∀V2. ⦃G, L0⦄ ⊢ V0 ➡ V2 → ∀U2. ⬆[O, 1] V2 ≡ U2 →
 265    ∀W2. ⦃G, L0⦄ ⊢ W0 ➡ W2 → ∀T2. ⦃G, L0.ⓓW0⦄ ⊢ T0 ➡ T2 →
 266    ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 → ∀L2. ⦃G, L0⦄ ⊢ ➡ L2 →
 267    ∃∃T. ⦃G, L1⦄ ⊢ ⓓ{a}W1.ⓐU1.T1 ➡ T & ⦃G, L2⦄ ⊢ ⓓ{a}W2.ⓐU2.T2 ➡ T.
 268 #a #G #L0 #V0 #W0 #T0 #IH #V1 #HV01 #U1 #HVU1 #W1 #HW01 #T1 #HT01
 269 #V2 #HV02 #U2 #HVU2 #W2 #HW02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 270 elim (IH … HV01 … HV02 … HL01 … HL02) -HV01 -HV02 /2 width=1 by/ #V #HV1 #HV2
 271 elim (IH … HW01 … HW02 … HL01 … HL02) /2 width=1 by/
 272 elim (IH … HT01 … HT02 (L1.ⓓW1) … (L2.ⓓW2)) /2 width=1 by lpr_pair/ -L0 -V0 -W0 -T0
 273 elim (lift_total V 0 1) #U #HVU
 274 lapply (cpr_lift … HV1 (L1.ⓓW1) … HVU1 … HVU) -HVU1 /2 width=2 by drop_drop/
 275 lapply (cpr_lift … HV2 (L2.ⓓW2) … HVU2 … HVU) -HVU2 /2 width=2 by drop_drop/
 276 /4 width=7 by cpr_bind, cpr_flat, ex2_intro/ (**) (* full auto not tried *)
 277 qed-.
 278
 279 theorem cpr_conf_lpr: ∀G. lpx_sn_confluent (cpr G) (cpr G).
 280 #G #L0 #T0 @(fqup_wf_ind_eq … G L0 T0) -G -L0 -T0 #G #L #T #IH #G0 #L0 * [| * ]
 281 [ #I0 #HG #HL #HT #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 282   elim (cpr_inv_atom1 … H1) -H1
 283   elim (cpr_inv_atom1 … H2) -H2
 284   [ #H2 #H1 destruct
 285     /2 width=1 by cpr_conf_lpr_atom_atom/
 286   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 287     /3 width=10 by cpr_conf_lpr_atom_delta/
 288   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 289     /4 width=10 by ex2_commute, cpr_conf_lpr_atom_delta/
 290   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 291     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 292     /3 width=17 by cpr_conf_lpr_delta_delta/
 293   ]
 294 | #a #I #V0 #T0 #HG #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 295   elim (cpr_inv_bind1 … H1) -H1 *
 296   [ #V1 #T1 #HV01 #HT01 #H1
 297   | #T1 #HT01 #HXT1 #H11 #H12
 298   ]
 299   elim (cpr_inv_bind1 … H2) -H2 *
 300   [1,3: #V2 #T2 #HV02 #HT02 #H2
 301   |2,4: #T2 #HT02 #HXT2 #H21 #H22
 302   ] destruct
 303   [ /3 width=10 by cpr_conf_lpr_bind_bind/
 304   | /4 width=11 by ex2_commute, cpr_conf_lpr_bind_zeta/
 305   | /3 width=11 by cpr_conf_lpr_bind_zeta/
 306   | /3 width=12 by cpr_conf_lpr_zeta_zeta/
 307   ]
 308 | #I #V0 #T0 #HG #HL #HT #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 309   elim (cpr_inv_flat1 … H1) -H1 *
 310   [ #V1 #T1 #HV01 #HT01 #H1
 311   | #HX1 #H1
 312   | #a1 #V1 #Y1 #W1 #Z1 #T1 #HV01 #HYW1 #HZT1 #H11 #H12 #H13
 313   | #a1 #V1 #U1 #Y1 #W1 #Z1 #T1 #HV01 #HVU1 #HYW1 #HZT1 #H11 #H12 #H13
 314   ]
 315   elim (cpr_inv_flat1 … H2) -H2 *
 316   [1,5,9,13: #V2 #T2 #HV02 #HT02 #H2
 317   |2,6,10,14: #HX2 #H2
 318   |3,7,11,15: #a2 #V2 #Y2 #W2 #Z2 #T2 #HV02 #HYW2 #HZT2 #H21 #H22 #H23
 319   |4,8,12,16: #a2 #V2 #U2 #Y2 #W2 #Z2 #T2 #HV02 #HVU2 #HYW2 #HZT2 #H21 #H22 #H23
 320   ] destruct
 321   [ /3 width=10 by cpr_conf_lpr_flat_flat/
 322   | /4 width=8 by ex2_commute, cpr_conf_lpr_flat_eps/
 323   | /4 width=12 by ex2_commute, cpr_conf_lpr_flat_beta/
 324   | /4 width=14 by ex2_commute, cpr_conf_lpr_flat_theta/
 325   | /3 width=8 by cpr_conf_lpr_flat_eps/
 326   | /3 width=7 by cpr_conf_lpr_eps_eps/
 327   | /3 width=12 by cpr_conf_lpr_flat_beta/
 328   | /3 width=13 by cpr_conf_lpr_beta_beta/
 329   | /3 width=14 by cpr_conf_lpr_flat_theta/
 330   | /3 width=17 by cpr_conf_lpr_theta_theta/
 331   ]
 332 ]
 333 qed-.
 334
 335 (* Basic_1: includes: pr0_confluence pr2_confluence *)
 336 theorem cpr_conf: ∀G,L. confluent … (cpr G L).
 337 /2 width=6 by cpr_conf_lpr/ qed-.
 338
 339 (* Properties on context-sensitive parallel reduction for terms *************)
 340
 341 lemma lpr_cpr_conf_dx: ∀G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ➡ T1 → ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 →
 342                        ∃∃T. ⦃G, L1⦄ ⊢ T0 ➡ T & ⦃G, L1⦄ ⊢ T1 ➡ T.
 343 #G #L0 #T0 #T1 #HT01 #L1 #HL01
 344 elim (cpr_conf_lpr … HT01 T0 … HL01 … HL01) /2 width=3 by ex2_intro/
 345 qed-.
 346
 347 lemma lpr_cpr_conf_sn: ∀G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ➡ T1 → ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 →
 348                        ∃∃T. ⦃G, L1⦄ ⊢ T0 ➡ T & ⦃G, L0⦄ ⊢ T1 ➡ T.
 349 #G #L0 #T0 #T1 #HT01 #L1 #HL01
 350 elim (cpr_conf_lpr … HT01 T0 … L0 … HL01) /2 width=3 by ex2_intro/
 351 qed-.
 352
 353 (* Main properties **********************************************************)
 354
 355 theorem lpr_conf: ∀G. confluent … (lpr G).
 356 /3 width=6 by lpx_sn_conf, cpr_conf_lpr/
 357 qed-.