matita/matita/contribs/lambdadelta/basic_2A/substitution/cpy_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/drop_drop.ma".
  16 include "basic_2A/substitution/cpy.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED ORDINARY SUBSTITUTION FOR TERMS ***************)
  19
  20 (* Properties on relocation *************************************************)
  21
  22 (* Basic_1: was: subst1_lift_lt *)
  23 lemma cpy_lift_le: ∀G,K,T1,T2,lt,mt. ⦃G, K⦄ ⊢ T1 ▶[lt, mt] T2 →
  24                    ∀L,U1,U2,s,l,m. ⬇[s, l, m] L ≡ K →
  25                    ⬆[l, m] T1 ≡ U1 → ⬆[l, m] T2 ≡ U2 →
  26                    lt + mt ≤ l → ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2.
  27 #G #K #T1 #T2 #lt #mt #H elim H -G -K -T1 -T2 -lt -mt
  28 [ #I #G #K #lt #mt #L #U1 #U2 #s #l #m #_ #H1 #H2 #_
  29   >(lift_mono … H1 … H2) -H1 -H2 //
  30 | #I #G #K #KV #V #W #i #lt #mt #Hlti #Hilmt #HKV #HVW #L #U1 #U2 #s #l #m #HLK #H #HWU2 #Hlmtl
  31   lapply (ylt_yle_trans … Hlmtl … Hilmt) -Hlmtl #Hil
  32   lapply (ylt_inv_inj … Hil) -Hil #Hil
  33   lapply (lift_inv_lref1_lt … H … Hil) -H #H destruct
  34   elim (lift_trans_ge … HVW … HWU2) -W // <minus_plus #W #HVW #HWU2
  35   elim (drop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  36   elim (drop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hil #K #Y #_ #HVY
  37   >(lift_mono … HVY … HVW) -Y -HVW #H destruct /2 width=5 by cpy_subst/
  38 | #a #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hlmtl
  39   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  40   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  41   /4 width=7 by cpy_bind, drop_skip, yle_succ/
  42 | #G #I #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hlmtl
  43   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  44   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  45   /3 width=7 by cpy_flat/
  46 ]
  47 qed-.
  48
  49 lemma cpy_lift_be: ∀G,K,T1,T2,lt,mt. ⦃G, K⦄ ⊢ T1 ▶[lt, mt] T2 →
  50                    ∀L,U1,U2,s,l,m. ⬇[s, l, m] L ≡ K →
  51                    ⬆[l, m] T1 ≡ U1 → ⬆[l, m] T2 ≡ U2 →
  52                    lt ≤ l → l ≤ lt + mt → ⦃G, L⦄ ⊢ U1 ▶[lt, mt + m] U2.
  53 #G #K #T1 #T2 #lt #mt #H elim H -G -K -T1 -T2 -lt -mt
  54 [ #I #G #K #lt #mt #L #U1 #U2 #s #l #m #_ #H1 #H2 #_ #_
  55   >(lift_mono … H1 … H2) -H1 -H2 //
  56 | #I #G #K #KV #V #W #i #lt #mt #Hlti #Hilmt #HKV #HVW #L #U1 #U2 #s #l #m #HLK #H #HWU2 #Hltl #_
  57   elim (lift_inv_lref1 … H) -H * #Hil #H destruct
  58   [ -Hltl
  59     lapply (ylt_yle_trans … (lt+mt+m) … Hilmt) // -Hilmt #Hilmtm
  60     elim (lift_trans_ge … HVW … HWU2) -W // <minus_plus #W #HVW #HWU2
  61     elim (drop_trans_le … HLK … HKV) -K /2 width=2 by lt_to_le/ #X #HLK #H
  62     elim (drop_inv_skip2 … H) -H /2 width=1 by lt_plus_to_minus_r/ -Hil #K #Y #_ #HVY
  63     >(lift_mono … HVY … HVW) -V #H destruct /2 width=5 by cpy_subst/
  64   | -Hlti
  65     elim (yle_inv_inj2 … Hltl) -Hltl #ltt #Hltl #H destruct
  66     lapply (transitive_le … Hltl Hil) -Hltl #Hlti
  67     lapply (lift_trans_be … HVW … HWU2 ? ?) -W /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  68     lapply (drop_trans_ge_comm … HLK … HKV ?) -K // -Hil
  69     /4 width=5 by cpy_subst, drop_inv_gen, monotonic_ylt_plus_dx, yle_plus_dx1_trans, yle_inj/
  70   ]
  71 | #a #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hltl #Hllmt
  72   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  73   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  74   /4 width=7 by cpy_bind, drop_skip, yle_succ/
  75 | #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hlmtl
  76   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  77   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
  78   /3 width=7 by cpy_flat/
  79 ]
  80 qed-.
  81
  82 (* Basic_1: was: subst1_lift_ge *)
  83 lemma cpy_lift_ge: ∀G,K,T1,T2,lt,mt. ⦃G, K⦄ ⊢ T1 ▶[lt, mt] T2 →
  84                    ∀L,U1,U2,s,l,m. ⬇[s, l, m] L ≡ K →
  85                    ⬆[l, m] T1 ≡ U1 → ⬆[l, m] T2 ≡ U2 →
  86                    l ≤ lt → ⦃G, L⦄ ⊢ U1 ▶[lt+m, mt] U2.
  87 #G #K #T1 #T2 #lt #mt #H elim H -G -K -T1 -T2 -lt -mt
  88 [ #I #G #K #lt #mt #L #U1 #U2 #s #l #m #_ #H1 #H2 #_
  89   >(lift_mono … H1 … H2) -H1 -H2 //
  90 | #I #G #K #KV #V #W #i #lt #mt #Hlti #Hilmt #HKV #HVW #L #U1 #U2 #s #l #m #HLK #H #HWU2 #Hllt
  91   lapply (yle_trans … Hllt … Hlti) -Hllt #Hil
  92   elim (yle_inv_inj2 … Hil) -Hil #ll #Hlli #H0 destruct
  93   lapply (lift_inv_lref1_ge … H … Hlli) -H #H destruct
  94   lapply (lift_trans_be … HVW … HWU2 ? ?) -W /2 width=1 by le_S/ >plus_plus_comm_23 #HVU2
  95   lapply (drop_trans_ge_comm … HLK … HKV ?) -K // -Hlli
  96   /3 width=5 by cpy_subst, drop_inv_gen, monotonic_ylt_plus_dx, monotonic_yle_plus_dx/
  97 | #a #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hllt
  98   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  99   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
 100   /4 width=6 by cpy_bind, drop_skip, yle_succ/
 101 | #I #G #K #V1 #V2 #T1 #T2 #lt #mt #_ #_ #IHV12 #IHT12 #L #U1 #U2 #s #l #m #HLK #H1 #H2 #Hllt
 102   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
 103   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct
 104   /3 width=6 by cpy_flat/
 105 ]
 106 qed-.
 107
 108 (* Inversion lemmas on relocation *******************************************)
 109
 110 (* Basic_1: was: subst1_gen_lift_lt *)
 111 lemma cpy_inv_lift1_le: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 112                         ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 113                         lt + mt ≤ l →
 114                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt, mt] T2 & ⬆[l, m] T2 ≡ U2.
 115 #G #L #U1 #U2 #lt #mt #H elim H -G -L -U1 -U2 -lt -mt
 116 [ * #i #G #L #lt #mt #K #s #l #m #_ #T1 #H #_
 117   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 118   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 119   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 120   ]
 121 | #I #G #L #KV #V #W #i #lt #mt #Hlti #Hilmt #HLKV #HVW #K #s #l #m #HLK #T1 #H #Hlmtl
 122   lapply (ylt_yle_trans … Hlmtl … Hilmt) -Hlmtl #Hil
 123   lapply (ylt_inv_inj … Hil) -Hil #Hil
 124   lapply (lift_inv_lref2_lt … H … Hil) -H #H destruct
 125   elim (drop_conf_lt … HLK … HLKV) -L // #L #U #HKL #_ #HUV
 126   elim (lift_trans_le … HUV … HVW) -V // >minus_plus <plus_minus_m_m // -Hil /3 width=5 by cpy_subst, ex2_intro/
 127 | #a #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hlmtl
 128   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 129   elim (IHW12 … HLK … HVW1) -IHW12 // #V2 #HV12 #HVW2
 130   elim (IHU12 … HTU1) -IHU12 -HTU1
 131   /3 width=6 by cpy_bind, yle_succ, drop_skip, lift_bind, ex2_intro/
 132 | #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hlmtl
 133   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 134   elim (IHW12 … HLK … HVW1) -W1 //
 135   elim (IHU12 … HLK … HTU1) -U1 -HLK
 136   /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 137 ]
 138 qed-.
 139
 140 lemma cpy_inv_lift1_be: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 141                         ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 142                         lt ≤ l → yinj l + m ≤ lt + mt →
 143                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt, mt-m] T2 & ⬆[l, m] T2 ≡ U2.
 144 #G #L #U1 #U2 #lt #mt #H elim H -G -L -U1 -U2 -lt -mt
 145 [ * #i #G #L #lt #mt #K #s #l #m #_ #T1 #H #_ #_
 146   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 147   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 148   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 149   ]
 150 | #I #G #L #KV #V #W #i #lt #mt #Hlti #Hilmt #HLKV #HVW #K #s #l #m #HLK #T1 #H #Hltl #Hlmlmt
 151   lapply (yle_fwd_plus_ge_inj … Hltl Hlmlmt) #Hmmt
 152   elim (lift_inv_lref2 … H) -H * #Hil #H destruct [ -Hltl -Hilmt | -Hlti -Hlmlmt ]
 153   [ lapply (ylt_yle_trans i l (lt+(mt-m)) ? ?) /2 width=1 by ylt_inj/
 154     [ >yplus_minus_assoc_inj /2 width=1 by yle_plus1_to_minus_inj2/ ] -Hlmlmt #Hilmtm
 155     elim (drop_conf_lt … HLK … HLKV) -L // #L #U #HKL #_ #HUV
 156     elim (lift_trans_le … HUV … HVW) -V // >minus_plus <plus_minus_m_m // -Hil
 157     /3 width=5 by cpy_subst, ex2_intro/
 158   | elim (le_inv_plus_l … Hil) #Hlim #Hmi
 159     lapply (yle_trans … Hltl (i-m) ?) /2 width=1 by yle_inj/ -Hltl #Hltim
 160     lapply (drop_conf_ge … HLK … HLKV ?) -L // #HKV
 161     elim (lift_split … HVW l (i-m+1)) -HVW [2,3,4: /2 width=1 by le_S_S, le_S/ ] -Hil -Hlim
 162     #V1 #HV1 >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O #H
 163     @(ex2_intro … H) @(cpy_subst … HKV HV1) // (**) (* explicit constructor *)
 164     >yplus_minus_assoc_inj /3 width=1 by monotonic_ylt_minus_dx, yle_inj/
 165   ]
 166 | #a #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hltl #Hlmlmt
 167   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 168   elim (IHW12 … HLK … HVW1) -IHW12 // #V2 #HV12 #HVW2
 169   elim (IHU12 … HTU1) -U1
 170   /3 width=6 by cpy_bind, drop_skip, lift_bind, yle_succ, ex2_intro/
 171 | #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hltl #Hlmlmt
 172   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 173   elim (IHW12 … HLK … HVW1) -W1 //
 174   elim (IHU12 … HLK … HTU1) -U1 -HLK //
 175   /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 176 ]
 177 qed-.
 178
 179 (* Basic_1: was: subst1_gen_lift_ge *)
 180 lemma cpy_inv_lift1_ge: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 181                         ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 182                         yinj l + m ≤ lt →
 183                         ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt-m, mt] T2 & ⬆[l, m] T2 ≡ U2.
 184 #G #L #U1 #U2 #lt #mt #H elim H -G -L -U1 -U2 -lt -mt
 185 [ * #i #G #L #lt #mt #K #s #l #m #_ #T1 #H #_
 186   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 187   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 188   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 189   ]
 190 | #I #G #L #KV #V #W #i #lt #mt #Hlti #Hilmt #HLKV #HVW #K #s #l #m #HLK #T1 #H #Hlmlt
 191   lapply (yle_trans … Hlmlt … Hlti) #Hlmi
 192   elim (yle_inv_plus_inj2 … Hlmlt) -Hlmlt #_ #Hmlt
 193   elim (yle_inv_plus_inj2 … Hlmi) #Hlim #Hmi
 194   lapply (lift_inv_lref2_ge  … H ?) -H /2 width=1 by yle_inv_inj/ #H destruct
 195   lapply (drop_conf_ge … HLK … HLKV ?) -L /2 width=1 by yle_inv_inj/ #HKV
 196   elim (lift_split … HVW l (i-m+1)) -HVW [2,3,4: /3 width=1 by yle_inv_inj, le_S_S, le_S/ ] -Hlmi -Hlim
 197   #V0 #HV10 >plus_minus /2 width=1 by yle_inv_inj/ <minus_minus /3 width=1 by yle_inv_inj, le_S/ <minus_n_n <plus_n_O #H
 198   @(ex2_intro … H) @(cpy_subst … HKV HV10) (**) (* explicit constructor *)
 199   [ /2 width=1 by monotonic_yle_minus_dx/
 200   | <yplus_minus_comm_inj /2 width=1 by monotonic_ylt_minus_dx/
 201   ]
 202 | #a #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hlmtl
 203   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 204   elim (yle_inv_plus_inj2 … Hlmtl) #_ #Hmlt
 205   elim (IHW12 … HLK … HVW1) -IHW12 // #V2 #HV12 #HVW2
 206   elim (IHU12 … HTU1) -U1 [4: @drop_skip // |2,5: skip |3: /2 width=1 by yle_succ/ ]
 207   >yminus_succ1_inj /3 width=5 by cpy_bind, lift_bind, ex2_intro/
 208 | #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #K #s #l #m #HLK #X #H #Hlmtl
 209   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 210   elim (IHW12 … HLK … HVW1) -W1 //
 211   elim (IHU12 … HLK … HTU1) -U1 -HLK /3 width=5 by cpy_flat, lift_flat, ex2_intro/
 212 ]
 213 qed-.
 214
 215 (* Advanced inversion lemmas on relocation ***********************************)
 216
 217 lemma cpy_inv_lift1_ge_up: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 218                            ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 219                            l ≤ lt → lt ≤ yinj l + m → yinj l + m ≤ lt + mt →
 220                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[l, lt + mt - (yinj l + m)] T2 & ⬆[l, m] T2 ≡ U2.
 221 #G #L #U1 #U2 #lt #mt #HU12 #K #s #l #m #HLK #T1 #HTU1 #Hllt #Hltlm #Hlmlmt
 222 elim (cpy_split_up … HU12 (l + m)) -HU12 // -Hlmlmt #U #HU1 #HU2
 223 lapply (cpy_weak … HU1 l m ? ?) -HU1 // [ >ymax_pre_sn_comm // ] -Hllt -Hltlm #HU1
 224 lapply (cpy_inv_lift1_eq … HTU1 … HU1) -HU1 #HU1 destruct
 225 elim (cpy_inv_lift1_ge … HU2 … HLK … HTU1) -U -L /2 width=3 by ex2_intro/
 226 qed-.
 227
 228 lemma cpy_inv_lift1_be_up: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 229                            ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 230                            lt ≤ l → lt + mt ≤ yinj l + m →
 231                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt, l-lt] T2 & ⬆[l, m] T2 ≡ U2.
 232 #G #L #U1 #U2 #lt #mt #HU12 #K #s #l #m #HLK #T1 #HTU1 #Hltl #Hlmtlm
 233 lapply (cpy_weak … HU12 lt (l+m-lt) ? ?) -HU12 //
 234 [ >ymax_pre_sn_comm /2 width=1 by yle_plus_dx1_trans/ ] -Hlmtlm #HU12
 235 elim (cpy_inv_lift1_be … HU12 … HLK … HTU1) -U1 -L /2 width=3 by ex2_intro/
 236 qed-.
 237
 238 lemma cpy_inv_lift1_le_up: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 239                            ∀K,s,l,m. ⬇[s, l, m] L ≡ K → ∀T1. ⬆[l, m] T1 ≡ U1 →
 240                            lt ≤ l → l ≤ lt + mt → lt + mt ≤ yinj l + m →
 241                            ∃∃T2. ⦃G, K⦄ ⊢ T1 ▶[lt, l - lt] T2 & ⬆[l, m] T2 ≡ U2.
 242 #G #L #U1 #U2 #lt #mt #HU12 #K #s #l #m #HLK #T1 #HTU1 #Hltl #Hllmt #Hlmtlm
 243 elim (cpy_split_up … HU12 l) -HU12 // #U #HU1 #HU2
 244 elim (cpy_inv_lift1_le … HU1 … HLK … HTU1) -U1
 245 [2: >ymax_pre_sn_comm // ] -Hltl #T #HT1 #HTU
 246 lapply (cpy_weak … HU2 l m ? ?) -HU2 //
 247 [ >ymax_pre_sn_comm // ] -Hllmt -Hlmtlm #HU2
 248 lapply (cpy_inv_lift1_eq … HTU … HU2) -L #H destruct /2 width=3 by ex2_intro/
 249 qed-.