matita/matita/contribs/lambdadelta/basic_2A/reduction/lpx_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/static/aaa_lift.ma".
  16 include "basic_2A/static/lsuba_aaa.ma".
  17 include "basic_2A/reduction/lpx_drop.ma".
  18
  19 (* SN EXTENDED PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ********************)
  20
  21 (* Properties on atomic arity assignment for terms **************************)
  22
  23 (* Note: lemma 500 *)
  24 lemma cpx_lpx_aaa_conf: ∀h,g,G,L1,T1,A. ⦃G, L1⦄ ⊢ T1 ⁝ A →
  25                         ∀T2. ⦃G, L1⦄ ⊢ T1 ➡[h, g] T2 →
  26                         ∀L2. ⦃G, L1⦄ ⊢ ➡[h, g] L2 → ⦃G, L2⦄ ⊢ T2 ⁝ A.
  27 #h #g #G #L1 #T1 #A #H elim H -G -L1 -T1 -A
  28 [ #g #L1 #k #X #H
  29   elim (cpx_inv_sort1 … H) -H // * //
  30 | #I #G #L1 #K1 #V1 #B #i #HLK1 #_ #IHV1 #X #H #L2 #HL12
  31   elim (cpx_inv_lref1 … H) -H
  32   [ #H destruct
  33     elim (lpx_drop_conf … HLK1 … HL12) -L1 #X #H #HLK2
  34     elim (lpx_inv_pair1 … H) -H
  35     #K2 #V2 #HK12 #HV12 #H destruct /3 width=6 by aaa_lref/
  36   | * #J #Y #Z #V2 #H #HV12 #HV2
  37     lapply (drop_mono … H … HLK1) -H #H destruct
  38     elim (lpx_drop_conf … HLK1 … HL12) -L1 #Z #H #HLK2
  39     elim (lpx_inv_pair1 … H) -H #K2 #V0 #HK12 #_ #H destruct
  40     /3 width=8 by aaa_lift, drop_fwd_drop2/
  41   ]
  42 | #a #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  43   elim (cpx_inv_abbr1 … H) -H *
  44   [ #V2 #T2 #HV12 #HT12 #H destruct /4 width=2 by lpx_pair, aaa_abbr/
  45   | #T2 #HT12 #HT2 #H destruct -IHV1
  46     /4 width=8 by lpx_pair, aaa_inv_lift, drop_drop/
  47   ]
  48 | #a #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  49   elim (cpx_inv_abst1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct
  50   /4 width=1 by lpx_pair, aaa_abst/
  51 | #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  52   elim (cpx_inv_appl1 … H) -H *
  53   [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=3 by aaa_appl/
  54   | #b #V2 #W1 #W2 #U1 #U2 #HV12 #HW12 #HU12 #H1 #H2 destruct
  55     lapply (IHV1 … HV12 … HL12) -IHV1 -HV12 #HV2
  56     lapply (IHT1 (ⓛ{b}W2.U2) … HL12) -IHT1 /2 width=1 by cpx_bind/ -L1 #H
  57     elim (aaa_inv_abst … H) -H #B0 #A0 #HW1 #HU2 #H destruct
  58     /5 width=6 by lsuba_aaa_trans, lsuba_beta, aaa_abbr, aaa_cast/
  59   | #b #V #V2 #W1 #W2 #U1 #U2 #HV1 #HV2 #HW12 #HU12 #H1 #H2 destruct
  60     lapply (aaa_lift G L2 … B … (L2.ⓓW2) … HV2) -HV2 /2 width=2 by drop_drop/ #HV2
  61     lapply (IHT1 (ⓓ{b}W2.U2) … HL12) -IHT1 /2 width=1 by cpx_bind/ -L1 #H
  62     elim (aaa_inv_abbr … H) -H /3 width=3 by aaa_abbr, aaa_appl/
  63   ]
  64 | #G #L1 #V1 #T1 #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  65   elim (cpx_inv_cast1 … H) -H
  66   [ * #V2 #T2 #HV12 #HT12 #H destruct /3 width=1 by aaa_cast/
  67   | -IHV1 /2 width=1 by/
  68   | -IHT1 /2 width=1 by/
  69   ]
  70 ]
  71 qed-.
  72
  73 lemma cpx_aaa_conf: ∀h,g,G,L,T1,A. ⦃G, L⦄ ⊢ T1 ⁝ A → ∀T2. ⦃G, L⦄ ⊢ T1 ➡[h, g] T2 → ⦃G, L⦄ ⊢ T2 ⁝ A.
  74 /2 width=7 by cpx_lpx_aaa_conf/ qed-.
  75
  76 lemma lpx_aaa_conf: ∀h,g,G,L1,T,A. ⦃G, L1⦄ ⊢ T ⁝ A → ∀L2. ⦃G, L1⦄ ⊢ ➡[h, g] L2 → ⦃G, L2⦄ ⊢ T ⁝ A.
  77 /2 width=7 by cpx_lpx_aaa_conf/ qed-.
  78
  79 lemma cpr_aaa_conf: ∀G,L,T1,A. ⦃G, L⦄ ⊢ T1 ⁝ A → ∀T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ⦃G, L⦄ ⊢ T2 ⁝ A.
  80 /3 width=5 by cpx_aaa_conf, cpr_cpx/ qed-.
  81
  82 lemma lpr_aaa_conf: ∀G,L1,T,A. ⦃G, L1⦄ ⊢ T ⁝ A → ∀L2. ⦃G, L1⦄ ⊢ ➡ L2 → ⦃G, L2⦄ ⊢ T ⁝ A.
  83 /3 width=5 by lpx_aaa_conf, lpr_lpx/ qed-.