matita/matita/contribs/lambdadelta/basic_2A/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_2.ma".
  16 include "basic_2A/notation/relations/rlift_4.ma".
  17 include "basic_2A/grammar/term_weight.ma".
  18 include "basic_2A/grammar/term_simple.ma".
  19
  20 (* BASIC TERM RELOCATION ****************************************************)
  21
  22 (* Basic_1: includes:
  23             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  24 *)
  25 inductive lift: relation4 nat nat term term ≝
  26 | lift_sort   : ∀k,l,m. lift l m (⋆k) (⋆k)
  27 | lift_lref_lt: ∀i,l,m. i < l → lift l m (#i) (#i)
  28 | lift_lref_ge: ∀i,l,m. l ≤ i → lift l m (#i) (#(i + m))
  29 | lift_gref   : ∀p,l,m. lift l m (§p) (§p)
  30 | lift_bind   : ∀a,I,V1,V2,T1,T2,l,m.
  31                 lift l m V1 V2 → lift (l + 1) m T1 T2 →
  32                 lift l m (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  33 | lift_flat   : ∀I,V1,V2,T1,T2,l,m.
  34                 lift l m V1 V2 → lift l m T1 T2 →
  35                 lift l m (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  36 .
  37
  38 interpretation "relocation" 'RLift l m T1 T2 = (lift l m T1 T2).
  39
  40 (* Basic inversion lemmas ***************************************************)
  41
  42 fact lift_inv_O2_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → m = 0 → T1 = T2.
  43 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 /3 width=1 by eq_f2/
  44 qed-.
  45
  46 lemma lift_inv_O2: ∀l,T1,T2. ⬆[l, 0] T1 ≡ T2 → T1 = T2.
  47 /2 width=4 by lift_inv_O2_aux/ qed-.
  48
  49 fact lift_inv_sort1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  50 #l #m #T1 #T2 * -l -m -T1 -T2 //
  51 [ #i #l #m #_ #k #H destruct
  52 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  53 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  54 ]
  55 qed-.
  56
  57 lemma lift_inv_sort1: ∀l,m,T2,k. ⬆[l,m] ⋆k ≡ T2 → T2 = ⋆k.
  58 /2 width=5 by lift_inv_sort1_aux/ qed-.
  59
  60 fact lift_inv_lref1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀i. T1 = #i →
  61                          (i < l ∧ T2 = #i) ∨ (l ≤ i ∧ T2 = #(i + m)).
  62 #l #m #T1 #T2 * -l -m -T1 -T2
  63 [ #k #l #m #i #H destruct
  64 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_introl, conj/
  65 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_intror, conj/
  66 | #p #l #m #i #H destruct
  67 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
  68 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
  69 ]
  70 qed-.
  71
  72 lemma lift_inv_lref1: ∀l,m,T2,i. ⬆[l,m] #i ≡ T2 →
  73                       (i < l ∧ T2 = #i) ∨ (l ≤ i ∧ T2 = #(i + m)).
  74 /2 width=3 by lift_inv_lref1_aux/ qed-.
  75
  76 lemma lift_inv_lref1_lt: ∀l,m,T2,i. ⬆[l,m] #i ≡ T2 → i < l → T2 = #i.
  77 #l #m #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  78 #Hli #_ #Hil lapply (le_to_lt_to_lt … Hli Hil) -Hli -Hil #Hll
  79 elim (lt_refl_false … Hll)
  80 qed-.
  81
  82 lemma lift_inv_lref1_ge: ∀l,m,T2,i. ⬆[l,m] #i ≡ T2 → l ≤ i → T2 = #(i + m).
  83 #l #m #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  84 #Hil #_ #Hli lapply (le_to_lt_to_lt … Hli Hil) -Hli -Hil #Hll
  85 elim (lt_refl_false … Hll)
  86 qed-.
  87
  88 fact lift_inv_gref1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀p. T1 = §p → T2 = §p.
  89 #l #m #T1 #T2 * -l -m -T1 -T2 //
  90 [ #i #l #m #_ #k #H destruct
  91 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  92 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  93 ]
  94 qed-.
  95
  96 lemma lift_inv_gref1: ∀l,m,T2,p. ⬆[l,m] §p ≡ T2 → T2 = §p.
  97 /2 width=5 by lift_inv_gref1_aux/ qed-.
  98
  99 fact lift_inv_bind1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 →
 100                          ∀a,I,V1,U1. T1 = ⓑ{a,I} V1.U1 →
 101                          ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & ⬆[l+1,m] U1 ≡ U2 &
 102                                   T2 = ⓑ{a,I} V2. U2.
 103 #l #m #T1 #T2 * -l -m -T1 -T2
 104 [ #k #l #m #a #I #V1 #U1 #H destruct
 105 | #i #l #m #_ #a #I #V1 #U1 #H destruct
 106 | #i #l #m #_ #a #I #V1 #U1 #H destruct
 107 | #p #l #m #a #I #V1 #U1 #H destruct
 108 | #b #J #W1 #W2 #T1 #T2 #l #m #HW #HT #a #I #V1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 109 | #J #W1 #W2 #T1 #T2 #l #m #_ #HT #a #I #V1 #U1 #H destruct
 110 ]
 111 qed-.
 112
 113 lemma lift_inv_bind1: ∀l,m,T2,a,I,V1,U1. ⬆[l,m] ⓑ{a,I} V1. U1 ≡ T2 →
 114                       ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & ⬆[l+1,m] U1 ≡ U2 &
 115                                T2 = ⓑ{a,I} V2. U2.
 116 /2 width=3 by lift_inv_bind1_aux/ qed-.
 117
 118 fact lift_inv_flat1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 →
 119                          ∀I,V1,U1. T1 = ⓕ{I} V1.U1 →
 120                          ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & ⬆[l,m] U1 ≡ U2 &
 121                                   T2 = ⓕ{I} V2. U2.
 122 #l #m #T1 #T2 * -l -m -T1 -T2
 123 [ #k #l #m #I #V1 #U1 #H destruct
 124 | #i #l #m #_ #I #V1 #U1 #H destruct
 125 | #i #l #m #_ #I #V1 #U1 #H destruct
 126 | #p #l #m #I #V1 #U1 #H destruct
 127 | #a #J #W1 #W2 #T1 #T2 #l #m #_ #_ #I #V1 #U1 #H destruct
 128 | #J #W1 #W2 #T1 #T2 #l #m #HW #HT #I #V1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 129 ]
 130 qed-.
 131
 132 lemma lift_inv_flat1: ∀l,m,T2,I,V1,U1. ⬆[l,m] ⓕ{I} V1. U1 ≡ T2 →
 133                       ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & ⬆[l,m] U1 ≡ U2 &
 134                                T2 = ⓕ{I} V2. U2.
 135 /2 width=3 by lift_inv_flat1_aux/ qed-.
 136
 137 fact lift_inv_sort2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 138 #l #m #T1 #T2 * -l -m -T1 -T2 //
 139 [ #i #l #m #_ #k #H destruct
 140 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 141 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 142 ]
 143 qed-.
 144
 145 (* Basic_1: was: lift_gen_sort *)
 146 lemma lift_inv_sort2: ∀l,m,T1,k. ⬆[l,m] T1 ≡ ⋆k → T1 = ⋆k.
 147 /2 width=5 by lift_inv_sort2_aux/ qed-.
 148
 149 fact lift_inv_lref2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀i. T2 = #i →
 150                          (i < l ∧ T1 = #i) ∨ (l + m ≤ i ∧ T1 = #(i - m)).
 151 #l #m #T1 #T2 * -l -m -T1 -T2
 152 [ #k #l #m #i #H destruct
 153 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_introl, conj/
 154 | #j #l #m #Hj #i #Hi destruct <minus_plus_m_m /4 width=1 by monotonic_le_plus_l, or_intror, conj/
 155 | #p #l #m #i #H destruct
 156 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
 157 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
 158 ]
 159 qed-.
 160
 161 (* Basic_1: was: lift_gen_lref *)
 162 lemma lift_inv_lref2: ∀l,m,T1,i. ⬆[l,m] T1 ≡ #i →
 163                       (i < l ∧ T1 = #i) ∨ (l + m ≤ i ∧ T1 = #(i - m)).
 164 /2 width=3 by lift_inv_lref2_aux/ qed-.
 165
 166 (* Basic_1: was: lift_gen_lref_lt *)
 167 lemma lift_inv_lref2_lt: ∀l,m,T1,i. ⬆[l,m] T1 ≡ #i → i < l → T1 = #i.
 168 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 169 #Hli #_ #Hil lapply (le_to_lt_to_lt … Hli Hil) -Hli -Hil #Hll
 170 elim (lt_inv_plus_l … Hll) -Hll #Hll
 171 elim (lt_refl_false … Hll)
 172 qed-.
 173
 174 (* Basic_1: was: lift_gen_lref_false *)
 175 lemma lift_inv_lref2_be: ∀l,m,T1,i. ⬆[l,m] T1 ≡ #i →
 176                          l ≤ i → i < l + m → ⊥.
 177 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H *
 178 [ #H1 #_ #H2 #_ | #H2 #_ #_ #H1 ]
 179 lapply (le_to_lt_to_lt … H2 H1) -H2 -H1 #H
 180 elim (lt_refl_false … H)
 181 qed-.
 182
 183 (* Basic_1: was: lift_gen_lref_ge *)
 184 lemma lift_inv_lref2_ge: ∀l,m,T1,i. ⬆[l,m] T1 ≡ #i → l + m ≤ i → T1 = #(i - m).
 185 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 186 #Hil #_ #Hli lapply (le_to_lt_to_lt … Hli Hil) -Hli -Hil #Hll
 187 elim (lt_inv_plus_l … Hll) -Hll #Hll
 188 elim (lt_refl_false … Hll)
 189 qed-.
 190
 191 fact lift_inv_gref2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀p. T2 = §p → T1 = §p.
 192 #l #m #T1 #T2 * -l -m -T1 -T2 //
 193 [ #i #l #m #_ #k #H destruct
 194 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 195 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 196 ]
 197 qed-.
 198
 199 lemma lift_inv_gref2: ∀l,m,T1,p. ⬆[l,m] T1 ≡ §p → T1 = §p.
 200 /2 width=5 by lift_inv_gref2_aux/ qed-.
 201
 202 fact lift_inv_bind2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 →
 203                          ∀a,I,V2,U2. T2 = ⓑ{a,I} V2.U2 →
 204                          ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & ⬆[l+1,m] U1 ≡ U2 &
 205                                   T1 = ⓑ{a,I} V1. U1.
 206 #l #m #T1 #T2 * -l -m -T1 -T2
 207 [ #k #l #m #a #I #V2 #U2 #H destruct
 208 | #i #l #m #_ #a #I #V2 #U2 #H destruct
 209 | #i #l #m #_ #a #I #V2 #U2 #H destruct
 210 | #p #l #m #a #I #V2 #U2 #H destruct
 211 | #b #J #W1 #W2 #T1 #T2 #l #m #HW #HT #a #I #V2 #U2 #H destruct /2 width=5 by ex3_2_intro/
 212 | #J #W1 #W2 #T1 #T2 #l #m #_ #_ #a #I #V2 #U2 #H destruct
 213 ]
 214 qed-.
 215
 216 (* Basic_1: was: lift_gen_bind *)
 217 lemma lift_inv_bind2: ∀l,m,T1,a,I,V2,U2. ⬆[l,m] T1 ≡ ⓑ{a,I} V2. U2 →
 218                       ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & ⬆[l+1,m] U1 ≡ U2 &
 219                                T1 = ⓑ{a,I} V1. U1.
 220 /2 width=3 by lift_inv_bind2_aux/ qed-.
 221
 222 fact lift_inv_flat2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 →
 223                          ∀I,V2,U2. T2 = ⓕ{I} V2.U2 →
 224                          ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & ⬆[l,m] U1 ≡ U2 &
 225                                   T1 = ⓕ{I} V1. U1.
 226 #l #m #T1 #T2 * -l -m -T1 -T2
 227 [ #k #l #m #I #V2 #U2 #H destruct
 228 | #i #l #m #_ #I #V2 #U2 #H destruct
 229 | #i #l #m #_ #I #V2 #U2 #H destruct
 230 | #p #l #m #I #V2 #U2 #H destruct
 231 | #a #J #W1 #W2 #T1 #T2 #l #m #_ #_ #I #V2 #U2 #H destruct
 232 | #J #W1 #W2 #T1 #T2 #l #m #HW #HT #I #V2 #U2 #H destruct /2 width=5 by ex3_2_intro/
 233 ]
 234 qed-.
 235
 236 (* Basic_1: was: lift_gen_flat *)
 237 lemma lift_inv_flat2: ∀l,m,T1,I,V2,U2. ⬆[l,m] T1 ≡  ⓕ{I} V2. U2 →
 238                       ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & ⬆[l,m] U1 ≡ U2 &
 239                                T1 = ⓕ{I} V1. U1.
 240 /2 width=3 by lift_inv_flat2_aux/ qed-.
 241
 242 lemma lift_inv_pair_xy_x: ∀l,m,I,V,T. ⬆[l, m] ②{I} V. T ≡ V → ⊥.
 243 #l #m #J #V elim V -V
 244 [ * #i #T #H
 245   [ lapply (lift_inv_sort2 … H) -H #H destruct
 246   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 247   | lapply (lift_inv_gref2 … H) -H #H destruct
 248   ]
 249 | * [ #a ] #I #W2 #U2 #IHW2 #_ #T #H
 250   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2 by/
 251   | elim (lift_inv_flat2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2 by/
 252   ]
 253 ]
 254 qed-.
 255
 256 (* Basic_1: was: thead_x_lift_y_y *)
 257 lemma lift_inv_pair_xy_y: ∀I,T,V,l,m. ⬆[l, m] ②{I} V. T ≡ T → ⊥.
 258 #J #T elim T -T
 259 [ * #i #V #l #m #H
 260   [ lapply (lift_inv_sort2 … H) -H #H destruct
 261   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 262   | lapply (lift_inv_gref2 … H) -H #H destruct
 263   ]
 264 | * [ #a ] #I #W2 #U2 #_ #IHU2 #V #l #m #H
 265   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4 by/
 266   | elim (lift_inv_flat2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4 by/
 267   ]
 268 ]
 269 qed-.
 270
 271 (* Basic forward lemmas *****************************************************)
 272
 273 lemma lift_fwd_pair1: ∀I,T2,V1,U1,l,m. ⬆[l,m] ②{I}V1.U1 ≡ T2 →
 274                       ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & T2 = ②{I}V2.U2.
 275 * [ #a ] #I #T2 #V1 #U1 #l #m #H
 276 [ elim (lift_inv_bind1 … H) -H /2 width=4 by ex2_2_intro/
 277 |  elim (lift_inv_flat1 … H) -H /2 width=4 by ex2_2_intro/
 278 ]
 279 qed-.
 280
 281 lemma lift_fwd_pair2: ∀I,T1,V2,U2,l,m. ⬆[l,m] T1 ≡ ②{I}V2.U2 →
 282                       ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & T1 = ②{I}V1.U1.
 283 * [ #a ] #I #T1 #V2 #U2 #l #m #H
 284 [ elim (lift_inv_bind2 … H) -H /2 width=4 by ex2_2_intro/
 285 |  elim (lift_inv_flat2 … H) -H /2 width=4 by ex2_2_intro/
 286 ]
 287 qed-.
 288
 289 lemma lift_fwd_tw: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ♯{T1} = ♯{T2}.
 290 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 normalize //
 291 qed-.
 292
 293 lemma lift_simple_dx: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → 𝐒⦃T1⦄ → 𝐒⦃T2⦄.
 294 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 //
 295 #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #_ #_ #H
 296 elim (simple_inv_bind … H)
 297 qed-.
 298
 299 lemma lift_simple_sn: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → 𝐒⦃T2⦄ → 𝐒⦃T1⦄.
 300 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 //
 301 #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #_ #_ #H
 302 elim (simple_inv_bind … H)
 303 qed-.
 304
 305 (* Basic properties *********************************************************)
 306
 307 (* Basic_1: was: lift_lref_gt *)
 308 lemma lift_lref_ge_minus: ∀l,m,i. l + m ≤ i → ⬆[l, m] #(i - m) ≡ #i.
 309 #l #m #i #H >(plus_minus_m_m i m) in ⊢ (? ? ? ? %); /3 width=2 by lift_lref_ge, le_plus_to_minus_r, le_plus_b/
 310 qed.
 311
 312 lemma lift_lref_ge_minus_eq: ∀l,m,i,j. l + m ≤ i → j = i - m → ⬆[l, m] #j ≡ #i.
 313 /2 width=1 by lift_lref_ge_minus/ qed-.
 314
 315 (* Basic_1: was: lift_r *)
 316 lemma lift_refl: ∀T,l. ⬆[l, 0] T ≡ T.
 317 #T elim T -T
 318 [ * #i // #l elim (lt_or_ge i l) /2 width=1 by lift_lref_lt, lift_lref_ge/
 319 | * /2 width=1 by lift_bind, lift_flat/
 320 ]
 321 qed.
 322
 323 lemma lift_total: ∀T1,l,m. ∃T2. ⬆[l,m] T1 ≡ T2.
 324 #T1 elim T1 -T1
 325 [ * #i /2 width=2 by lift_sort, lift_gref, ex_intro/
 326   #l #m elim (lt_or_ge i l) /3 width=2 by lift_lref_lt, lift_lref_ge, ex_intro/
 327 | * [ #a ] #I #V1 #T1 #IHV1 #IHT1 #l #m
 328   elim (IHV1 l m) -IHV1 #V2 #HV12
 329   [ elim (IHT1 (l+1) m) -IHT1 /3 width=2 by lift_bind, ex_intro/
 330   | elim (IHT1 l m) -IHT1 /3 width=2 by lift_flat, ex_intro/
 331   ]
 332 ]
 333 qed.
 334
 335 (* Basic_1: was: lift_free (right to left) *)
 336 lemma lift_split: ∀l1,m2,T1,T2. ⬆[l1, m2] T1 ≡ T2 →
 337                   ∀l2,m1. l1 ≤ l2 → l2 ≤ l1 + m1 → m1 ≤ m2 →
 338                   ∃∃T. ⬆[l1, m1] T1 ≡ T & ⬆[l2, m2 - m1] T ≡ T2.
 339 #l1 #m2 #T1 #T2 #H elim H -l1 -m2 -T1 -T2
 340 [ /3 width=3 by lift_sort, ex2_intro/
 341 | #i #l1 #m2 #Hil1 #l2 #m1 #Hl12 #_ #_
 342   lapply (lt_to_le_to_lt … Hil1 Hl12) -Hl12 #Hil2 /4 width=3 by lift_lref_lt, ex2_intro/
 343 | #i #l1 #m2 #Hil1 #l2 #m1 #_ #Hl21 #Hm12
 344   lapply (transitive_le … (i+m1) Hl21 ?) /2 width=1 by monotonic_le_plus_l/ -Hl21 #Hl21
 345   >(plus_minus_m_m m2 m1 ?) /3 width=3 by lift_lref_ge, ex2_intro/
 346 | /3 width=3 by lift_gref, ex2_intro/
 347 | #a #I #V1 #V2 #T1 #T2 #l1 #m2 #_ #_ #IHV #IHT #l2 #m1 #Hl12 #Hl21 #Hm12
 348   elim (IHV … Hl12 Hl21 Hm12) -IHV #V0 #HV0a #HV0b
 349   elim (IHT (l2+1) … ? ? Hm12) /3 width=5 by lift_bind, monotonic_le_plus_l, ex2_intro/
 350 | #I #V1 #V2 #T1 #T2 #l1 #m2 #_ #_ #IHV #IHT #l2 #m1 #Hl12 #Hl21 #Hm12
 351   elim (IHV … Hl12 Hl21 Hm12) -IHV #V0 #HV0a #HV0b
 352   elim (IHT l2 … ? ? Hm12) /3 width=5 by lift_flat, ex2_intro/
 353 ]
 354 qed.
 355
 356 (* Basic_1: was only: dnf_dec2 dnf_dec *)
 357 lemma is_lift_dec: ∀T2,l,m. Decidable (∃T1. ⬆[l,m] T1 ≡ T2).
 358 #T1 elim T1 -T1
 359 [ * [1,3: /3 width=2 by lift_sort, lift_gref, ex_intro, or_introl/ ] #i #l #m
 360   elim (lt_or_ge i l) #Hli
 361   [ /4 width=3 by lift_lref_lt, ex_intro, or_introl/
 362   | elim (lt_or_ge i (l + m)) #Hilm
 363     [ @or_intror * #T1 #H elim (lift_inv_lref2_be … H Hli Hilm)
 364     | -Hli /4 width=2 by lift_lref_ge_minus, ex_intro, or_introl/
 365     ]
 366   ]
 367 | * [ #a ] #I #V2 #T2 #IHV2 #IHT2 #l #m
 368   [ elim (IHV2 l m) -IHV2
 369     [ * #V1 #HV12 elim (IHT2 (l+1) m) -IHT2
 370       [ * #T1 #HT12 @or_introl /3 width=2 by lift_bind, ex_intro/
 371       | -V1 #HT2 @or_intror * #X #H
 372         elim (lift_inv_bind2 … H) -H /3 width=2 by ex_intro/
 373       ]
 374     | -IHT2 #HV2 @or_intror * #X #H
 375       elim (lift_inv_bind2 … H) -H /3 width=2 by ex_intro/
 376     ]
 377   | elim (IHV2 l m) -IHV2
 378     [ * #V1 #HV12 elim (IHT2 l m) -IHT2
 379       [ * #T1 #HT12 /4 width=2 by lift_flat, ex_intro, or_introl/
 380       | -V1 #HT2 @or_intror * #X #H
 381         elim (lift_inv_flat2 … H) -H /3 width=2 by ex_intro/
 382       ]
 383     | -IHT2 #HV2 @or_intror * #X #H
 384       elim (lift_inv_flat2 … H) -H /3 width=2 by ex_intro/
 385     ]
 386   ]
 387 ]
 388 qed.
 389
 390 (* Basic_1: removed theorems 7:
 391             lift_head lift_gen_head
 392             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 393             lift_tlt_dx
 394 *)