matita/matita/contribs/lambdadelta/basic_2A/substitution/drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2A/lib/lstar.ma".
  16 include "basic_2A/notation/relations/rdrop_5.ma".
  17 include "basic_2A/notation/relations/rdrop_4.ma".
  18 include "basic_2A/notation/relations/rdrop_3.ma".
  19 include "basic_2A/grammar/lenv_length.ma".
  20 include "basic_2A/grammar/cl_restricted_weight.ma".
  21 include "basic_2A/substitution/lift.ma".
  22
  23 (* BASIC SLICING FOR LOCAL ENVIRONMENTS *************************************)
  24
  25 (* Basic_1: includes: drop_skip_bind *)
  26 inductive drop (s:bool): relation4 nat nat lenv lenv ≝
  27 | drop_atom: ∀l,m. (s = Ⓕ → m = 0) → drop s l m (⋆) (⋆)
  28 | drop_pair: ∀I,L,V. drop s 0 0 (L.ⓑ{I}V) (L.ⓑ{I}V)
  29 | drop_drop: ∀I,L1,L2,V,m. drop s 0 m L1 L2 → drop s 0 (m+1) (L1.ⓑ{I}V) L2
  30 | drop_skip: ∀I,L1,L2,V1,V2,l,m.
  31              drop s l m L1 L2 → ⬆[l, m] V2 ≡ V1 →
  32              drop s (l+1) m (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  33 .
  34
  35 interpretation
  36    "basic slicing (local environment) abstract"
  37    'RDrop s l m L1 L2 = (drop s l m L1 L2).
  38 (*
  39 interpretation
  40    "basic slicing (local environment) general"
  41    'RDrop d e L1 L2 = (drop true d e L1 L2).
  42 *)
  43 interpretation
  44    "basic slicing (local environment) lget"
  45    'RDrop m L1 L2 = (drop false O m L1 L2).
  46
  47 definition d_liftable: predicate (lenv → relation term) ≝
  48                        λR. ∀K,T1,T2. R K T1 T2 → ∀L,s,l,m. ⬇[s, l, m] L ≡ K →
  49                        ∀U1. ⬆[l, m] T1 ≡ U1 → ∀U2. ⬆[l, m] T2 ≡ U2 → R L U1 U2.
  50
  51 definition d_deliftable_sn: predicate (lenv → relation term) ≝
  52                             λR. ∀L,U1,U2. R L U1 U2 → ∀K,s,l,m. ⬇[s, l, m] L ≡ K →
  53                             ∀T1. ⬆[l, m] T1 ≡ U1 →
  54                             ∃∃T2. ⬆[l, m] T2 ≡ U2 & R K T1 T2.
  55
  56 definition dropable_sn: predicate (relation lenv) ≝
  57                         λR. ∀L1,K1,s,l,m. ⬇[s, l, m] L1 ≡ K1 → ∀L2. R L1 L2 →
  58                         ∃∃K2. R K1 K2 & ⬇[s, l, m] L2 ≡ K2.
  59
  60 definition dropable_dx: predicate (relation lenv) ≝
  61                         λR. ∀L1,L2. R L1 L2 → ∀K2,s,m. ⬇[s, 0, m] L2 ≡ K2 →
  62                         ∃∃K1. ⬇[s, 0, m] L1 ≡ K1 & R K1 K2.
  63
  64 (* Basic inversion lemmas ***************************************************)
  65
  66 fact drop_inv_atom1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → L1 = ⋆ →
  67                          L2 = ⋆ ∧ (s = Ⓕ → m = 0).
  68 #L1 #L2 #s #l #m * -L1 -L2 -l -m
  69 [ /3 width=1 by conj/
  70 | #I #L #V #H destruct
  71 | #I #L1 #L2 #V #m #_ #H destruct
  72 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #H destruct
  73 ]
  74 qed-.
  75
  76 (* Basic_1: was: drop_gen_sort *)
  77 lemma drop_inv_atom1: ∀L2,s,l,m. ⬇[s, l, m] ⋆ ≡ L2 → L2 = ⋆ ∧ (s = Ⓕ → m = 0).
  78 /2 width=4 by drop_inv_atom1_aux/ qed-.
  79
  80 fact drop_inv_O1_pair1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → l = 0 →
  81                             ∀K,I,V. L1 = K.ⓑ{I}V →
  82                             (m = 0 ∧ L2 = K.ⓑ{I}V) ∨
  83                             (0 < m ∧ ⬇[s, l, m-1] K ≡ L2).
  84 #L1 #L2 #s #l #m * -L1 -L2 -l -m
  85 [ #l #m #_ #_ #K #J #W #H destruct
  86 | #I #L #V #_ #K #J #W #HX destruct /3 width=1 by or_introl, conj/
  87 | #I #L1 #L2 #V #m #HL12 #_ #K #J #W #H destruct /3 width=1 by or_intror, conj/
  88 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ >commutative_plus normalize #H destruct
  89 ]
  90 qed-.
  91
  92 lemma drop_inv_O1_pair1: ∀I,K,L2,V,s,m. ⬇[s, 0, m] K. ⓑ{I} V ≡ L2 →
  93                          (m = 0 ∧ L2 = K.ⓑ{I}V) ∨
  94                          (0 < m ∧ ⬇[s, 0, m-1] K ≡ L2).
  95 /2 width=3 by drop_inv_O1_pair1_aux/ qed-.
  96
  97 lemma drop_inv_pair1: ∀I,K,L2,V,s. ⬇[s, 0, 0] K.ⓑ{I}V ≡ L2 → L2 = K.ⓑ{I}V.
  98 #I #K #L2 #V #s #H
  99 elim (drop_inv_O1_pair1 … H) -H * // #H destruct
 100 elim (lt_refl_false … H)
 101 qed-.
 102
 103 (* Basic_1: was: drop_gen_drop *)
 104 lemma drop_inv_drop1_lt: ∀I,K,L2,V,s,m.
 105                          ⬇[s, 0, m] K.ⓑ{I}V ≡ L2 → 0 < m → ⬇[s, 0, m-1] K ≡ L2.
 106 #I #K #L2 #V #s #m #H #Hm
 107 elim (drop_inv_O1_pair1 … H) -H * // #H destruct
 108 elim (lt_refl_false … Hm)
 109 qed-.
 110
 111 lemma drop_inv_drop1: ∀I,K,L2,V,s,m.
 112                       ⬇[s, 0, m+1] K.ⓑ{I}V ≡ L2 → ⬇[s, 0, m] K ≡ L2.
 113 #I #K #L2 #V #s #m #H lapply (drop_inv_drop1_lt … H ?) -H //
 114 qed-.
 115
 116 fact drop_inv_skip1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → 0 < l →
 117                          ∀I,K1,V1. L1 = K1.ⓑ{I}V1 →
 118                          ∃∃K2,V2. ⬇[s, l-1, m] K1 ≡ K2 &
 119                                   ⬆[l-1, m] V2 ≡ V1 &
 120                                    L2 = K2.ⓑ{I}V2.
 121 #L1 #L2 #s #l #m * -L1 -L2 -l -m
 122 [ #l #m #_ #_ #J #K1 #W1 #H destruct
 123 | #I #L #V #H elim (lt_refl_false … H)
 124 | #I #L1 #L2 #V #m #_ #H elim (lt_refl_false … H)
 125 | #I #L1 #L2 #V1 #V2 #l #m #HL12 #HV21 #_ #J #K1 #W1 #H destruct /2 width=5 by ex3_2_intro/
 126 ]
 127 qed-.
 128
 129 (* Basic_1: was: drop_gen_skip_l *)
 130 lemma drop_inv_skip1: ∀I,K1,V1,L2,s,l,m. ⬇[s, l, m] K1.ⓑ{I}V1 ≡ L2 → 0 < l →
 131                       ∃∃K2,V2. ⬇[s, l-1, m] K1 ≡ K2 &
 132                                ⬆[l-1, m] V2 ≡ V1 &
 133                                L2 = K2.ⓑ{I}V2.
 134 /2 width=3 by drop_inv_skip1_aux/ qed-.
 135
 136 lemma drop_inv_O1_pair2: ∀I,K,V,s,m,L1. ⬇[s, 0, m] L1 ≡ K.ⓑ{I}V →
 137                          (m = 0 ∧ L1 = K.ⓑ{I}V) ∨
 138                          ∃∃I1,K1,V1. ⬇[s, 0, m-1] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & 0 < m.
 139 #I #K #V #s #m *
 140 [ #H elim (drop_inv_atom1 … H) -H #H destruct
 141 | #L1 #I1 #V1 #H
 142   elim (drop_inv_O1_pair1 … H) -H *
 143   [ #H1 #H2 destruct /3 width=1 by or_introl, conj/
 144   | /3 width=5 by ex3_3_intro, or_intror/
 145   ]
 146 ]
 147 qed-.
 148
 149 fact drop_inv_skip2_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → 0 < l →
 150                          ∀I,K2,V2. L2 = K2.ⓑ{I}V2 →
 151                          ∃∃K1,V1. ⬇[s, l-1, m] K1 ≡ K2 &
 152                                   ⬆[l-1, m] V2 ≡ V1 &
 153                                   L1 = K1.ⓑ{I}V1.
 154 #L1 #L2 #s #l #m * -L1 -L2 -l -m
 155 [ #l #m #_ #_ #J #K2 #W2 #H destruct
 156 | #I #L #V #H elim (lt_refl_false … H)
 157 | #I #L1 #L2 #V #m #_ #H elim (lt_refl_false … H)
 158 | #I #L1 #L2 #V1 #V2 #l #m #HL12 #HV21 #_ #J #K2 #W2 #H destruct /2 width=5 by ex3_2_intro/
 159 ]
 160 qed-.
 161
 162 (* Basic_1: was: drop_gen_skip_r *)
 163 lemma drop_inv_skip2: ∀I,L1,K2,V2,s,l,m. ⬇[s, l, m] L1 ≡ K2.ⓑ{I}V2 → 0 < l →
 164                       ∃∃K1,V1. ⬇[s, l-1, m] K1 ≡ K2 & ⬆[l-1, m] V2 ≡ V1 &
 165                                L1 = K1.ⓑ{I}V1.
 166 /2 width=3 by drop_inv_skip2_aux/ qed-.
 167
 168 lemma drop_inv_O1_gt: ∀L,K,m,s. ⬇[s, 0, m] L ≡ K → |L| < m →
 169                       s = Ⓣ ∧ K = ⋆.
 170 #L elim L -L [| #L #Z #X #IHL ] #K #m #s #H normalize in ⊢ (?%?→?); #H1m
 171 [ elim (drop_inv_atom1 … H) -H elim s -s /2 width=1 by conj/
 172   #_ #Hs lapply (Hs ?) // -Hs #H destruct elim (lt_zero_false … H1m)
 173 | elim (drop_inv_O1_pair1 … H) -H * #H2m #HLK destruct
 174   [ elim (lt_zero_false … H1m)
 175   | elim (IHL … HLK) -IHL -HLK /2 width=1 by lt_plus_to_minus_r, conj/
 176   ]
 177 ]
 178 qed-.
 179
 180 (* Basic properties *********************************************************)
 181
 182 lemma drop_refl_atom_O2: ∀s,l. ⬇[s, l, O] ⋆ ≡ ⋆.
 183 /2 width=1 by drop_atom/ qed.
 184
 185 (* Basic_1: was by definition: drop_refl *)
 186 lemma drop_refl: ∀L,l,s. ⬇[s, l, 0] L ≡ L.
 187 #L elim L -L //
 188 #L #I #V #IHL #l #s @(nat_ind_plus … l) -l /2 width=1 by drop_pair, drop_skip/
 189 qed.
 190
 191 lemma drop_drop_lt: ∀I,L1,L2,V,s,m.
 192                     ⬇[s, 0, m-1] L1 ≡ L2 → 0 < m → ⬇[s, 0, m] L1.ⓑ{I}V ≡ L2.
 193 #I #L1 #L2 #V #s #m #HL12 #Hm >(plus_minus_m_m m 1) /2 width=1 by drop_drop/
 194 qed.
 195
 196 lemma drop_skip_lt: ∀I,L1,L2,V1,V2,s,l,m.
 197                     ⬇[s, l-1, m] L1 ≡ L2 → ⬆[l-1, m] V2 ≡ V1 → 0 < l →
 198                     ⬇[s, l, m] L1. ⓑ{I} V1 ≡ L2.ⓑ{I}V2.
 199 #I #L1 #L2 #V1 #V2 #s #l #m #HL12 #HV21 #Hl >(plus_minus_m_m l 1) /2 width=1 by drop_skip/
 200 qed.
 201
 202 lemma drop_O1_le: ∀s,m,L. m ≤ |L| → ∃K. ⬇[s, 0, m] L ≡ K.
 203 #s #m @(nat_ind_plus … m) -m /2 width=2 by ex_intro/
 204 #m #IHm *
 205 [ #H elim (le_plus_xSy_O_false … H)
 206 | #L #I #V normalize #H elim (IHm L) -IHm /3 width=2 by drop_drop, monotonic_pred, ex_intro/
 207 ]
 208 qed-.
 209
 210 lemma drop_O1_lt: ∀s,L,m. m < |L| → ∃∃I,K,V. ⬇[s, 0, m] L ≡ K.ⓑ{I}V.
 211 #s #L elim L -L
 212 [ #m #H elim (lt_zero_false … H)
 213 | #L #I #V #IHL #m @(nat_ind_plus … m) -m /2 width=4 by drop_pair, ex1_3_intro/
 214   #m #_ normalize #H elim (IHL m) -IHL /3 width=4 by drop_drop, lt_plus_to_minus_r, lt_plus_to_lt_l, ex1_3_intro/
 215 ]
 216 qed-.
 217
 218 lemma drop_O1_pair: ∀L,K,m,s. ⬇[s, 0, m] L ≡ K → m ≤ |L| → ∀I,V.
 219                     ∃∃J,W. ⬇[s, 0, m] L.ⓑ{I}V ≡ K.ⓑ{J}W.
 220 #L elim L -L [| #L #Z #X #IHL ] #K #m #s #H normalize #Hm #I #V
 221 [ elim (drop_inv_atom1 … H) -H #H <(le_n_O_to_eq … Hm) -m
 222   #Hs destruct /2 width=3 by ex1_2_intro/
 223 | elim (drop_inv_O1_pair1 … H) -H * #Hm #HLK destruct /2 width=3 by ex1_2_intro/
 224   elim (IHL … HLK … Z X) -IHL -HLK
 225   /3 width=3 by drop_drop_lt, le_plus_to_minus, ex1_2_intro/
 226 ]
 227 qed-.
 228
 229 lemma drop_O1_ge: ∀L,m. |L| ≤ m → ⬇[Ⓣ, 0, m] L ≡ ⋆.
 230 #L elim L -L [ #m #_ @drop_atom #H destruct ]
 231 #L #I #V #IHL #m @(nat_ind_plus … m) -m [ #H elim (le_plus_xSy_O_false … H) ]
 232 normalize /4 width=1 by drop_drop, monotonic_pred/
 233 qed.
 234
 235 lemma drop_O1_eq: ∀L,s. ⬇[s, 0, |L|] L ≡ ⋆.
 236 #L elim L -L /2 width=1 by drop_drop, drop_atom/
 237 qed.
 238
 239 lemma drop_split: ∀L1,L2,l,m2,s. ⬇[s, l, m2] L1 ≡ L2 → ∀m1. m1 ≤ m2 →
 240                   ∃∃L. ⬇[s, l, m2 - m1] L1 ≡ L & ⬇[s, l, m1] L ≡ L2.
 241 #L1 #L2 #l #m2 #s #H elim H -L1 -L2 -l -m2
 242 [ #l #m2 #Hs #m1 #Hm12 @(ex2_intro … (⋆))
 243   @drop_atom #H lapply (Hs H) -s #H destruct /2 width=1 by le_n_O_to_eq/
 244 | #I #L1 #V #m1 #Hm1 lapply (le_n_O_to_eq … Hm1) -Hm1
 245   #H destruct /2 width=3 by ex2_intro/
 246 | #I #L1 #L2 #V #m2 #HL12 #IHL12 #m1 @(nat_ind_plus … m1) -m1
 247   [ /3 width=3 by drop_drop, ex2_intro/
 248   | -HL12 #m1 #_ #Hm12 lapply (le_plus_to_le_r … Hm12) -Hm12
 249     #Hm12 elim (IHL12 … Hm12) -IHL12 >minus_plus_plus_l
 250     #L #HL1 #HL2 elim (lt_or_ge (|L1|) (m2-m1)) #H0
 251     [ elim (drop_inv_O1_gt … HL1 H0) -HL1 #H1 #H2 destruct
 252       elim (drop_inv_atom1 … HL2) -HL2 #H #_ destruct
 253       @(ex2_intro … (⋆)) [ @drop_O1_ge normalize // ]
 254       @drop_atom #H destruct
 255     | elim (drop_O1_pair … HL1 H0 I V) -HL1 -H0 /3 width=5 by drop_drop, ex2_intro/
 256     ]
 257   ]
 258 | #I #L1 #L2 #V1 #V2 #l #m2 #_ #HV21 #IHL12 #m1 #Hm12 elim (IHL12 … Hm12) -IHL12
 259   #L #HL1 #HL2 elim (lift_split … HV21 l m1) -HV21 /3 width=5 by drop_skip, ex2_intro/
 260 ]
 261 qed-.
 262
 263 lemma drop_FT: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → ⬇[Ⓣ, l, m] L1 ≡ L2.
 264 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m
 265 /3 width=1 by drop_atom, drop_drop, drop_skip/
 266 qed.
 267
 268 lemma drop_gen: ∀L1,L2,s,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → ⬇[s, l, m] L1 ≡ L2.
 269 #L1 #L2 * /2 width=1 by drop_FT/
 270 qed-.
 271
 272 lemma drop_T: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → ⬇[Ⓣ, l, m] L1 ≡ L2.
 273 #L1 #L2 * /2 width=1 by drop_FT/
 274 qed-.
 275
 276 lemma d_liftable_LTC: ∀R. d_liftable R → d_liftable (LTC … R).
 277 #R #HR #K #T1 #T2 #H elim H -T2
 278 [ /3 width=10 by inj/
 279 | #T #T2 #_ #HT2 #IHT1 #L #s #l #m #HLK #U1 #HTU1 #U2 #HTU2
 280   elim (lift_total T l m) /4 width=12 by step/
 281 ]
 282 qed-.
 283
 284 lemma d_deliftable_sn_LTC: ∀R. d_deliftable_sn R → d_deliftable_sn (LTC … R).
 285 #R #HR #L #U1 #U2 #H elim H -U2
 286 [ #U2 #HU12 #K #s #l #m #HLK #T1 #HTU1
 287   elim (HR … HU12 … HLK … HTU1) -HR -L -U1 /3 width=3 by inj, ex2_intro/
 288 | #U #U2 #_ #HU2 #IHU1 #K #s #l #m #HLK #T1 #HTU1
 289   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 290   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by step, ex2_intro/
 291 ]
 292 qed-.
 293
 294 lemma dropable_sn_TC: ∀R. dropable_sn R → dropable_sn (TC … R).
 295 #R #HR #L1 #K1 #s #l #m #HLK1 #L2 #H elim H -L2
 296 [ #L2 #HL12 elim (HR … HLK1 … HL12) -HR -L1
 297   /3 width=3 by inj, ex2_intro/
 298 | #L #L2 #_ #HL2 * #K #HK1 #HLK elim (HR … HLK … HL2) -HR -L
 299   /3 width=3 by step, ex2_intro/
 300 ]
 301 qed-.
 302
 303 lemma dropable_dx_TC: ∀R. dropable_dx R → dropable_dx (TC … R).
 304 #R #HR #L1 #L2 #H elim H -L2
 305 [ #L2 #HL12 #K2 #s #m #HLK2 elim (HR … HL12 … HLK2) -HR -L2
 306   /3 width=3 by inj, ex2_intro/
 307 | #L #L2 #_ #HL2 #IHL1 #K2 #s #m #HLK2 elim (HR … HL2 … HLK2) -HR -L2
 308   #K #HLK #HK2 elim (IHL1 … HLK) -L
 309   /3 width=5 by step, ex2_intro/
 310 ]
 311 qed-.
 312
 313 lemma d_deliftable_sn_llstar: ∀R. d_deliftable_sn R →
 314                               ∀d. d_deliftable_sn (llstar … R d).
 315 #R #HR #d #L #U1 #U2 #H @(lstar_ind_r … d U2 H) -d -U2
 316 [ /2 width=3 by lstar_O, ex2_intro/
 317 | #d #U #U2 #_ #HU2 #IHU1 #K #s #l #m #HLK #T1 #HTU1
 318   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 319   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by lstar_dx, ex2_intro/
 320 ]
 321 qed-.
 322
 323 (* Basic forward lemmas *****************************************************)
 324
 325 (* Basic_1: was: drop_S *)
 326 lemma drop_fwd_drop2: ∀L1,I2,K2,V2,s,m. ⬇[s, O, m] L1 ≡ K2. ⓑ{I2} V2 →
 327                       ⬇[s, O, m + 1] L1 ≡ K2.
 328 #L1 elim L1 -L1
 329 [ #I2 #K2 #V2 #s #m #H lapply (drop_inv_atom1 … H) -H * #H destruct
 330 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #s #m #H
 331   elim (drop_inv_O1_pair1 … H) -H * #Hm #H
 332   [ -IHL1 destruct /2 width=1 by drop_drop/
 333   | @drop_drop >(plus_minus_m_m m 1) /2 width=3 by/
 334   ]
 335 ]
 336 qed-.
 337
 338 lemma drop_fwd_length_ge: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → |L1| ≤ l → |L2| = |L1|.
 339 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m // normalize
 340 [ #I #L1 #L2 #V #m #_ #_ #H elim (le_plus_xSy_O_false … H)
 341 | /4 width=2 by le_plus_to_le_r, eq_f/
 342 ]
 343 qed-.
 344
 345 lemma drop_fwd_length_le_le: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → l ≤ |L1| → m ≤ |L1| - l → |L2| = |L1| - m.
 346 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m // normalize
 347 [ /3 width=2 by le_plus_to_le_r/
 348 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #IHL12 >minus_plus_plus_l
 349   #Hl #Hm lapply (le_plus_to_le_r … Hl) -Hl
 350   #Hl >IHL12 // -L2 >plus_minus /2 width=3 by transitive_le/
 351 ]
 352 qed-.
 353
 354 lemma drop_fwd_length_le_ge: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → l ≤ |L1| → |L1| - l ≤ m → |L2| = l.
 355 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m normalize
 356 [ /2 width=1 by le_n_O_to_eq/
 357 | #I #L #V #_ <minus_n_O #H elim (le_plus_xSy_O_false … H)
 358 | /3 width=2 by le_plus_to_le_r/
 359 | /4 width=2 by le_plus_to_le_r, eq_f/
 360 ]
 361 qed-.
 362
 363 lemma drop_fwd_length: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L1| = |L2| + m.
 364 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m // normalize /2 width=1 by/
 365 qed-.
 366
 367 lemma drop_fwd_length_minus2: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L2| = |L1| - m.
 368 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H /2 width=1 by plus_minus, le_n/
 369 qed-.
 370
 371 lemma drop_fwd_length_minus4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → m = |L1| - |L2|.
 372 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 373 qed-.
 374
 375 lemma drop_fwd_length_le2: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → m ≤ |L1|.
 376 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 377 qed-.
 378
 379 lemma drop_fwd_length_le4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L2| ≤ |L1|.
 380 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 381 qed-.
 382
 383 lemma drop_fwd_length_lt2: ∀L1,I2,K2,V2,l,m.
 384                            ⬇[Ⓕ, l, m] L1 ≡ K2. ⓑ{I2} V2 → m < |L1|.
 385 #L1 #I2 #K2 #V2 #l #m #H
 386 lapply (drop_fwd_length … H) normalize in ⊢ (%→?); -I2 -V2 //
 387 qed-.
 388
 389 lemma drop_fwd_length_lt4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → 0 < m → |L2| < |L1|.
 390 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H /2 width=1 by lt_minus_to_plus_r/
 391 qed-.
 392
 393 lemma drop_fwd_length_eq1: ∀L1,L2,K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 394                            |L1| = |L2| → |K1| = |K2|.
 395 #L1 #L2 #K1 #K2 #l #m #HLK1 #HLK2 #HL12
 396 lapply (drop_fwd_length … HLK1) -HLK1
 397 lapply (drop_fwd_length … HLK2) -HLK2
 398 /2 width=2 by injective_plus_r/
 399 qed-.
 400
 401 lemma drop_fwd_length_eq2: ∀L1,L2,K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 402                            |K1| = |K2| → |L1| = |L2|.
 403 #L1 #L2 #K1 #K2 #l #m #HLK1 #HLK2 #HL12
 404 lapply (drop_fwd_length … HLK1) -HLK1
 405 lapply (drop_fwd_length … HLK2) -HLK2 //
 406 qed-.
 407
 408 lemma drop_fwd_lw: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → ♯{L2} ≤ ♯{L1}.
 409 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m // normalize
 410 [ /2 width=3 by transitive_le/
 411 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12
 412   >(lift_fwd_tw … HV21) -HV21 /2 width=1 by monotonic_le_plus_l/
 413 ]
 414 qed-.
 415
 416 lemma drop_fwd_lw_lt: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → 0 < m → ♯{L2} < ♯{L1}.
 417 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m
 418 [ #l #m #H >H -H //
 419 | #I #L #V #H elim (lt_refl_false … H)
 420 | #I #L1 #L2 #V #m #HL12 #_ #_
 421   lapply (drop_fwd_lw … HL12) -HL12 #HL12
 422   @(le_to_lt_to_lt … HL12) -HL12 //
 423 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12 #H normalize in ⊢ (?%%); -I
 424   >(lift_fwd_tw … HV21) -V2 /3 by lt_minus_to_plus/
 425 ]
 426 qed-.
 427
 428 lemma drop_fwd_rfw: ∀I,L,K,V,i. ⬇[i] L ≡ K.ⓑ{I}V → ∀T. ♯{K, V} < ♯{L, T}.
 429 #I #L #K #V #i #HLK lapply (drop_fwd_lw … HLK) -HLK
 430 normalize in ⊢ (%→?→?%%); /3 width=3 by le_to_lt_to_lt/
 431 qed-.
 432
 433 (* Advanced inversion lemmas ************************************************)
 434
 435 fact drop_inv_O2_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → m = 0 → L1 = L2.
 436 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m
 437 [ //
 438 | //
 439 | #I #L1 #L2 #V #m #_ #_ >commutative_plus normalize #H destruct
 440 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12 #H
 441   >(IHL12 H) -L1 >(lift_inv_O2_aux … HV21 … H) -V2 -l -m //
 442 ]
 443 qed-.
 444
 445 (* Basic_1: was: drop_gen_refl *)
 446 lemma drop_inv_O2: ∀L1,L2,s,l. ⬇[s, l, 0] L1 ≡ L2 → L1 = L2.
 447 /2 width=5 by drop_inv_O2_aux/ qed-.
 448
 449 lemma drop_inv_length_eq: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L1| = |L2| → m = 0.
 450 #L1 #L2 #l #m #H #HL12 lapply (drop_fwd_length_minus4 … H) //
 451 qed-.
 452
 453 lemma drop_inv_refl: ∀L,l,m. ⬇[Ⓕ, l, m] L ≡ L → m = 0.
 454 /2 width=5 by drop_inv_length_eq/ qed-.
 455
 456 fact drop_inv_FT_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 →
 457                       ∀I,K,V. L2 = K.ⓑ{I}V → s = Ⓣ → l = 0 →
 458                       ⬇[Ⓕ, l, m] L1 ≡ K.ⓑ{I}V.
 459 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m
 460 [ #l #m #_ #J #K #W #H destruct
 461 | #I #L #V #J #K #W #H destruct //
 462 | #I #L1 #L2 #V #m #_ #IHL12 #J #K #W #H1 #H2 destruct
 463   /3 width=1 by drop_drop/
 464 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #_ #J #K #W #_ #_
 465   <plus_n_Sm #H destruct
 466 ]
 467 qed-.
 468
 469 lemma drop_inv_FT: ∀I,L,K,V,m. ⬇[Ⓣ, 0, m] L ≡ K.ⓑ{I}V → ⬇[m] L ≡ K.ⓑ{I}V.
 470 /2 width=5 by drop_inv_FT_aux/ qed.
 471
 472 lemma drop_inv_gen: ∀I,L,K,V,s,m. ⬇[s, 0, m] L ≡ K.ⓑ{I}V → ⬇[m] L ≡ K.ⓑ{I}V.
 473 #I #L #K #V * /2 width=1 by drop_inv_FT/
 474 qed-.
 475
 476 lemma drop_inv_T: ∀I,L,K,V,s,m. ⬇[Ⓣ, 0, m] L ≡ K.ⓑ{I}V → ⬇[s, 0, m] L ≡ K.ⓑ{I}V.
 477 #I #L #K #V * /2 width=1 by drop_inv_FT/
 478 qed-.
 479
 480 (* Basic_1: removed theorems 50:
 481             drop_ctail drop_skip_flat
 482             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 483             drop_clear drop_clear_O drop_clear_S
 484             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 485             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 486             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 487             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 488             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 489             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 490             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 491             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 492             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 493 *)