matita/matita/contribs/lambdadelta/basic_2A/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/rlift_4.ma".
  16 include "basic_2A/grammar/term_weight.ma".
  17 include "basic_2A/grammar/term_simple.ma".
  18
  19 (* BASIC TERM RELOCATION ****************************************************)
  20
  21 (* Basic_1: includes:
  22             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  23 *)
  24 inductive lift: relation4 nat nat term term ≝
  25 | lift_sort   : ∀k,l,m. lift l m (⋆k) (⋆k)
  26 | lift_lref_lt: ∀i,l,m. i < l → lift l m (#i) (#i)
  27 | lift_lref_ge: ∀i,l,m. l ≤ i → lift l m (#i) (#(i + m))
  28 | lift_gref   : ∀p,l,m. lift l m (§p) (§p)
  29 | lift_bind   : ∀a,I,V1,V2,T1,T2,l,m.
  30                 lift l m V1 V2 → lift (l + 1) m T1 T2 →
  31                 lift l m (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  32 | lift_flat   : ∀I,V1,V2,T1,T2,l,m.
  33                 lift l m V1 V2 → lift l m T1 T2 →
  34                 lift l m (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  35 .
  36
  37 interpretation "relocation" 'RLift l m T1 T2 = (lift l m T1 T2).
  38
  39 (* Basic inversion lemmas ***************************************************)
  40
  41 fact lift_inv_O2_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → m = 0 → T1 = T2.
  42 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 /3 width=1 by eq_f2/
  43 qed-.
  44
  45 lemma lift_inv_O2: ∀l,T1,T2. ⬆[l, 0] T1 ≡ T2 → T1 = T2.
  46 /2 width=4 by lift_inv_O2_aux/ qed-.
  47
  48 fact lift_inv_sort1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  49 #l #m #T1 #T2 * -l -m -T1 -T2 //
  50 [ #i #l #m #_ #k #H destruct
  51 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  52 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  53 ]
  54 qed-.
  55
  56 lemma lift_inv_sort1: ∀l,m,T2,k. ⬆[l,m] ⋆k ≡ T2 → T2 = ⋆k.
  57 /2 width=5 by lift_inv_sort1_aux/ qed-.
  58
  59 fact lift_inv_lref1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀i. T1 = #i →
  60                          (i < l ∧ T2 = #i) ∨ (l ≤ i ∧ T2 = #(i + m)).
  61 #l #m #T1 #T2 * -l -m -T1 -T2
  62 [ #k #l #m #i #H destruct
  63 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_introl, conj/
  64 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_intror, conj/
  65 | #p #l #m #i #H destruct
  66 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
  67 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
  68 ]
  69 qed-.
  70
  71 lemma lift_inv_lref1: ∀l,m,T2,i. ⬆[l,m] #i ≡ T2 →
  72                       (i < l ∧ T2 = #i) ∨ (l ≤ i ∧ T2 = #(i + m)).
  73 /2 width=3 by lift_inv_lref1_aux/ qed-.
  74
  75 lemma lift_inv_lref1_lt: ∀l,m,T2,i. ⬆[l,m] #i ≡ T2 → i < l → T2 = #i.
  76 #l #m #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  77 #Hli #_ #Hil lapply (le_to_lt_to_lt … Hli Hil) -Hli -Hil #Hll
  78 elim (lt_refl_false … Hll)
  79 qed-.
  80
  81 lemma lift_inv_lref1_ge: ∀l,m,T2,i. ⬆[l,m] #i ≡ T2 → l ≤ i → T2 = #(i + m).
  82 #l #m #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  83 #Hil #_ #Hli lapply (le_to_lt_to_lt … Hli Hil) -Hli -Hil #Hll
  84 elim (lt_refl_false … Hll)
  85 qed-.
  86
  87 fact lift_inv_gref1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀p. T1 = §p → T2 = §p.
  88 #l #m #T1 #T2 * -l -m -T1 -T2 //
  89 [ #i #l #m #_ #k #H destruct
  90 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  91 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  92 ]
  93 qed-.
  94
  95 lemma lift_inv_gref1: ∀l,m,T2,p. ⬆[l,m] §p ≡ T2 → T2 = §p.
  96 /2 width=5 by lift_inv_gref1_aux/ qed-.
  97
  98 fact lift_inv_bind1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 →
  99                          ∀a,I,V1,U1. T1 = ⓑ{a,I} V1.U1 →
 100                          ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & ⬆[l+1,m] U1 ≡ U2 &
 101                                   T2 = ⓑ{a,I} V2. U2.
 102 #l #m #T1 #T2 * -l -m -T1 -T2
 103 [ #k #l #m #a #I #V1 #U1 #H destruct
 104 | #i #l #m #_ #a #I #V1 #U1 #H destruct
 105 | #i #l #m #_ #a #I #V1 #U1 #H destruct
 106 | #p #l #m #a #I #V1 #U1 #H destruct
 107 | #b #J #W1 #W2 #T1 #T2 #l #m #HW #HT #a #I #V1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 108 | #J #W1 #W2 #T1 #T2 #l #m #_ #HT #a #I #V1 #U1 #H destruct
 109 ]
 110 qed-.
 111
 112 lemma lift_inv_bind1: ∀l,m,T2,a,I,V1,U1. ⬆[l,m] ⓑ{a,I} V1. U1 ≡ T2 →
 113                       ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & ⬆[l+1,m] U1 ≡ U2 &
 114                                T2 = ⓑ{a,I} V2. U2.
 115 /2 width=3 by lift_inv_bind1_aux/ qed-.
 116
 117 fact lift_inv_flat1_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 →
 118                          ∀I,V1,U1. T1 = ⓕ{I} V1.U1 →
 119                          ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & ⬆[l,m] U1 ≡ U2 &
 120                                   T2 = ⓕ{I} V2. U2.
 121 #l #m #T1 #T2 * -l -m -T1 -T2
 122 [ #k #l #m #I #V1 #U1 #H destruct
 123 | #i #l #m #_ #I #V1 #U1 #H destruct
 124 | #i #l #m #_ #I #V1 #U1 #H destruct
 125 | #p #l #m #I #V1 #U1 #H destruct
 126 | #a #J #W1 #W2 #T1 #T2 #l #m #_ #_ #I #V1 #U1 #H destruct
 127 | #J #W1 #W2 #T1 #T2 #l #m #HW #HT #I #V1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 128 ]
 129 qed-.
 130
 131 lemma lift_inv_flat1: ∀l,m,T2,I,V1,U1. ⬆[l,m] ⓕ{I} V1. U1 ≡ T2 →
 132                       ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & ⬆[l,m] U1 ≡ U2 &
 133                                T2 = ⓕ{I} V2. U2.
 134 /2 width=3 by lift_inv_flat1_aux/ qed-.
 135
 136 fact lift_inv_sort2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 137 #l #m #T1 #T2 * -l -m -T1 -T2 //
 138 [ #i #l #m #_ #k #H destruct
 139 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 140 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 141 ]
 142 qed-.
 143
 144 (* Basic_1: was: lift_gen_sort *)
 145 lemma lift_inv_sort2: ∀l,m,T1,k. ⬆[l,m] T1 ≡ ⋆k → T1 = ⋆k.
 146 /2 width=5 by lift_inv_sort2_aux/ qed-.
 147
 148 fact lift_inv_lref2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀i. T2 = #i →
 149                          (i < l ∧ T1 = #i) ∨ (l + m ≤ i ∧ T1 = #(i - m)).
 150 #l #m #T1 #T2 * -l -m -T1 -T2
 151 [ #k #l #m #i #H destruct
 152 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_introl, conj/
 153 | #j #l #m #Hj #i #Hi destruct <minus_plus_m_m /4 width=1 by monotonic_le_plus_l, or_intror, conj/
 154 | #p #l #m #i #H destruct
 155 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
 156 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
 157 ]
 158 qed-.
 159
 160 (* Basic_1: was: lift_gen_lref *)
 161 lemma lift_inv_lref2: ∀l,m,T1,i. ⬆[l,m] T1 ≡ #i →
 162                       (i < l ∧ T1 = #i) ∨ (l + m ≤ i ∧ T1 = #(i - m)).
 163 /2 width=3 by lift_inv_lref2_aux/ qed-.
 164
 165 (* Basic_1: was: lift_gen_lref_lt *)
 166 lemma lift_inv_lref2_lt: ∀l,m,T1,i. ⬆[l,m] T1 ≡ #i → i < l → T1 = #i.
 167 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 168 #Hli #_ #Hil lapply (le_to_lt_to_lt … Hli Hil) -Hli -Hil #Hll
 169 elim (lt_inv_plus_l … Hll) -Hll #Hll
 170 elim (lt_refl_false … Hll)
 171 qed-.
 172
 173 (* Basic_1: was: lift_gen_lref_false *)
 174 lemma lift_inv_lref2_be: ∀l,m,T1,i. ⬆[l,m] T1 ≡ #i →
 175                          l ≤ i → i < l + m → ⊥.
 176 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H *
 177 [ #H1 #_ #H2 #_ | #H2 #_ #_ #H1 ]
 178 lapply (le_to_lt_to_lt … H2 H1) -H2 -H1 #H
 179 elim (lt_refl_false … H)
 180 qed-.
 181
 182 (* Basic_1: was: lift_gen_lref_ge *)
 183 lemma lift_inv_lref2_ge: ∀l,m,T1,i. ⬆[l,m] T1 ≡ #i → l + m ≤ i → T1 = #(i - m).
 184 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 185 #Hil #_ #Hli lapply (le_to_lt_to_lt … Hli Hil) -Hli -Hil #Hll
 186 elim (lt_inv_plus_l … Hll) -Hll #Hll
 187 elim (lt_refl_false … Hll)
 188 qed-.
 189
 190 fact lift_inv_gref2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 → ∀p. T2 = §p → T1 = §p.
 191 #l #m #T1 #T2 * -l -m -T1 -T2 //
 192 [ #i #l #m #_ #k #H destruct
 193 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 194 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 195 ]
 196 qed-.
 197
 198 lemma lift_inv_gref2: ∀l,m,T1,p. ⬆[l,m] T1 ≡ §p → T1 = §p.
 199 /2 width=5 by lift_inv_gref2_aux/ qed-.
 200
 201 fact lift_inv_bind2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 →
 202                          ∀a,I,V2,U2. T2 = ⓑ{a,I} V2.U2 →
 203                          ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & ⬆[l+1,m] U1 ≡ U2 &
 204                                   T1 = ⓑ{a,I} V1. U1.
 205 #l #m #T1 #T2 * -l -m -T1 -T2
 206 [ #k #l #m #a #I #V2 #U2 #H destruct
 207 | #i #l #m #_ #a #I #V2 #U2 #H destruct
 208 | #i #l #m #_ #a #I #V2 #U2 #H destruct
 209 | #p #l #m #a #I #V2 #U2 #H destruct
 210 | #b #J #W1 #W2 #T1 #T2 #l #m #HW #HT #a #I #V2 #U2 #H destruct /2 width=5 by ex3_2_intro/
 211 | #J #W1 #W2 #T1 #T2 #l #m #_ #_ #a #I #V2 #U2 #H destruct
 212 ]
 213 qed-.
 214
 215 (* Basic_1: was: lift_gen_bind *)
 216 lemma lift_inv_bind2: ∀l,m,T1,a,I,V2,U2. ⬆[l,m] T1 ≡ ⓑ{a,I} V2. U2 →
 217                       ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & ⬆[l+1,m] U1 ≡ U2 &
 218                                T1 = ⓑ{a,I} V1. U1.
 219 /2 width=3 by lift_inv_bind2_aux/ qed-.
 220
 221 fact lift_inv_flat2_aux: ∀l,m,T1,T2. ⬆[l,m] T1 ≡ T2 →
 222                          ∀I,V2,U2. T2 = ⓕ{I} V2.U2 →
 223                          ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & ⬆[l,m] U1 ≡ U2 &
 224                                   T1 = ⓕ{I} V1. U1.
 225 #l #m #T1 #T2 * -l -m -T1 -T2
 226 [ #k #l #m #I #V2 #U2 #H destruct
 227 | #i #l #m #_ #I #V2 #U2 #H destruct
 228 | #i #l #m #_ #I #V2 #U2 #H destruct
 229 | #p #l #m #I #V2 #U2 #H destruct
 230 | #a #J #W1 #W2 #T1 #T2 #l #m #_ #_ #I #V2 #U2 #H destruct
 231 | #J #W1 #W2 #T1 #T2 #l #m #HW #HT #I #V2 #U2 #H destruct /2 width=5 by ex3_2_intro/
 232 ]
 233 qed-.
 234
 235 (* Basic_1: was: lift_gen_flat *)
 236 lemma lift_inv_flat2: ∀l,m,T1,I,V2,U2. ⬆[l,m] T1 ≡  ⓕ{I} V2. U2 →
 237                       ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & ⬆[l,m] U1 ≡ U2 &
 238                                T1 = ⓕ{I} V1. U1.
 239 /2 width=3 by lift_inv_flat2_aux/ qed-.
 240
 241 lemma lift_inv_pair_xy_x: ∀l,m,I,V,T. ⬆[l, m] ②{I} V. T ≡ V → ⊥.
 242 #l #m #J #V elim V -V
 243 [ * #i #T #H
 244   [ lapply (lift_inv_sort2 … H) -H #H destruct
 245   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 246   | lapply (lift_inv_gref2 … H) -H #H destruct
 247   ]
 248 | * [ #a ] #I #W2 #U2 #IHW2 #_ #T #H
 249   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2 by/
 250   | elim (lift_inv_flat2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2 by/
 251   ]
 252 ]
 253 qed-.
 254
 255 (* Basic_1: was: thead_x_lift_y_y *)
 256 lemma lift_inv_pair_xy_y: ∀I,T,V,l,m. ⬆[l, m] ②{I} V. T ≡ T → ⊥.
 257 #J #T elim T -T
 258 [ * #i #V #l #m #H
 259   [ lapply (lift_inv_sort2 … H) -H #H destruct
 260   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 261   | lapply (lift_inv_gref2 … H) -H #H destruct
 262   ]
 263 | * [ #a ] #I #W2 #U2 #_ #IHU2 #V #l #m #H
 264   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4 by/
 265   | elim (lift_inv_flat2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4 by/
 266   ]
 267 ]
 268 qed-.
 269
 270 (* Basic forward lemmas *****************************************************)
 271
 272 lemma lift_fwd_pair1: ∀I,T2,V1,U1,l,m. ⬆[l,m] ②{I}V1.U1 ≡ T2 →
 273                       ∃∃V2,U2. ⬆[l,m] V1 ≡ V2 & T2 = ②{I}V2.U2.
 274 * [ #a ] #I #T2 #V1 #U1 #l #m #H
 275 [ elim (lift_inv_bind1 … H) -H /2 width=4 by ex2_2_intro/
 276 |  elim (lift_inv_flat1 … H) -H /2 width=4 by ex2_2_intro/
 277 ]
 278 qed-.
 279
 280 lemma lift_fwd_pair2: ∀I,T1,V2,U2,l,m. ⬆[l,m] T1 ≡ ②{I}V2.U2 →
 281                       ∃∃V1,U1. ⬆[l,m] V1 ≡ V2 & T1 = ②{I}V1.U1.
 282 * [ #a ] #I #T1 #V2 #U2 #l #m #H
 283 [ elim (lift_inv_bind2 … H) -H /2 width=4 by ex2_2_intro/
 284 |  elim (lift_inv_flat2 … H) -H /2 width=4 by ex2_2_intro/
 285 ]
 286 qed-.
 287
 288 lemma lift_fwd_tw: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ♯{T1} = ♯{T2}.
 289 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 normalize //
 290 qed-.
 291
 292 lemma lift_simple_dx: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → 𝐒⦃T1⦄ → 𝐒⦃T2⦄.
 293 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 //
 294 #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #_ #_ #H
 295 elim (simple_inv_bind … H)
 296 qed-.
 297
 298 lemma lift_simple_sn: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → 𝐒⦃T2⦄ → 𝐒⦃T1⦄.
 299 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 //
 300 #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #_ #_ #H
 301 elim (simple_inv_bind … H)
 302 qed-.
 303
 304 (* Basic properties *********************************************************)
 305
 306 (* Basic_1: was: lift_lref_gt *)
 307 lemma lift_lref_ge_minus: ∀l,m,i. l + m ≤ i → ⬆[l, m] #(i - m) ≡ #i.
 308 #l #m #i #H >(plus_minus_m_m i m) in ⊢ (? ? ? ? %); /3 width=2 by lift_lref_ge, le_plus_to_minus_r, le_plus_b/
 309 qed.
 310
 311 lemma lift_lref_ge_minus_eq: ∀l,m,i,j. l + m ≤ i → j = i - m → ⬆[l, m] #j ≡ #i.
 312 /2 width=1 by lift_lref_ge_minus/ qed-.
 313
 314 (* Basic_1: was: lift_r *)
 315 lemma lift_refl: ∀T,l. ⬆[l, 0] T ≡ T.
 316 #T elim T -T
 317 [ * #i // #l elim (lt_or_ge i l) /2 width=1 by lift_lref_lt, lift_lref_ge/
 318 | * /2 width=1 by lift_bind, lift_flat/
 319 ]
 320 qed.
 321
 322 lemma lift_total: ∀T1,l,m. ∃T2. ⬆[l,m] T1 ≡ T2.
 323 #T1 elim T1 -T1
 324 [ * #i /2 width=2 by lift_sort, lift_gref, ex_intro/
 325   #l #m elim (lt_or_ge i l) /3 width=2 by lift_lref_lt, lift_lref_ge, ex_intro/
 326 | * [ #a ] #I #V1 #T1 #IHV1 #IHT1 #l #m
 327   elim (IHV1 l m) -IHV1 #V2 #HV12
 328   [ elim (IHT1 (l+1) m) -IHT1 /3 width=2 by lift_bind, ex_intro/
 329   | elim (IHT1 l m) -IHT1 /3 width=2 by lift_flat, ex_intro/
 330   ]
 331 ]
 332 qed.
 333
 334 (* Basic_1: was: lift_free (right to left) *)
 335 lemma lift_split: ∀l1,m2,T1,T2. ⬆[l1, m2] T1 ≡ T2 →
 336                   ∀l2,m1. l1 ≤ l2 → l2 ≤ l1 + m1 → m1 ≤ m2 →
 337                   ∃∃T. ⬆[l1, m1] T1 ≡ T & ⬆[l2, m2 - m1] T ≡ T2.
 338 #l1 #m2 #T1 #T2 #H elim H -l1 -m2 -T1 -T2
 339 [ /3 width=3 by lift_sort, ex2_intro/
 340 | #i #l1 #m2 #Hil1 #l2 #m1 #Hl12 #_ #_
 341   lapply (lt_to_le_to_lt … Hil1 Hl12) -Hl12 #Hil2 /4 width=3 by lift_lref_lt, ex2_intro/
 342 | #i #l1 #m2 #Hil1 #l2 #m1 #_ #Hl21 #Hm12
 343   lapply (transitive_le … (i+m1) Hl21 ?) /2 width=1 by monotonic_le_plus_l/ -Hl21 #Hl21
 344   >(plus_minus_m_m m2 m1 ?) /3 width=3 by lift_lref_ge, ex2_intro/
 345 | /3 width=3 by lift_gref, ex2_intro/
 346 | #a #I #V1 #V2 #T1 #T2 #l1 #m2 #_ #_ #IHV #IHT #l2 #m1 #Hl12 #Hl21 #Hm12
 347   elim (IHV … Hl12 Hl21 Hm12) -IHV #V0 #HV0a #HV0b
 348   elim (IHT (l2+1) … ? ? Hm12) /3 width=5 by lift_bind, le_S_S, ex2_intro/
 349 | #I #V1 #V2 #T1 #T2 #l1 #m2 #_ #_ #IHV #IHT #l2 #m1 #Hl12 #Hl21 #Hm12
 350   elim (IHV … Hl12 Hl21 Hm12) -IHV #V0 #HV0a #HV0b
 351   elim (IHT l2 … ? ? Hm12) /3 width=5 by lift_flat, ex2_intro/
 352 ]
 353 qed.
 354
 355 (* Basic_1: was only: dnf_dec2 dnf_dec *)
 356 lemma is_lift_dec: ∀T2,l,m. Decidable (∃T1. ⬆[l,m] T1 ≡ T2).
 357 #T1 elim T1 -T1
 358 [ * [1,3: /3 width=2 by lift_sort, lift_gref, ex_intro, or_introl/ ] #i #l #m
 359   elim (lt_or_ge i l) #Hli
 360   [ /4 width=3 by lift_lref_lt, ex_intro, or_introl/
 361   | elim (lt_or_ge i (l + m)) #Hilm
 362     [ @or_intror * #T1 #H elim (lift_inv_lref2_be … H Hli Hilm)
 363     | -Hli /4 width=2 by lift_lref_ge_minus, ex_intro, or_introl/
 364     ]
 365   ]
 366 | * [ #a ] #I #V2 #T2 #IHV2 #IHT2 #l #m
 367   [ elim (IHV2 l m) -IHV2
 368     [ * #V1 #HV12 elim (IHT2 (l+1) m) -IHT2
 369       [ * #T1 #HT12 @or_introl /3 width=2 by lift_bind, ex_intro/
 370       | -V1 #HT2 @or_intror * #X #H
 371         elim (lift_inv_bind2 … H) -H /3 width=2 by ex_intro/
 372       ]
 373     | -IHT2 #HV2 @or_intror * #X #H
 374       elim (lift_inv_bind2 … H) -H /3 width=2 by ex_intro/
 375     ]
 376   | elim (IHV2 l m) -IHV2
 377     [ * #V1 #HV12 elim (IHT2 l m) -IHT2
 378       [ * #T1 #HT12 /4 width=2 by lift_flat, ex_intro, or_introl/
 379       | -V1 #HT2 @or_intror * #X #H
 380         elim (lift_inv_flat2 … H) -H /3 width=2 by ex_intro/
 381       ]
 382     | -IHT2 #HV2 @or_intror * #X #H
 383       elim (lift_inv_flat2 … H) -H /3 width=2 by ex_intro/
 384     ]
 385   ]
 386 ]
 387 qed.
 388
 389 (* Basic_1: removed theorems 7:
 390             lift_head lift_gen_head
 391             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 392             lift_tlt_dx
 393 *)