matita/matita/contribs/lambdadelta/basic_2A/substitution/drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_1_2.ma".
  16 include "ground/xoa/ex_1_3.ma".
  17 include "ground/xoa/ex_3_3.ma".
  18 include "ground/lib/star.ma".
  19 include "ground/lib/lstar_2a.ma".
  20 include "basic_2A/notation/relations/rdrop_5.ma".
  21 include "basic_2A/notation/relations/rdrop_4.ma".
  22 include "basic_2A/notation/relations/rdrop_3.ma".
  23 include "basic_2A/grammar/lenv_length.ma".
  24 include "basic_2A/grammar/cl_restricted_weight.ma".
  25 include "basic_2A/substitution/lift.ma".
  26
  27 (* BASIC SLICING FOR LOCAL ENVIRONMENTS *************************************)
  28
  29 inductive drop (s:bool): relation4 nat nat lenv lenv ≝
  30 | drop_atom: ∀l,m. (s = Ⓕ → m = 0) → drop s l m (⋆) (⋆)
  31 | drop_pair: ∀I,L,V. drop s 0 0 (L.ⓑ{I}V) (L.ⓑ{I}V)
  32 | drop_drop: ∀I,L1,L2,V,m. drop s 0 m L1 L2 → drop s 0 (m+1) (L1.ⓑ{I}V) L2
  33 | drop_skip: ∀I,L1,L2,V1,V2,l,m.
  34              drop s l m L1 L2 → ⬆[l, m] V2 ≡ V1 →
  35              drop s (l+1) m (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  36 .
  37
  38 interpretation
  39    "basic slicing (local environment) abstract"
  40    'RDrop s l m L1 L2 = (drop s l m L1 L2).
  41 (*
  42 interpretation
  43    "basic slicing (local environment) general"
  44    'RDrop d e L1 L2 = (drop true d e L1 L2).
  45 *)
  46 interpretation
  47    "basic slicing (local environment) lget"
  48    'RDrop m L1 L2 = (drop false O m L1 L2).
  49
  50 definition d_liftable: predicate (lenv → relation term) ≝
  51                        λR. ∀K,T1,T2. R K T1 T2 → ∀L,s,l,m. ⬇[s, l, m] L ≡ K →
  52                        ∀U1. ⬆[l, m] T1 ≡ U1 → ∀U2. ⬆[l, m] T2 ≡ U2 → R L U1 U2.
  53
  54 definition d_deliftable_sn: predicate (lenv → relation term) ≝
  55                             λR. ∀L,U1,U2. R L U1 U2 → ∀K,s,l,m. ⬇[s, l, m] L ≡ K →
  56                             ∀T1. ⬆[l, m] T1 ≡ U1 →
  57                             ∃∃T2. ⬆[l, m] T2 ≡ U2 & R K T1 T2.
  58
  59 definition dropable_sn: predicate (relation lenv) ≝
  60                         λR. ∀L1,K1,s,l,m. ⬇[s, l, m] L1 ≡ K1 → ∀L2. R L1 L2 →
  61                         ∃∃K2. R K1 K2 & ⬇[s, l, m] L2 ≡ K2.
  62
  63 definition dropable_dx: predicate (relation lenv) ≝
  64                         λR. ∀L1,L2. R L1 L2 → ∀K2,s,m. ⬇[s, 0, m] L2 ≡ K2 →
  65                         ∃∃K1. ⬇[s, 0, m] L1 ≡ K1 & R K1 K2.
  66
  67 (* Basic inversion lemmas ***************************************************)
  68
  69 fact drop_inv_atom1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → L1 = ⋆ →
  70                          L2 = ⋆ ∧ (s = Ⓕ → m = 0).
  71 #L1 #L2 #s #l #m * -L1 -L2 -l -m
  72 [ /3 width=1 by conj/
  73 | #I #L #V #H destruct
  74 | #I #L1 #L2 #V #m #_ #H destruct
  75 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #H destruct
  76 ]
  77 qed-.
  78
  79 lemma drop_inv_atom1: ∀L2,s,l,m. ⬇[s, l, m] ⋆ ≡ L2 → L2 = ⋆ ∧ (s = Ⓕ → m = 0).
  80 /2 width=4 by drop_inv_atom1_aux/ qed-.
  81
  82 fact drop_inv_O1_pair1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → l = 0 →
  83                             ∀K,I,V. L1 = K.ⓑ{I}V →
  84                             (m = 0 ∧ L2 = K.ⓑ{I}V) ∨
  85                             (0 < m ∧ ⬇[s, l, m-1] K ≡ L2).
  86 #L1 #L2 #s #l #m * -L1 -L2 -l -m
  87 [ #l #m #_ #_ #K #J #W #H destruct
  88 | #I #L #V #_ #K #J #W #HX destruct /3 width=1 by or_introl, conj/
  89 | #I #L1 #L2 #V #m #HL12 #_ #K #J #W #H destruct /3 width=1 by or_intror, conj/
  90 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ >commutative_plus normalize #H destruct
  91 ]
  92 qed-.
  93
  94 lemma drop_inv_O1_pair1: ∀I,K,L2,V,s,m. ⬇[s, 0, m] K. ⓑ{I} V ≡ L2 →
  95                          (m = 0 ∧ L2 = K.ⓑ{I}V) ∨
  96                          (0 < m ∧ ⬇[s, 0, m-1] K ≡ L2).
  97 /2 width=3 by drop_inv_O1_pair1_aux/ qed-.
  98
  99 lemma drop_inv_pair1: ∀I,K,L2,V,s. ⬇[s, 0, 0] K.ⓑ{I}V ≡ L2 → L2 = K.ⓑ{I}V.
 100 #I #K #L2 #V #s #H
 101 elim (drop_inv_O1_pair1 … H) -H * // #H destruct
 102 elim (lt_refl_false … H)
 103 qed-.
 104
 105 lemma drop_inv_drop1_lt: ∀I,K,L2,V,s,m.
 106                          ⬇[s, 0, m] K.ⓑ{I}V ≡ L2 → 0 < m → ⬇[s, 0, m-1] K ≡ L2.
 107 #I #K #L2 #V #s #m #H #Hm
 108 elim (drop_inv_O1_pair1 … H) -H * // #H destruct
 109 elim (lt_refl_false … Hm)
 110 qed-.
 111
 112 lemma drop_inv_drop1: ∀I,K,L2,V,s,m.
 113                       ⬇[s, 0, m+1] K.ⓑ{I}V ≡ L2 → ⬇[s, 0, m] K ≡ L2.
 114 #I #K #L2 #V #s #m #H lapply (drop_inv_drop1_lt … H ?) -H //
 115 qed-.
 116
 117 fact drop_inv_skip1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → 0 < l →
 118                          ∀I,K1,V1. L1 = K1.ⓑ{I}V1 →
 119                          ∃∃K2,V2. ⬇[s, l-1, m] K1 ≡ K2 &
 120                                   ⬆[l-1, m] V2 ≡ V1 &
 121                                    L2 = K2.ⓑ{I}V2.
 122 #L1 #L2 #s #l #m * -L1 -L2 -l -m
 123 [ #l #m #_ #_ #J #K1 #W1 #H destruct
 124 | #I #L #V #H elim (lt_refl_false … H)
 125 | #I #L1 #L2 #V #m #_ #H elim (lt_refl_false … H)
 126 | #I #L1 #L2 #V1 #V2 #l #m #HL12 #HV21 #_ #J #K1 #W1 #H destruct /2 width=5 by ex3_2_intro/
 127 ]
 128 qed-.
 129
 130 lemma drop_inv_skip1: ∀I,K1,V1,L2,s,l,m. ⬇[s, l, m] K1.ⓑ{I}V1 ≡ L2 → 0 < l →
 131                       ∃∃K2,V2. ⬇[s, l-1, m] K1 ≡ K2 &
 132                                ⬆[l-1, m] V2 ≡ V1 &
 133                                L2 = K2.ⓑ{I}V2.
 134 /2 width=3 by drop_inv_skip1_aux/ qed-.
 135
 136 lemma drop_inv_O1_pair2: ∀I,K,V,s,m,L1. ⬇[s, 0, m] L1 ≡ K.ⓑ{I}V →
 137                          (m = 0 ∧ L1 = K.ⓑ{I}V) ∨
 138                          ∃∃I1,K1,V1. ⬇[s, 0, m-1] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & 0 < m.
 139 #I #K #V #s #m *
 140 [ #H elim (drop_inv_atom1 … H) -H #H destruct
 141 | #L1 #I1 #V1 #H
 142   elim (drop_inv_O1_pair1 … H) -H *
 143   [ #H1 #H2 destruct /3 width=1 by or_introl, conj/
 144   | /3 width=5 by ex3_3_intro, or_intror/
 145   ]
 146 ]
 147 qed-.
 148
 149 fact drop_inv_skip2_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → 0 < l →
 150                          ∀I,K2,V2. L2 = K2.ⓑ{I}V2 →
 151                          ∃∃K1,V1. ⬇[s, l-1, m] K1 ≡ K2 &
 152                                   ⬆[l-1, m] V2 ≡ V1 &
 153                                   L1 = K1.ⓑ{I}V1.
 154 #L1 #L2 #s #l #m * -L1 -L2 -l -m
 155 [ #l #m #_ #_ #J #K2 #W2 #H destruct
 156 | #I #L #V #H elim (lt_refl_false … H)
 157 | #I #L1 #L2 #V #m #_ #H elim (lt_refl_false … H)
 158 | #I #L1 #L2 #V1 #V2 #l #m #HL12 #HV21 #_ #J #K2 #W2 #H destruct /2 width=5 by ex3_2_intro/
 159 ]
 160 qed-.
 161
 162 lemma drop_inv_skip2: ∀I,L1,K2,V2,s,l,m. ⬇[s, l, m] L1 ≡ K2.ⓑ{I}V2 → 0 < l →
 163                       ∃∃K1,V1. ⬇[s, l-1, m] K1 ≡ K2 & ⬆[l-1, m] V2 ≡ V1 &
 164                                L1 = K1.ⓑ{I}V1.
 165 /2 width=3 by drop_inv_skip2_aux/ qed-.
 166
 167 lemma drop_inv_O1_gt: ∀L,K,m,s. ⬇[s, 0, m] L ≡ K → |L| < m →
 168                       s = Ⓣ ∧ K = ⋆.
 169 #L elim L -L [| #L #Z #X #IHL ] #K #m #s #H normalize in ⊢ (?%?→?); #H1m
 170 [ elim (drop_inv_atom1 … H) -H elim s -s /2 width=1 by conj/
 171   #_ #Hs lapply (Hs ?) // -Hs #H destruct elim (lt_zero_false … H1m)
 172 | elim (drop_inv_O1_pair1 … H) -H * #H2m #HLK destruct
 173   [ elim (lt_zero_false … H1m)
 174   | elim (IHL … HLK) -IHL -HLK /2 width=1 by lt_plus_to_minus_r, conj/
 175   ]
 176 ]
 177 qed-.
 178
 179 (* Basic properties *********************************************************)
 180
 181 lemma drop_refl_atom_O2: ∀s,l. ⬇[s, l, O] ⋆ ≡ ⋆.
 182 /2 width=1 by drop_atom/ qed.
 183
 184 lemma drop_refl: ∀L,l,s. ⬇[s, l, 0] L ≡ L.
 185 #L elim L -L //
 186 #L #I #V #IHL #l #s @(nat_ind_plus … l) -l /2 width=1 by drop_pair, drop_skip/
 187 qed.
 188
 189 lemma drop_drop_lt: ∀I,L1,L2,V,s,m.
 190                     ⬇[s, 0, m-1] L1 ≡ L2 → 0 < m → ⬇[s, 0, m] L1.ⓑ{I}V ≡ L2.
 191 #I #L1 #L2 #V #s #m #HL12 #Hm >(plus_minus_m_m m 1) /2 width=1 by drop_drop/
 192 qed.
 193
 194 lemma drop_skip_lt: ∀I,L1,L2,V1,V2,s,l,m.
 195                     ⬇[s, l-1, m] L1 ≡ L2 → ⬆[l-1, m] V2 ≡ V1 → 0 < l →
 196                     ⬇[s, l, m] L1. ⓑ{I} V1 ≡ L2.ⓑ{I}V2.
 197 #I #L1 #L2 #V1 #V2 #s #l #m #HL12 #HV21 #Hl >(plus_minus_m_m l 1) /2 width=1 by drop_skip/
 198 qed.
 199
 200 lemma drop_O1_le: ∀s,m,L. m ≤ |L| → ∃K. ⬇[s, 0, m] L ≡ K.
 201 #s #m @(nat_ind_plus … m) -m /2 width=2 by ex_intro/
 202 #m #IHm *
 203 [ #H elim (le_plus_xSy_O_false … H)
 204 | #L #I #V normalize #H elim (IHm L) -IHm /3 width=2 by drop_drop, monotonic_pred, ex_intro/
 205 ]
 206 qed-.
 207
 208 lemma drop_O1_lt: ∀s,L,m. m < |L| → ∃∃I,K,V. ⬇[s, 0, m] L ≡ K.ⓑ{I}V.
 209 #s #L elim L -L
 210 [ #m #H elim (lt_zero_false … H)
 211 | #L #I #V #IHL #m @(nat_ind_plus … m) -m /2 width=4 by drop_pair, ex1_3_intro/
 212   #m #_ normalize #H elim (IHL m) -IHL /3 width=4 by drop_drop, lt_plus_to_minus_r, lt_plus_to_lt_l, ex1_3_intro/
 213 ]
 214 qed-.
 215
 216 lemma drop_O1_pair: ∀L,K,m,s. ⬇[s, 0, m] L ≡ K → m ≤ |L| → ∀I,V.
 217                     ∃∃J,W. ⬇[s, 0, m] L.ⓑ{I}V ≡ K.ⓑ{J}W.
 218 #L elim L -L [| #L #Z #X #IHL ] #K #m #s #H normalize #Hm #I #V
 219 [ elim (drop_inv_atom1 … H) -H #H <(le_n_O_to_eq … Hm) -m
 220   #Hs destruct /2 width=3 by ex1_2_intro/
 221 | elim (drop_inv_O1_pair1 … H) -H * #Hm #HLK destruct /2 width=3 by ex1_2_intro/
 222   elim (IHL … HLK … Z X) -IHL -HLK
 223   /3 width=3 by drop_drop_lt, le_plus_to_minus, ex1_2_intro/
 224 ]
 225 qed-.
 226
 227 lemma drop_O1_ge: ∀L,m. |L| ≤ m → ⬇[Ⓣ, 0, m] L ≡ ⋆.
 228 #L elim L -L [ #m #_ @drop_atom #H destruct ]
 229 #L #I #V #IHL #m @(nat_ind_plus … m) -m [ #H elim (le_plus_xSy_O_false … H) ]
 230 normalize /4 width=1 by drop_drop, monotonic_pred/
 231 qed.
 232
 233 lemma drop_O1_eq: ∀L,s. ⬇[s, 0, |L|] L ≡ ⋆.
 234 #L elim L -L /2 width=1 by drop_drop, drop_atom/
 235 qed.
 236
 237 lemma drop_split: ∀L1,L2,l,m2,s. ⬇[s, l, m2] L1 ≡ L2 → ∀m1. m1 ≤ m2 →
 238                   ∃∃L. ⬇[s, l, m2 - m1] L1 ≡ L & ⬇[s, l, m1] L ≡ L2.
 239 #L1 #L2 #l #m2 #s #H elim H -L1 -L2 -l -m2
 240 [ #l #m2 #Hs #m1 #Hm12 @(ex2_intro … (⋆))
 241   @drop_atom #H lapply (Hs H) -s #H destruct /2 width=1 by le_n_O_to_eq/
 242 | #I #L1 #V #m1 #Hm1 lapply (le_n_O_to_eq … Hm1) -Hm1
 243   #H destruct /2 width=3 by ex2_intro/
 244 | #I #L1 #L2 #V #m2 #HL12 #IHL12 #m1 @(nat_ind_plus … m1) -m1
 245   [ /3 width=3 by drop_drop, ex2_intro/
 246   | -HL12 #m1 #_ #Hm12 lapply (le_plus_to_le_r … Hm12) -Hm12
 247     #Hm12 elim (IHL12 … Hm12) -IHL12 >minus_plus_plus_l
 248     #L #HL1 #HL2 elim (lt_or_ge (|L1|) (m2-m1)) #H0
 249     [ elim (drop_inv_O1_gt … HL1 H0) -HL1 #H1 #H2 destruct
 250       elim (drop_inv_atom1 … HL2) -HL2 #H #_ destruct
 251       @(ex2_intro … (⋆)) [ @drop_O1_ge normalize // ]
 252       @drop_atom #H destruct
 253     | elim (drop_O1_pair … HL1 H0 I V) -HL1 -H0 /3 width=5 by drop_drop, ex2_intro/
 254     ]
 255   ]
 256 | #I #L1 #L2 #V1 #V2 #l #m2 #_ #HV21 #IHL12 #m1 #Hm12 elim (IHL12 … Hm12) -IHL12
 257   #L #HL1 #HL2 elim (lift_split … HV21 l m1) -HV21 /3 width=5 by drop_skip, ex2_intro/
 258 ]
 259 qed-.
 260
 261 lemma drop_FT: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → ⬇[Ⓣ, l, m] L1 ≡ L2.
 262 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m
 263 /3 width=1 by drop_atom, drop_drop, drop_skip/
 264 qed.
 265
 266 lemma drop_gen: ∀L1,L2,s,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → ⬇[s, l, m] L1 ≡ L2.
 267 #L1 #L2 * /2 width=1 by drop_FT/
 268 qed-.
 269
 270 lemma drop_T: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → ⬇[Ⓣ, l, m] L1 ≡ L2.
 271 #L1 #L2 * /2 width=1 by drop_FT/
 272 qed-.
 273
 274 lemma d_liftable_LTC: ∀R. d_liftable R → d_liftable (CTC … R).
 275 #R #HR #K #T1 #T2 #H elim H -T2
 276 [ /3 width=10 by inj/
 277 | #T #T2 #_ #HT2 #IHT1 #L #s #l #m #HLK #U1 #HTU1 #U2 #HTU2
 278   elim (lift_total T l m) /4 width=12 by step/
 279 ]
 280 qed-.
 281
 282 lemma d_deliftable_sn_LTC: ∀R. d_deliftable_sn R → d_deliftable_sn (CTC … R).
 283 #R #HR #L #U1 #U2 #H elim H -U2
 284 [ #U2 #HU12 #K #s #l #m #HLK #T1 #HTU1
 285   elim (HR … HU12 … HLK … HTU1) -HR -L -U1 /3 width=3 by inj, ex2_intro/
 286 | #U #U2 #_ #HU2 #IHU1 #K #s #l #m #HLK #T1 #HTU1
 287   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 288   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by step, ex2_intro/
 289 ]
 290 qed-.
 291
 292 lemma dropable_sn_TC: ∀R. dropable_sn R → dropable_sn (TC … R).
 293 #R #HR #L1 #K1 #s #l #m #HLK1 #L2 #H elim H -L2
 294 [ #L2 #HL12 elim (HR … HLK1 … HL12) -HR -L1
 295   /3 width=3 by inj, ex2_intro/
 296 | #L #L2 #_ #HL2 * #K #HK1 #HLK elim (HR … HLK … HL2) -HR -L
 297   /3 width=3 by step, ex2_intro/
 298 ]
 299 qed-.
 300
 301 lemma dropable_dx_TC: ∀R. dropable_dx R → dropable_dx (TC … R).
 302 #R #HR #L1 #L2 #H elim H -L2
 303 [ #L2 #HL12 #K2 #s #m #HLK2 elim (HR … HL12 … HLK2) -HR -L2
 304   /3 width=3 by inj, ex2_intro/
 305 | #L #L2 #_ #HL2 #IHL1 #K2 #s #m #HLK2 elim (HR … HL2 … HLK2) -HR -L2
 306   #K #HLK #HK2 elim (IHL1 … HLK) -L
 307   /3 width=5 by step, ex2_intro/
 308 ]
 309 qed-.
 310
 311 lemma d_deliftable_sn_llstar: ∀R. d_deliftable_sn R →
 312                               ∀d. d_deliftable_sn (llstar … R d).
 313 #R #HR #d #L #U1 #U2 #H @(lstar_ind_r … d U2 H) -d -U2
 314 [ /2 width=3 by lstar_O, ex2_intro/
 315 | #d #U #U2 #_ #HU2 #IHU1 #K #s #l #m #HLK #T1 #HTU1
 316   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 317   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by lstar_dx, ex2_intro/
 318 ]
 319 qed-.
 320
 321 (* Basic forward lemmas *****************************************************)
 322
 323 lemma drop_fwd_drop2: ∀L1,I2,K2,V2,s,m. ⬇[s, O, m] L1 ≡ K2. ⓑ{I2} V2 →
 324                       ⬇[s, O, m + 1] L1 ≡ K2.
 325 #L1 elim L1 -L1
 326 [ #I2 #K2 #V2 #s #m #H lapply (drop_inv_atom1 … H) -H * #H destruct
 327 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #s #m #H
 328   elim (drop_inv_O1_pair1 … H) -H * #Hm #H
 329   [ -IHL1 destruct /2 width=1 by drop_drop/
 330   | @drop_drop >(plus_minus_m_m m 1) /2 width=3 by/
 331   ]
 332 ]
 333 qed-.
 334
 335 lemma drop_fwd_length_ge: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → |L1| ≤ l → |L2| = |L1|.
 336 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m // normalize
 337 [ #I #L1 #L2 #V #m #_ #_ #H elim (le_plus_xSy_O_false … H)
 338 | /4 width=2 by le_plus_to_le_r, eq_f/
 339 ]
 340 qed-.
 341
 342 lemma drop_fwd_length_le_le: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → l ≤ |L1| → m ≤ |L1| - l → |L2| = |L1| - m.
 343 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m // normalize
 344 [ /3 width=2 by le_plus_to_le_r/
 345 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #IHL12 >minus_plus_plus_l
 346   #Hl #Hm lapply (le_plus_to_le_r … Hl) -Hl
 347   #Hl >IHL12 // -L2 >plus_minus /2 width=3 by transitive_le/
 348 ]
 349 qed-.
 350
 351 lemma drop_fwd_length_le_ge: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → l ≤ |L1| → |L1| - l ≤ m → |L2| = l.
 352 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m normalize
 353 [ /2 width=1 by le_n_O_to_eq/
 354 | #I #L #V #_ <minus_n_O #H elim (le_plus_xSy_O_false … H)
 355 | /3 width=2 by le_plus_to_le_r/
 356 | /4 width=2 by le_plus_to_le_r, eq_f/
 357 ]
 358 qed-.
 359
 360 lemma drop_fwd_length: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L1| = |L2| + m.
 361 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m // normalize
 362 /2 width=1 by le_to_le_to_eq, le_n/
 363 qed-.
 364
 365 lemma drop_fwd_length_minus2: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L2| = |L1| - m.
 366 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H /2 width=1 by plus_minus, le_n/
 367 qed-.
 368
 369 lemma drop_fwd_length_minus4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → m = |L1| - |L2|.
 370 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 371 qed-.
 372
 373 lemma drop_fwd_length_le2: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → m ≤ |L1|.
 374 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 375 qed-.
 376
 377 lemma drop_fwd_length_le4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L2| ≤ |L1|.
 378 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 379 qed-.
 380
 381 lemma drop_fwd_length_lt2: ∀L1,I2,K2,V2,l,m.
 382                            ⬇[Ⓕ, l, m] L1 ≡ K2. ⓑ{I2} V2 → m < |L1|.
 383 #L1 #I2 #K2 #V2 #l #m #H
 384 lapply (drop_fwd_length … H) normalize in ⊢ (%→?); -I2 -V2 //
 385 qed-.
 386
 387 lemma drop_fwd_length_lt4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → 0 < m → |L2| < |L1|.
 388 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H /2 width=1 by lt_minus_to_plus_r/
 389 qed-.
 390
 391 lemma drop_fwd_length_eq1: ∀L1,L2,K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 392                            |L1| = |L2| → |K1| = |K2|.
 393 #L1 #L2 #K1 #K2 #l #m #HLK1 #HLK2 #HL12
 394 lapply (drop_fwd_length … HLK1) -HLK1
 395 lapply (drop_fwd_length … HLK2) -HLK2
 396 /2 width=2 by injective_plus_r/
 397 qed-.
 398
 399 lemma drop_fwd_length_eq2: ∀L1,L2,K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 400                            |K1| = |K2| → |L1| = |L2|.
 401 #L1 #L2 #K1 #K2 #l #m #HLK1 #HLK2 #HL12
 402 lapply (drop_fwd_length … HLK1) -HLK1
 403 lapply (drop_fwd_length … HLK2) -HLK2 //
 404 qed-.
 405
 406 lemma drop_fwd_lw: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → ♯{L2} ≤ ♯{L1}.
 407 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m // normalize
 408 [ /2 width=3 by transitive_le/
 409 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12
 410   >(lift_fwd_tw … HV21) -HV21 /2 width=1 by monotonic_le_plus_l/
 411 ]
 412 qed-.
 413
 414 lemma drop_fwd_lw_lt: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → 0 < m → ♯{L2} < ♯{L1}.
 415 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m
 416 [ #l #m #H >H -H //
 417 | #I #L #V #H elim (lt_refl_false … H)
 418 | #I #L1 #L2 #V #m #HL12 #_ #_
 419   lapply (drop_fwd_lw … HL12) -HL12 #HL12
 420   @(le_to_lt_to_lt … HL12) -HL12 //
 421 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12 #H normalize in ⊢ (?%%); -I
 422   >(lift_fwd_tw … HV21) -V2 /3 by lt_minus_to_plus/
 423 ]
 424 qed-.
 425
 426 lemma drop_fwd_rfw: ∀I,L,K,V,i. ⬇[i] L ≡ K.ⓑ{I}V → ∀T. ♯{K, V} < ♯{L, T}.
 427 #I #L #K #V #i #HLK lapply (drop_fwd_lw … HLK) -HLK
 428 normalize in ⊢ (%→?→?%%); /3 width=3 by le_to_lt_to_lt/
 429 qed-.
 430
 431 (* Advanced inversion lemmas ************************************************)
 432
 433 fact drop_inv_O2_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → m = 0 → L1 = L2.
 434 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m
 435 [ //
 436 | //
 437 | #I #L1 #L2 #V #m #_ #_ >commutative_plus normalize #H destruct
 438 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12 #H
 439   >(IHL12 H) -L1 >(lift_inv_O2_aux … HV21 … H) -V2 -l -m //
 440 ]
 441 qed-.
 442
 443 lemma drop_inv_O2: ∀L1,L2,s,l. ⬇[s, l, 0] L1 ≡ L2 → L1 = L2.
 444 /2 width=5 by drop_inv_O2_aux/ qed-.
 445
 446 lemma drop_inv_length_eq: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L1| = |L2| → m = 0.
 447 #L1 #L2 #l #m #H #HL12 lapply (drop_fwd_length_minus4 … H) //
 448 qed-.
 449
 450 lemma drop_inv_refl: ∀L,l,m. ⬇[Ⓕ, l, m] L ≡ L → m = 0.
 451 /2 width=5 by drop_inv_length_eq/ qed-.
 452
 453 fact drop_inv_FT_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 →
 454                       ∀I,K,V. L2 = K.ⓑ{I}V → s = Ⓣ → l = 0 →
 455                       ⬇[Ⓕ, l, m] L1 ≡ K.ⓑ{I}V.
 456 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m
 457 [ #l #m #_ #J #K #W #H destruct
 458 | #I #L #V #J #K #W #H destruct //
 459 | #I #L1 #L2 #V #m #_ #IHL12 #J #K #W #H1 #H2 destruct
 460   /3 width=1 by drop_drop/
 461 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #_ #J #K #W #_ #_
 462   <plus_n_Sm #H destruct
 463 ]
 464 qed-.
 465
 466 lemma drop_inv_FT: ∀I,L,K,V,m. ⬇[Ⓣ, 0, m] L ≡ K.ⓑ{I}V → ⬇[m] L ≡ K.ⓑ{I}V.
 467 /2 width=5 by drop_inv_FT_aux/ qed.
 468
 469 lemma drop_inv_gen: ∀I,L,K,V,s,m. ⬇[s, 0, m] L ≡ K.ⓑ{I}V → ⬇[m] L ≡ K.ⓑ{I}V.
 470 #I #L #K #V * /2 width=1 by drop_inv_FT/
 471 qed-.
 472
 473 lemma drop_inv_T: ∀I,L,K,V,s,m. ⬇[Ⓣ, 0, m] L ≡ K.ⓑ{I}V → ⬇[s, 0, m] L ≡ K.ⓑ{I}V.
 474 #I #L #K #V * /2 width=1 by drop_inv_FT/
 475 qed-.