matita/matita/contribs/lambdadelta/basic_2A/substitution/drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_1_2.ma".
  16 include "ground/xoa/ex_1_3.ma".
  17 include "ground/xoa/ex_3_3.ma".
  18 include "ground/lib/star.ma".
  19 include "ground/lib/lstar_2a.ma".
  20 include "basic_2A/notation/relations/rdrop_5.ma".
  21 include "basic_2A/notation/relations/rdrop_4.ma".
  22 include "basic_2A/notation/relations/rdrop_3.ma".
  23 include "basic_2A/grammar/lenv_length.ma".
  24 include "basic_2A/grammar/cl_restricted_weight.ma".
  25 include "basic_2A/substitution/lift.ma".
  26
  27 (* BASIC SLICING FOR LOCAL ENVIRONMENTS *************************************)
  28
  29 (* Basic_1: includes: drop_skip_bind *)
  30 inductive drop (s:bool): relation4 nat nat lenv lenv ≝
  31 | drop_atom: ∀l,m. (s = Ⓕ → m = 0) → drop s l m (⋆) (⋆)
  32 | drop_pair: ∀I,L,V. drop s 0 0 (L.ⓑ{I}V) (L.ⓑ{I}V)
  33 | drop_drop: ∀I,L1,L2,V,m. drop s 0 m L1 L2 → drop s 0 (m+1) (L1.ⓑ{I}V) L2
  34 | drop_skip: ∀I,L1,L2,V1,V2,l,m.
  35              drop s l m L1 L2 → ⬆[l, m] V2 ≡ V1 →
  36              drop s (l+1) m (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  37 .
  38
  39 interpretation
  40    "basic slicing (local environment) abstract"
  41    'RDrop s l m L1 L2 = (drop s l m L1 L2).
  42 (*
  43 interpretation
  44    "basic slicing (local environment) general"
  45    'RDrop d e L1 L2 = (drop true d e L1 L2).
  46 *)
  47 interpretation
  48    "basic slicing (local environment) lget"
  49    'RDrop m L1 L2 = (drop false O m L1 L2).
  50
  51 definition d_liftable: predicate (lenv → relation term) ≝
  52                        λR. ∀K,T1,T2. R K T1 T2 → ∀L,s,l,m. ⬇[s, l, m] L ≡ K →
  53                        ∀U1. ⬆[l, m] T1 ≡ U1 → ∀U2. ⬆[l, m] T2 ≡ U2 → R L U1 U2.
  54
  55 definition d_deliftable_sn: predicate (lenv → relation term) ≝
  56                             λR. ∀L,U1,U2. R L U1 U2 → ∀K,s,l,m. ⬇[s, l, m] L ≡ K →
  57                             ∀T1. ⬆[l, m] T1 ≡ U1 →
  58                             ∃∃T2. ⬆[l, m] T2 ≡ U2 & R K T1 T2.
  59
  60 definition dropable_sn: predicate (relation lenv) ≝
  61                         λR. ∀L1,K1,s,l,m. ⬇[s, l, m] L1 ≡ K1 → ∀L2. R L1 L2 →
  62                         ∃∃K2. R K1 K2 & ⬇[s, l, m] L2 ≡ K2.
  63
  64 definition dropable_dx: predicate (relation lenv) ≝
  65                         λR. ∀L1,L2. R L1 L2 → ∀K2,s,m. ⬇[s, 0, m] L2 ≡ K2 →
  66                         ∃∃K1. ⬇[s, 0, m] L1 ≡ K1 & R K1 K2.
  67
  68 (* Basic inversion lemmas ***************************************************)
  69
  70 fact drop_inv_atom1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → L1 = ⋆ →
  71                          L2 = ⋆ ∧ (s = Ⓕ → m = 0).
  72 #L1 #L2 #s #l #m * -L1 -L2 -l -m
  73 [ /3 width=1 by conj/
  74 | #I #L #V #H destruct
  75 | #I #L1 #L2 #V #m #_ #H destruct
  76 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #H destruct
  77 ]
  78 qed-.
  79
  80 (* Basic_1: was: drop_gen_sort *)
  81 lemma drop_inv_atom1: ∀L2,s,l,m. ⬇[s, l, m] ⋆ ≡ L2 → L2 = ⋆ ∧ (s = Ⓕ → m = 0).
  82 /2 width=4 by drop_inv_atom1_aux/ qed-.
  83
  84 fact drop_inv_O1_pair1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → l = 0 →
  85                             ∀K,I,V. L1 = K.ⓑ{I}V →
  86                             (m = 0 ∧ L2 = K.ⓑ{I}V) ∨
  87                             (0 < m ∧ ⬇[s, l, m-1] K ≡ L2).
  88 #L1 #L2 #s #l #m * -L1 -L2 -l -m
  89 [ #l #m #_ #_ #K #J #W #H destruct
  90 | #I #L #V #_ #K #J #W #HX destruct /3 width=1 by or_introl, conj/
  91 | #I #L1 #L2 #V #m #HL12 #_ #K #J #W #H destruct /3 width=1 by or_intror, conj/
  92 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ >commutative_plus normalize #H destruct
  93 ]
  94 qed-.
  95
  96 lemma drop_inv_O1_pair1: ∀I,K,L2,V,s,m. ⬇[s, 0, m] K. ⓑ{I} V ≡ L2 →
  97                          (m = 0 ∧ L2 = K.ⓑ{I}V) ∨
  98                          (0 < m ∧ ⬇[s, 0, m-1] K ≡ L2).
  99 /2 width=3 by drop_inv_O1_pair1_aux/ qed-.
 100
 101 lemma drop_inv_pair1: ∀I,K,L2,V,s. ⬇[s, 0, 0] K.ⓑ{I}V ≡ L2 → L2 = K.ⓑ{I}V.
 102 #I #K #L2 #V #s #H
 103 elim (drop_inv_O1_pair1 … H) -H * // #H destruct
 104 elim (lt_refl_false … H)
 105 qed-.
 106
 107 (* Basic_1: was: drop_gen_drop *)
 108 lemma drop_inv_drop1_lt: ∀I,K,L2,V,s,m.
 109                          ⬇[s, 0, m] K.ⓑ{I}V ≡ L2 → 0 < m → ⬇[s, 0, m-1] K ≡ L2.
 110 #I #K #L2 #V #s #m #H #Hm
 111 elim (drop_inv_O1_pair1 … H) -H * // #H destruct
 112 elim (lt_refl_false … Hm)
 113 qed-.
 114
 115 lemma drop_inv_drop1: ∀I,K,L2,V,s,m.
 116                       ⬇[s, 0, m+1] K.ⓑ{I}V ≡ L2 → ⬇[s, 0, m] K ≡ L2.
 117 #I #K #L2 #V #s #m #H lapply (drop_inv_drop1_lt … H ?) -H //
 118 qed-.
 119
 120 fact drop_inv_skip1_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → 0 < l →
 121                          ∀I,K1,V1. L1 = K1.ⓑ{I}V1 →
 122                          ∃∃K2,V2. ⬇[s, l-1, m] K1 ≡ K2 &
 123                                   ⬆[l-1, m] V2 ≡ V1 &
 124                                    L2 = K2.ⓑ{I}V2.
 125 #L1 #L2 #s #l #m * -L1 -L2 -l -m
 126 [ #l #m #_ #_ #J #K1 #W1 #H destruct
 127 | #I #L #V #H elim (lt_refl_false … H)
 128 | #I #L1 #L2 #V #m #_ #H elim (lt_refl_false … H)
 129 | #I #L1 #L2 #V1 #V2 #l #m #HL12 #HV21 #_ #J #K1 #W1 #H destruct /2 width=5 by ex3_2_intro/
 130 ]
 131 qed-.
 132
 133 (* Basic_1: was: drop_gen_skip_l *)
 134 lemma drop_inv_skip1: ∀I,K1,V1,L2,s,l,m. ⬇[s, l, m] K1.ⓑ{I}V1 ≡ L2 → 0 < l →
 135                       ∃∃K2,V2. ⬇[s, l-1, m] K1 ≡ K2 &
 136                                ⬆[l-1, m] V2 ≡ V1 &
 137                                L2 = K2.ⓑ{I}V2.
 138 /2 width=3 by drop_inv_skip1_aux/ qed-.
 139
 140 lemma drop_inv_O1_pair2: ∀I,K,V,s,m,L1. ⬇[s, 0, m] L1 ≡ K.ⓑ{I}V →
 141                          (m = 0 ∧ L1 = K.ⓑ{I}V) ∨
 142                          ∃∃I1,K1,V1. ⬇[s, 0, m-1] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & 0 < m.
 143 #I #K #V #s #m *
 144 [ #H elim (drop_inv_atom1 … H) -H #H destruct
 145 | #L1 #I1 #V1 #H
 146   elim (drop_inv_O1_pair1 … H) -H *
 147   [ #H1 #H2 destruct /3 width=1 by or_introl, conj/
 148   | /3 width=5 by ex3_3_intro, or_intror/
 149   ]
 150 ]
 151 qed-.
 152
 153 fact drop_inv_skip2_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → 0 < l →
 154                          ∀I,K2,V2. L2 = K2.ⓑ{I}V2 →
 155                          ∃∃K1,V1. ⬇[s, l-1, m] K1 ≡ K2 &
 156                                   ⬆[l-1, m] V2 ≡ V1 &
 157                                   L1 = K1.ⓑ{I}V1.
 158 #L1 #L2 #s #l #m * -L1 -L2 -l -m
 159 [ #l #m #_ #_ #J #K2 #W2 #H destruct
 160 | #I #L #V #H elim (lt_refl_false … H)
 161 | #I #L1 #L2 #V #m #_ #H elim (lt_refl_false … H)
 162 | #I #L1 #L2 #V1 #V2 #l #m #HL12 #HV21 #_ #J #K2 #W2 #H destruct /2 width=5 by ex3_2_intro/
 163 ]
 164 qed-.
 165
 166 (* Basic_1: was: drop_gen_skip_r *)
 167 lemma drop_inv_skip2: ∀I,L1,K2,V2,s,l,m. ⬇[s, l, m] L1 ≡ K2.ⓑ{I}V2 → 0 < l →
 168                       ∃∃K1,V1. ⬇[s, l-1, m] K1 ≡ K2 & ⬆[l-1, m] V2 ≡ V1 &
 169                                L1 = K1.ⓑ{I}V1.
 170 /2 width=3 by drop_inv_skip2_aux/ qed-.
 171
 172 lemma drop_inv_O1_gt: ∀L,K,m,s. ⬇[s, 0, m] L ≡ K → |L| < m →
 173                       s = Ⓣ ∧ K = ⋆.
 174 #L elim L -L [| #L #Z #X #IHL ] #K #m #s #H normalize in ⊢ (?%?→?); #H1m
 175 [ elim (drop_inv_atom1 … H) -H elim s -s /2 width=1 by conj/
 176   #_ #Hs lapply (Hs ?) // -Hs #H destruct elim (lt_zero_false … H1m)
 177 | elim (drop_inv_O1_pair1 … H) -H * #H2m #HLK destruct
 178   [ elim (lt_zero_false … H1m)
 179   | elim (IHL … HLK) -IHL -HLK /2 width=1 by lt_plus_to_minus_r, conj/
 180   ]
 181 ]
 182 qed-.
 183
 184 (* Basic properties *********************************************************)
 185
 186 lemma drop_refl_atom_O2: ∀s,l. ⬇[s, l, O] ⋆ ≡ ⋆.
 187 /2 width=1 by drop_atom/ qed.
 188
 189 (* Basic_1: was by definition: drop_refl *)
 190 lemma drop_refl: ∀L,l,s. ⬇[s, l, 0] L ≡ L.
 191 #L elim L -L //
 192 #L #I #V #IHL #l #s @(nat_ind_plus … l) -l /2 width=1 by drop_pair, drop_skip/
 193 qed.
 194
 195 lemma drop_drop_lt: ∀I,L1,L2,V,s,m.
 196                     ⬇[s, 0, m-1] L1 ≡ L2 → 0 < m → ⬇[s, 0, m] L1.ⓑ{I}V ≡ L2.
 197 #I #L1 #L2 #V #s #m #HL12 #Hm >(plus_minus_m_m m 1) /2 width=1 by drop_drop/
 198 qed.
 199
 200 lemma drop_skip_lt: ∀I,L1,L2,V1,V2,s,l,m.
 201                     ⬇[s, l-1, m] L1 ≡ L2 → ⬆[l-1, m] V2 ≡ V1 → 0 < l →
 202                     ⬇[s, l, m] L1. ⓑ{I} V1 ≡ L2.ⓑ{I}V2.
 203 #I #L1 #L2 #V1 #V2 #s #l #m #HL12 #HV21 #Hl >(plus_minus_m_m l 1) /2 width=1 by drop_skip/
 204 qed.
 205
 206 lemma drop_O1_le: ∀s,m,L. m ≤ |L| → ∃K. ⬇[s, 0, m] L ≡ K.
 207 #s #m @(nat_ind_plus … m) -m /2 width=2 by ex_intro/
 208 #m #IHm *
 209 [ #H elim (le_plus_xSy_O_false … H)
 210 | #L #I #V normalize #H elim (IHm L) -IHm /3 width=2 by drop_drop, monotonic_pred, ex_intro/
 211 ]
 212 qed-.
 213
 214 lemma drop_O1_lt: ∀s,L,m. m < |L| → ∃∃I,K,V. ⬇[s, 0, m] L ≡ K.ⓑ{I}V.
 215 #s #L elim L -L
 216 [ #m #H elim (lt_zero_false … H)
 217 | #L #I #V #IHL #m @(nat_ind_plus … m) -m /2 width=4 by drop_pair, ex1_3_intro/
 218   #m #_ normalize #H elim (IHL m) -IHL /3 width=4 by drop_drop, lt_plus_to_minus_r, lt_plus_to_lt_l, ex1_3_intro/
 219 ]
 220 qed-.
 221
 222 lemma drop_O1_pair: ∀L,K,m,s. ⬇[s, 0, m] L ≡ K → m ≤ |L| → ∀I,V.
 223                     ∃∃J,W. ⬇[s, 0, m] L.ⓑ{I}V ≡ K.ⓑ{J}W.
 224 #L elim L -L [| #L #Z #X #IHL ] #K #m #s #H normalize #Hm #I #V
 225 [ elim (drop_inv_atom1 … H) -H #H <(le_n_O_to_eq … Hm) -m
 226   #Hs destruct /2 width=3 by ex1_2_intro/
 227 | elim (drop_inv_O1_pair1 … H) -H * #Hm #HLK destruct /2 width=3 by ex1_2_intro/
 228   elim (IHL … HLK … Z X) -IHL -HLK
 229   /3 width=3 by drop_drop_lt, le_plus_to_minus, ex1_2_intro/
 230 ]
 231 qed-.
 232
 233 lemma drop_O1_ge: ∀L,m. |L| ≤ m → ⬇[Ⓣ, 0, m] L ≡ ⋆.
 234 #L elim L -L [ #m #_ @drop_atom #H destruct ]
 235 #L #I #V #IHL #m @(nat_ind_plus … m) -m [ #H elim (le_plus_xSy_O_false … H) ]
 236 normalize /4 width=1 by drop_drop, monotonic_pred/
 237 qed.
 238
 239 lemma drop_O1_eq: ∀L,s. ⬇[s, 0, |L|] L ≡ ⋆.
 240 #L elim L -L /2 width=1 by drop_drop, drop_atom/
 241 qed.
 242
 243 lemma drop_split: ∀L1,L2,l,m2,s. ⬇[s, l, m2] L1 ≡ L2 → ∀m1. m1 ≤ m2 →
 244                   ∃∃L. ⬇[s, l, m2 - m1] L1 ≡ L & ⬇[s, l, m1] L ≡ L2.
 245 #L1 #L2 #l #m2 #s #H elim H -L1 -L2 -l -m2
 246 [ #l #m2 #Hs #m1 #Hm12 @(ex2_intro … (⋆))
 247   @drop_atom #H lapply (Hs H) -s #H destruct /2 width=1 by le_n_O_to_eq/
 248 | #I #L1 #V #m1 #Hm1 lapply (le_n_O_to_eq … Hm1) -Hm1
 249   #H destruct /2 width=3 by ex2_intro/
 250 | #I #L1 #L2 #V #m2 #HL12 #IHL12 #m1 @(nat_ind_plus … m1) -m1
 251   [ /3 width=3 by drop_drop, ex2_intro/
 252   | -HL12 #m1 #_ #Hm12 lapply (le_plus_to_le_r … Hm12) -Hm12
 253     #Hm12 elim (IHL12 … Hm12) -IHL12 >minus_plus_plus_l
 254     #L #HL1 #HL2 elim (lt_or_ge (|L1|) (m2-m1)) #H0
 255     [ elim (drop_inv_O1_gt … HL1 H0) -HL1 #H1 #H2 destruct
 256       elim (drop_inv_atom1 … HL2) -HL2 #H #_ destruct
 257       @(ex2_intro … (⋆)) [ @drop_O1_ge normalize // ]
 258       @drop_atom #H destruct
 259     | elim (drop_O1_pair … HL1 H0 I V) -HL1 -H0 /3 width=5 by drop_drop, ex2_intro/
 260     ]
 261   ]
 262 | #I #L1 #L2 #V1 #V2 #l #m2 #_ #HV21 #IHL12 #m1 #Hm12 elim (IHL12 … Hm12) -IHL12
 263   #L #HL1 #HL2 elim (lift_split … HV21 l m1) -HV21 /3 width=5 by drop_skip, ex2_intro/
 264 ]
 265 qed-.
 266
 267 lemma drop_FT: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → ⬇[Ⓣ, l, m] L1 ≡ L2.
 268 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m
 269 /3 width=1 by drop_atom, drop_drop, drop_skip/
 270 qed.
 271
 272 lemma drop_gen: ∀L1,L2,s,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → ⬇[s, l, m] L1 ≡ L2.
 273 #L1 #L2 * /2 width=1 by drop_FT/
 274 qed-.
 275
 276 lemma drop_T: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → ⬇[Ⓣ, l, m] L1 ≡ L2.
 277 #L1 #L2 * /2 width=1 by drop_FT/
 278 qed-.
 279
 280 lemma d_liftable_LTC: ∀R. d_liftable R → d_liftable (CTC … R).
 281 #R #HR #K #T1 #T2 #H elim H -T2
 282 [ /3 width=10 by inj/
 283 | #T #T2 #_ #HT2 #IHT1 #L #s #l #m #HLK #U1 #HTU1 #U2 #HTU2
 284   elim (lift_total T l m) /4 width=12 by step/
 285 ]
 286 qed-.
 287
 288 lemma d_deliftable_sn_LTC: ∀R. d_deliftable_sn R → d_deliftable_sn (CTC … R).
 289 #R #HR #L #U1 #U2 #H elim H -U2
 290 [ #U2 #HU12 #K #s #l #m #HLK #T1 #HTU1
 291   elim (HR … HU12 … HLK … HTU1) -HR -L -U1 /3 width=3 by inj, ex2_intro/
 292 | #U #U2 #_ #HU2 #IHU1 #K #s #l #m #HLK #T1 #HTU1
 293   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 294   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by step, ex2_intro/
 295 ]
 296 qed-.
 297
 298 lemma dropable_sn_TC: ∀R. dropable_sn R → dropable_sn (TC … R).
 299 #R #HR #L1 #K1 #s #l #m #HLK1 #L2 #H elim H -L2
 300 [ #L2 #HL12 elim (HR … HLK1 … HL12) -HR -L1
 301   /3 width=3 by inj, ex2_intro/
 302 | #L #L2 #_ #HL2 * #K #HK1 #HLK elim (HR … HLK … HL2) -HR -L
 303   /3 width=3 by step, ex2_intro/
 304 ]
 305 qed-.
 306
 307 lemma dropable_dx_TC: ∀R. dropable_dx R → dropable_dx (TC … R).
 308 #R #HR #L1 #L2 #H elim H -L2
 309 [ #L2 #HL12 #K2 #s #m #HLK2 elim (HR … HL12 … HLK2) -HR -L2
 310   /3 width=3 by inj, ex2_intro/
 311 | #L #L2 #_ #HL2 #IHL1 #K2 #s #m #HLK2 elim (HR … HL2 … HLK2) -HR -L2
 312   #K #HLK #HK2 elim (IHL1 … HLK) -L
 313   /3 width=5 by step, ex2_intro/
 314 ]
 315 qed-.
 316
 317 lemma d_deliftable_sn_llstar: ∀R. d_deliftable_sn R →
 318                               ∀d. d_deliftable_sn (llstar … R d).
 319 #R #HR #d #L #U1 #U2 #H @(lstar_ind_r … d U2 H) -d -U2
 320 [ /2 width=3 by lstar_O, ex2_intro/
 321 | #d #U #U2 #_ #HU2 #IHU1 #K #s #l #m #HLK #T1 #HTU1
 322   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 323   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by lstar_dx, ex2_intro/
 324 ]
 325 qed-.
 326
 327 (* Basic forward lemmas *****************************************************)
 328
 329 (* Basic_1: was: drop_S *)
 330 lemma drop_fwd_drop2: ∀L1,I2,K2,V2,s,m. ⬇[s, O, m] L1 ≡ K2. ⓑ{I2} V2 →
 331                       ⬇[s, O, m + 1] L1 ≡ K2.
 332 #L1 elim L1 -L1
 333 [ #I2 #K2 #V2 #s #m #H lapply (drop_inv_atom1 … H) -H * #H destruct
 334 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #s #m #H
 335   elim (drop_inv_O1_pair1 … H) -H * #Hm #H
 336   [ -IHL1 destruct /2 width=1 by drop_drop/
 337   | @drop_drop >(plus_minus_m_m m 1) /2 width=3 by/
 338   ]
 339 ]
 340 qed-.
 341
 342 lemma drop_fwd_length_ge: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → |L1| ≤ l → |L2| = |L1|.
 343 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m // normalize
 344 [ #I #L1 #L2 #V #m #_ #_ #H elim (le_plus_xSy_O_false … H)
 345 | /4 width=2 by le_plus_to_le_r, eq_f/
 346 ]
 347 qed-.
 348
 349 lemma drop_fwd_length_le_le: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → l ≤ |L1| → m ≤ |L1| - l → |L2| = |L1| - m.
 350 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m // normalize
 351 [ /3 width=2 by le_plus_to_le_r/
 352 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #IHL12 >minus_plus_plus_l
 353   #Hl #Hm lapply (le_plus_to_le_r … Hl) -Hl
 354   #Hl >IHL12 // -L2 >plus_minus /2 width=3 by transitive_le/
 355 ]
 356 qed-.
 357
 358 lemma drop_fwd_length_le_ge: ∀L1,L2,l,m,s. ⬇[s, l, m] L1 ≡ L2 → l ≤ |L1| → |L1| - l ≤ m → |L2| = l.
 359 #L1 #L2 #l #m #s #H elim H -L1 -L2 -l -m normalize
 360 [ /2 width=1 by le_n_O_to_eq/
 361 | #I #L #V #_ <minus_n_O #H elim (le_plus_xSy_O_false … H)
 362 | /3 width=2 by le_plus_to_le_r/
 363 | /4 width=2 by le_plus_to_le_r, eq_f/
 364 ]
 365 qed-.
 366
 367 lemma drop_fwd_length: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L1| = |L2| + m.
 368 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m // normalize
 369 /2 width=1 by le_to_le_to_eq, le_n/
 370 qed-.
 371
 372 lemma drop_fwd_length_minus2: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L2| = |L1| - m.
 373 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H /2 width=1 by plus_minus, le_n/
 374 qed-.
 375
 376 lemma drop_fwd_length_minus4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → m = |L1| - |L2|.
 377 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 378 qed-.
 379
 380 lemma drop_fwd_length_le2: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → m ≤ |L1|.
 381 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 382 qed-.
 383
 384 lemma drop_fwd_length_le4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L2| ≤ |L1|.
 385 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H //
 386 qed-.
 387
 388 lemma drop_fwd_length_lt2: ∀L1,I2,K2,V2,l,m.
 389                            ⬇[Ⓕ, l, m] L1 ≡ K2. ⓑ{I2} V2 → m < |L1|.
 390 #L1 #I2 #K2 #V2 #l #m #H
 391 lapply (drop_fwd_length … H) normalize in ⊢ (%→?); -I2 -V2 //
 392 qed-.
 393
 394 lemma drop_fwd_length_lt4: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → 0 < m → |L2| < |L1|.
 395 #L1 #L2 #l #m #H lapply (drop_fwd_length … H) -H /2 width=1 by lt_minus_to_plus_r/
 396 qed-.
 397
 398 lemma drop_fwd_length_eq1: ∀L1,L2,K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 399                            |L1| = |L2| → |K1| = |K2|.
 400 #L1 #L2 #K1 #K2 #l #m #HLK1 #HLK2 #HL12
 401 lapply (drop_fwd_length … HLK1) -HLK1
 402 lapply (drop_fwd_length … HLK2) -HLK2
 403 /2 width=2 by injective_plus_r/
 404 qed-.
 405
 406 lemma drop_fwd_length_eq2: ∀L1,L2,K1,K2,l,m. ⬇[Ⓕ, l, m] L1 ≡ K1 → ⬇[Ⓕ, l, m] L2 ≡ K2 →
 407                            |K1| = |K2| → |L1| = |L2|.
 408 #L1 #L2 #K1 #K2 #l #m #HLK1 #HLK2 #HL12
 409 lapply (drop_fwd_length … HLK1) -HLK1
 410 lapply (drop_fwd_length … HLK2) -HLK2 //
 411 qed-.
 412
 413 lemma drop_fwd_lw: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → ♯{L2} ≤ ♯{L1}.
 414 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m // normalize
 415 [ /2 width=3 by transitive_le/
 416 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12
 417   >(lift_fwd_tw … HV21) -HV21 /2 width=1 by monotonic_le_plus_l/
 418 ]
 419 qed-.
 420
 421 lemma drop_fwd_lw_lt: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → 0 < m → ♯{L2} < ♯{L1}.
 422 #L1 #L2 #l #m #H elim H -L1 -L2 -l -m
 423 [ #l #m #H >H -H //
 424 | #I #L #V #H elim (lt_refl_false … H)
 425 | #I #L1 #L2 #V #m #HL12 #_ #_
 426   lapply (drop_fwd_lw … HL12) -HL12 #HL12
 427   @(le_to_lt_to_lt … HL12) -HL12 //
 428 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12 #H normalize in ⊢ (?%%); -I
 429   >(lift_fwd_tw … HV21) -V2 /3 by lt_minus_to_plus/
 430 ]
 431 qed-.
 432
 433 lemma drop_fwd_rfw: ∀I,L,K,V,i. ⬇[i] L ≡ K.ⓑ{I}V → ∀T. ♯{K, V} < ♯{L, T}.
 434 #I #L #K #V #i #HLK lapply (drop_fwd_lw … HLK) -HLK
 435 normalize in ⊢ (%→?→?%%); /3 width=3 by le_to_lt_to_lt/
 436 qed-.
 437
 438 (* Advanced inversion lemmas ************************************************)
 439
 440 fact drop_inv_O2_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 → m = 0 → L1 = L2.
 441 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m
 442 [ //
 443 | //
 444 | #I #L1 #L2 #V #m #_ #_ >commutative_plus normalize #H destruct
 445 | #I #L1 #L2 #V1 #V2 #l #m #_ #HV21 #IHL12 #H
 446   >(IHL12 H) -L1 >(lift_inv_O2_aux … HV21 … H) -V2 -l -m //
 447 ]
 448 qed-.
 449
 450 (* Basic_1: was: drop_gen_refl *)
 451 lemma drop_inv_O2: ∀L1,L2,s,l. ⬇[s, l, 0] L1 ≡ L2 → L1 = L2.
 452 /2 width=5 by drop_inv_O2_aux/ qed-.
 453
 454 lemma drop_inv_length_eq: ∀L1,L2,l,m. ⬇[Ⓕ, l, m] L1 ≡ L2 → |L1| = |L2| → m = 0.
 455 #L1 #L2 #l #m #H #HL12 lapply (drop_fwd_length_minus4 … H) //
 456 qed-.
 457
 458 lemma drop_inv_refl: ∀L,l,m. ⬇[Ⓕ, l, m] L ≡ L → m = 0.
 459 /2 width=5 by drop_inv_length_eq/ qed-.
 460
 461 fact drop_inv_FT_aux: ∀L1,L2,s,l,m. ⬇[s, l, m] L1 ≡ L2 →
 462                       ∀I,K,V. L2 = K.ⓑ{I}V → s = Ⓣ → l = 0 →
 463                       ⬇[Ⓕ, l, m] L1 ≡ K.ⓑ{I}V.
 464 #L1 #L2 #s #l #m #H elim H -L1 -L2 -l -m
 465 [ #l #m #_ #J #K #W #H destruct
 466 | #I #L #V #J #K #W #H destruct //
 467 | #I #L1 #L2 #V #m #_ #IHL12 #J #K #W #H1 #H2 destruct
 468   /3 width=1 by drop_drop/
 469 | #I #L1 #L2 #V1 #V2 #l #m #_ #_ #_ #J #K #W #_ #_
 470   <plus_n_Sm #H destruct
 471 ]
 472 qed-.
 473
 474 lemma drop_inv_FT: ∀I,L,K,V,m. ⬇[Ⓣ, 0, m] L ≡ K.ⓑ{I}V → ⬇[m] L ≡ K.ⓑ{I}V.
 475 /2 width=5 by drop_inv_FT_aux/ qed.
 476
 477 lemma drop_inv_gen: ∀I,L,K,V,s,m. ⬇[s, 0, m] L ≡ K.ⓑ{I}V → ⬇[m] L ≡ K.ⓑ{I}V.
 478 #I #L #K #V * /2 width=1 by drop_inv_FT/
 479 qed-.
 480
 481 lemma drop_inv_T: ∀I,L,K,V,s,m. ⬇[Ⓣ, 0, m] L ≡ K.ⓑ{I}V → ⬇[s, 0, m] L ≡ K.ⓑ{I}V.
 482 #I #L #K #V * /2 width=1 by drop_inv_FT/
 483 qed-.
 484
 485 (* Basic_1: removed theorems 50:
 486             drop_ctail drop_skip_flat
 487             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 488             drop_clear drop_clear_O drop_clear_S
 489             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 490             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 491             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 492             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 493             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 494             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 495             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 496             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 497             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 498 *)