matita/matita/contribs/lambdadelta/basic_2A/reduction/lpx_drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/lpx_sn_drop.ma".
  16 include "basic_2A/reduction/cpx_lift.ma".
  17 include "basic_2A/reduction/lpx.ma".
  18
  19 (* SN EXTENDED PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ********************)
  20
  21 (* Properties on local environment slicing ***********************************)
  22
  23 lemma lpx_drop_conf: ∀h,g,G. dropable_sn (lpx h g G).
  24 /3 width=6 by lpx_sn_deliftable_dropable, cpx_inv_lift1/ qed-.
  25
  26 lemma drop_lpx_trans: ∀h,g,G. dedropable_sn (lpx h g G).
  27 /3 width=10 by lpx_sn_liftable_dedropable, cpx_lift/ qed-.
  28
  29 lemma lpx_drop_trans_O1: ∀h,g,G. dropable_dx (lpx h g G).
  30 /2 width=3 by lpx_sn_dropable/ qed-.
  31
  32 (* Properties on supclosure *************************************************)
  33
  34 lemma fqu_lpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  35                      ∀K2. ⦃G2, L2⦄ ⊢ ➡[h, g] K2 →
  36                      ∃∃K1,T. ⦃G1, L1⦄ ⊢ ➡[h, g] K1 & ⦃G1, L1⦄ ⊢ T1 ➡[h, g] T & ⦃G1, K1, T⦄ ⊐ ⦃G2, K2, T2⦄.
  37 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  38 /3 width=5 by fqu_lref_O, fqu_pair_sn, fqu_flat_dx, lpx_pair, ex3_2_intro/
  39 [ #a #I #G2 #L2 #V2 #T2 #X #H elim (lpx_inv_pair1 … H) -H
  40   #K2 #W2 #HLK2 #HVW2 #H destruct
  41   /3 width=5 by cpx_pair_sn, fqu_bind_dx, ex3_2_intro/
  42 | #G #L1 #K1 #T1 #U1 #m #HLK1 #HTU1 #K2 #HK12
  43   elim (drop_lpx_trans … HLK1 … HK12) -HK12
  44   /3 width=7 by fqu_drop, ex3_2_intro/
  45 ]
  46 qed-.
  47
  48 lemma fquq_lpx_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  49                       ∀K2. ⦃G2, L2⦄ ⊢ ➡[h, g] K2 →
  50                       ∃∃K1,T. ⦃G1, L1⦄ ⊢ ➡[h, g] K1 & ⦃G1, L1⦄ ⊢ T1 ➡[h, g] T & ⦃G1, K1, T⦄ ⊐⸮ ⦃G2, K2, T2⦄.
  51 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K2 #HLK2 elim (fquq_inv_gen … H) -H
  52 [ #HT12 elim (fqu_lpx_trans … HT12 … HLK2) /3 width=5 by fqu_fquq, ex3_2_intro/
  53 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  54 ]
  55 qed-.
  56
  57 lemma lpx_fqu_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  58                      ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 →
  59                      ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡[h, g] T & ⦃G1, K1, T⦄ ⊐ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2.
  60 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  61 /3 width=7 by fqu_pair_sn, fqu_bind_dx, fqu_flat_dx, lpx_pair, ex3_2_intro/
  62 [ #I #G1 #L1 #V1 #X #H elim (lpx_inv_pair2 … H) -H
  63   #K1 #W1 #HKL1 #HWV1 #H destruct elim (lift_total V1 0 1)
  64   /4 width=7 by cpx_delta, fqu_drop, drop_drop, ex3_2_intro/
  65 | #G #L1 #K1 #T1 #U1 #m #HLK1 #HTU1 #L0 #HL01
  66   elim (lpx_drop_trans_O1 … HL01 … HLK1) -L1
  67   /3 width=5 by fqu_drop, ex3_2_intro/
  68 ]
  69 qed-.
  70
  71 lemma lpx_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  72                       ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 →
  73                       ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ➡[h, g] T & ⦃G1, K1, T⦄ ⊐⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2.
  74 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #HKL1 elim (fquq_inv_gen … H) -H
  75 [ #HT12 elim (lpx_fqu_trans … HT12 … HKL1) /3 width=5 by fqu_fquq, ex3_2_intro/
  76 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  77 ]
  78 qed-.