matita/matita/contribs/lambdadelta/basic_2A/reduction/lpx_lleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/multiple/llor_drop.ma".
  16 include "basic_2A/multiple/llpx_sn_llor.ma".
  17 include "basic_2A/multiple/llpx_sn_lpx_sn.ma".
  18 include "basic_2A/multiple/lleq_lreq.ma".
  19 include "basic_2A/multiple/lleq_llor.ma".
  20 include "basic_2A/reduction/cpx_lreq.ma".
  21 include "basic_2A/reduction/cpx_lleq.ma".
  22 include "basic_2A/reduction/lpx_frees.ma".
  23
  24 (* SN EXTENDED PARALLEL REDUCTION FOR LOCAL ENVIRONMENTS ********************)
  25
  26 (* Properties on lazy equivalence for local environments ********************)
  27
  28 (* Note: contains a proof of llpx_cpx_conf *)
  29 lemma lleq_lpx_trans: ∀h,g,G,L2,K2. ⦃G, L2⦄ ⊢ ➡[h, g] K2 →
  30                       ∀L1,T,l. L1 ≡[T, l] L2 →
  31                       ∃∃K1. ⦃G, L1⦄ ⊢ ➡[h, g] K1 & K1 ≡[T, l] K2.
  32 #h #g #G #L2 #K2 #HLK2 #L1 #T #l #HL12
  33 lapply (lpx_fwd_length … HLK2) #H1
  34 lapply (lleq_fwd_length … HL12) #H2
  35 lapply (lpx_sn_llpx_sn … T … l HLK2) // -HLK2 #H
  36 lapply (lleq_llpx_sn_trans … HL12 … H) /2 width=3 by lleq_cpx_trans/ -HL12 -H #H
  37 elim (llor_total L1 K2 T l) // -H1 -H2 #K1 #HLK1
  38 lapply (llpx_sn_llor_dx_sym … H … HLK1)
  39 [ /2 width=6 by cpx_frees_trans/
  40 | /3 width=10 by cpx_llpx_sn_conf, cpx_inv_lift1, cpx_lift/
  41 | /3 width=5 by llpx_sn_llor_fwd_sn, ex2_intro/
  42 ]
  43 qed-.
  44
  45 lemma lpx_lleq_fqu_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  46                           ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ≡[T1, 0] L1 →
  47                           ∃∃K2. ⦃G1, K1, T1⦄ ⊐ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ≡[T2, 0] L2.
  48 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  49 [ #I #G1 #L1 #V1 #X #H1 #H2 elim (lpx_inv_pair2 … H1) -H1
  50   #K0 #V0 #H1KL1 #_ #H destruct
  51   elim (lleq_inv_lref_ge_dx … H2 ? I L1 V1) -H2 //
  52   #K1 #H #H2KL1 lapply (drop_inv_O2 … H) -H #H destruct
  53   /2 width=4 by fqu_lref_O, ex3_intro/
  54 | * [ #a ] #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H
  55   [ elim (lleq_inv_bind … H)
  56   | elim (lleq_inv_flat … H)
  57   ] -H /2 width=4 by fqu_pair_sn, ex3_intro/
  58 | #a #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_bind_O … H) -H
  59   /3 width=4 by lpx_pair, fqu_bind_dx, ex3_intro/
  60 | #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_flat … H) -H
  61   /2 width=4 by fqu_flat_dx, ex3_intro/
  62 | #G1 #L1 #L #T1 #U1 #m #HL1 #HTU1 #K1 #H1KL1 #H2KL1
  63   elim (drop_O1_le (Ⓕ) (m+1) K1)
  64   [ #K #HK1 lapply (lleq_inv_lift_le … H2KL1 … HK1 HL1 … HTU1 ?) -H2KL1 //
  65     #H2KL elim (lpx_drop_trans_O1 … H1KL1 … HL1) -L1
  66     #K0 #HK10 #H1KL lapply (drop_mono … HK10 … HK1) -HK10 #H destruct
  67     /3 width=4 by fqu_drop, ex3_intro/
  68   | lapply (drop_fwd_length_le2 … HL1) -L -T1 -g
  69     lapply (lleq_fwd_length … H2KL1) //
  70   ]
  71 ]
  72 qed-.
  73
  74 lemma lpx_lleq_fquq_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  75                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ≡[T1, 0] L1 →
  76                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ≡[T2, 0] L2.
  77 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
  78 elim (fquq_inv_gen … H) -H
  79 [ #H elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  80   /3 width=4 by fqu_fquq, ex3_intro/
  81 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
  82 ]
  83 qed-.
  84
  85 lemma lpx_lleq_fqup_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
  86                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ≡[T1, 0] L1 →
  87                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ≡[T2, 0] L2.
  88 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  89 [ #G2 #L2 #T2 #H #K1 #H1KL1 #H2KL1 elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
  90   /3 width=4 by fqu_fqup, ex3_intro/
  91 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #K1 #H1KL1 #H2KL1 elim (IHT1 … H2KL1) // -L1
  92   #K #HT1 #H1KL #H2KL elim (lpx_lleq_fqu_trans … HT2 … H1KL H2KL) -L
  93   /3 width=5 by fqup_strap1, ex3_intro/
  94 ]
  95 qed-.
  96
  97 lemma lpx_lleq_fqus_trans: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  98                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, g] L1 → K1 ≡[T1, 0] L1 →
  99                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, g] L2 & K2 ≡[T2, 0] L2.
 100 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
 101 elim (fqus_inv_gen … H) -H
 102 [ #H elim (lpx_lleq_fqup_trans … H … H1KL1 H2KL1) -L1
 103   /3 width=4 by fqup_fqus, ex3_intro/
 104 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
 105 ]
 106 qed-.
 107
 108 fact lreq_lpx_trans_lleq_aux: ∀h,g,G,L1,L0,l,m. L1 ⩬[l, m] L0 → m = ∞ →
 109                               ∀L2. ⦃G, L0⦄ ⊢ ➡[h, g] L2 →
 110                               ∃∃L. L ⩬[l, m] L2 & ⦃G, L1⦄ ⊢ ➡[h, g] L &
 111                                    (∀T. L0 ≡[T, l] L2 ↔ L1 ≡[T, l] L).
 112 #h #g #G #L1 #L0 #l #m #H elim H -L1 -L0 -l -m
 113 [ #l #m #_ #L2 #H >(lpx_inv_atom1 … H) -H
 114   /3 width=5 by ex3_intro, conj/
 115 | #I1 #I0 #L1 #L0 #V1 #V0 #_ #_ #Hm destruct
 116 | #I #L1 #L0 #V1 #m #HL10 #IHL10 #Hm #Y #H
 117   elim (lpx_inv_pair1 … H) -H #L2 #V2 #HL02 #HV02 #H destruct
 118   lapply (ysucc_inv_Y_dx … Hm) -Hm #Hm
 119   elim (IHL10 … HL02) // -IHL10 -HL02 #L #HL2 #HL1 #IH
 120   @(ex3_intro … (L.ⓑ{I}V2)) /3 width=3 by lpx_pair, lreq_cpx_trans, lreq_pair/
 121   #T elim (IH T) #HL0dx #HL0sn
 122   @conj #H @(lleq_lreq_repl … H) -H /3 width=1 by lreq_sym, lreq_pair_O_Y/
 123 | #I1 #I0 #L1 #L0 #V1 #V0 #l #m #HL10 #IHL10 #Hm #Y #H
 124   elim (lpx_inv_pair1 … H) -H #L2 #V2 #HL02 #HV02 #H destruct
 125   elim (IHL10 … HL02) // -IHL10 -HL02 #L #HL2 #HL1 #IH
 126   @(ex3_intro … (L.ⓑ{I1}V1)) /3 width=1 by lpx_pair, lreq_succ/
 127   #T elim (IH T) #HL0dx #HL0sn
 128   @conj #H @(lleq_lreq_repl … H) -H /3 width=1 by lreq_sym, lreq_succ/
 129 ]
 130 qed-.
 131
 132 lemma lreq_lpx_trans_lleq: ∀h,g,G,L1,L0,l. L1 ⩬[l, ∞] L0 →
 133                            ∀L2. ⦃G, L0⦄ ⊢ ➡[h, g] L2 →
 134                            ∃∃L. L ⩬[l, ∞] L2 & ⦃G, L1⦄ ⊢ ➡[h, g] L &
 135                                 (∀T. L0 ≡[T, l] L2 ↔ L1 ≡[T, l] L).
 136 /2 width=1 by lreq_lpx_trans_lleq_aux/ qed-.