matita/matita/contribs/lambdadelta/basic_2A/substitution/lift_neg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/substitution/lift.ma".
  16
  17 (* BASIC TERM RELOCATION ****************************************************)
  18
  19 (* Properties on negated basic relocation ***********************************)
  20
  21 lemma nlift_lref_be_SO: ∀X,i. ⬆[i, 1] X ≡ #i → ⊥.
  22 /2 width=7 by lift_inv_lref2_be/ qed-.
  23
  24 lemma nlift_bind_sn: ∀W,l,m. (∀V. ⬆[l, m] V ≡ W → ⊥) →
  25                      ∀a,I,U. (∀X. ⬆[l, m] X ≡ ⓑ{a,I}W.U → ⊥).
  26 #W #l #m #HW #a #I #U #X #H elim (lift_inv_bind2 … H) -H /2 width=2 by/
  27 qed-.
  28
  29 lemma nlift_bind_dx: ∀U,l,m. (∀T. ⬆[l+1, m] T ≡ U → ⊥) →
  30                      ∀a,I,W. (∀X. ⬆[l, m] X ≡ ⓑ{a,I}W.U → ⊥).
  31 #U #l #m #HU #a #I #W #X #H elim (lift_inv_bind2 … H) -H /2 width=2 by/
  32 qed-.
  33
  34 lemma nlift_flat_sn: ∀W,l,m. (∀V. ⬆[l, m] V ≡ W → ⊥) →
  35                      ∀I,U. (∀X. ⬆[l, m] X ≡ ⓕ{I}W.U → ⊥).
  36 #W #l #m #HW #I #U #X #H elim (lift_inv_flat2 … H) -H /2 width=2 by/
  37 qed-.
  38
  39 lemma nlift_flat_dx: ∀U,l,m. (∀T. ⬆[l, m] T ≡ U → ⊥) →
  40                      ∀I,W. (∀X. ⬆[l, m] X ≡ ⓕ{I}W.U → ⊥).
  41 #U #l #m #HU #I #W #X #H elim (lift_inv_flat2 … H) -H /2 width=2 by/
  42 qed-.
  43
  44 (* Inversion lemmas on negated basic relocation *****************************)
  45
  46 lemma nlift_inv_lref_be_SO: ∀i,j. (∀X. ⬆[i, 1] X ≡ #j → ⊥) → j = i.
  47 #i #j elim (lt_or_eq_or_gt i j) // #Hij #H
  48 [ elim (H (#(j-1))) -H /2 width=1 by lift_lref_ge_minus/
  49 | elim (H (#j)) -H /2 width=1 by lift_lref_lt/
  50 ]
  51 qed-.
  52
  53 lemma nlift_inv_bind: ∀a,I,W,U,l,m. (∀X. ⬆[l, m] X ≡ ⓑ{a,I}W.U → ⊥) →
  54                       (∀V. ⬆[l, m] V ≡ W → ⊥) ∨ (∀T. ⬆[l+1, m] T ≡ U → ⊥).
  55 #a #I #W #U #l #m #H elim (is_lift_dec W l m)
  56 [ * /4 width=2 by lift_bind, or_intror/
  57 | /4 width=2 by ex_intro, or_introl/
  58 ]
  59 qed-.
  60
  61 lemma nlift_inv_flat: ∀I,W,U,l,m. (∀X. ⬆[l, m] X ≡ ⓕ{I}W.U → ⊥) →
  62                       (∀V. ⬆[l, m] V ≡ W → ⊥) ∨ (∀T. ⬆[l, m] T ≡ U → ⊥).
  63 #I #W #U #l #m #H elim (is_lift_dec W l m)
  64 [ * /4 width=2 by lift_flat, or_intror/
  65 | /4 width=2 by ex_intro, or_introl/
  66 ]
  67 qed-.