matita/matita/contribs/lambdadelta/basic_2A/substitution/lpx_sn.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/grammar/lenv_length.ma".
  16
  17 (* SN POINTWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS *********)
  18
  19 inductive lpx_sn (R:relation3 lenv term term): relation lenv ≝
  20 | lpx_sn_atom: lpx_sn R (⋆) (⋆)
  21 | lpx_sn_pair: ∀I,K1,K2,V1,V2.
  22                lpx_sn R K1 K2 → R K1 V1 V2 →
  23                lpx_sn R (K1. ⓑ{I} V1) (K2. ⓑ{I} V2)
  24 .
  25
  26 (* Basic properties *********************************************************)
  27
  28 lemma lpx_sn_refl: ∀R. (∀L. reflexive ? (R L)) → reflexive … (lpx_sn R).
  29 #R #HR #L elim L -L /2 width=1 by lpx_sn_atom, lpx_sn_pair/
  30 qed-.
  31
  32 (* Basic inversion lemmas ***************************************************)
  33
  34 fact lpx_sn_inv_atom1_aux: ∀R,L1,L2. lpx_sn R L1 L2 → L1 = ⋆ → L2 = ⋆.
  35 #R #L1 #L2 * -L1 -L2
  36 [ //
  37 | #I #K1 #K2 #V1 #V2 #_ #_ #H destruct
  38 ]
  39 qed-.
  40
  41 lemma lpx_sn_inv_atom1: ∀R,L2. lpx_sn R (⋆) L2 → L2 = ⋆.
  42 /2 width=4 by lpx_sn_inv_atom1_aux/ qed-.
  43
  44 fact lpx_sn_inv_pair1_aux: ∀R,L1,L2. lpx_sn R L1 L2 → ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
  45                            ∃∃K2,V2. lpx_sn R K1 K2 & R K1 V1 V2 & L2 = K2. ⓑ{I} V2.
  46 #R #L1 #L2 * -L1 -L2
  47 [ #J #K1 #V1 #H destruct
  48 | #I #K1 #K2 #V1 #V2 #HK12 #HV12 #J #L #W #H destruct /2 width=5 by ex3_2_intro/
  49 ]
  50 qed-.
  51
  52 lemma lpx_sn_inv_pair1: ∀R,I,K1,V1,L2. lpx_sn R (K1. ⓑ{I} V1) L2 →
  53                         ∃∃K2,V2. lpx_sn R K1 K2 & R K1 V1 V2 & L2 = K2. ⓑ{I} V2.
  54 /2 width=3 by lpx_sn_inv_pair1_aux/ qed-.
  55
  56 fact lpx_sn_inv_atom2_aux: ∀R,L1,L2. lpx_sn R L1 L2 → L2 = ⋆ → L1 = ⋆.
  57 #R #L1 #L2 * -L1 -L2
  58 [ //
  59 | #I #K1 #K2 #V1 #V2 #_ #_ #H destruct
  60 ]
  61 qed-.
  62
  63 lemma lpx_sn_inv_atom2: ∀R,L1. lpx_sn R L1 (⋆) → L1 = ⋆.
  64 /2 width=4 by lpx_sn_inv_atom2_aux/ qed-.
  65
  66 fact lpx_sn_inv_pair2_aux: ∀R,L1,L2. lpx_sn R L1 L2 → ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
  67                            ∃∃K1,V1. lpx_sn R K1 K2 & R K1 V1 V2 & L1 = K1. ⓑ{I} V1.
  68 #R #L1 #L2 * -L1 -L2
  69 [ #J #K2 #V2 #H destruct
  70 | #I #K1 #K2 #V1 #V2 #HK12 #HV12 #J #K #W #H destruct /2 width=5 by ex3_2_intro/
  71 ]
  72 qed-.
  73
  74 lemma lpx_sn_inv_pair2: ∀R,I,L1,K2,V2. lpx_sn R L1 (K2. ⓑ{I} V2) →
  75                         ∃∃K1,V1. lpx_sn R K1 K2 & R K1 V1 V2 & L1 = K1. ⓑ{I} V1.
  76 /2 width=3 by lpx_sn_inv_pair2_aux/ qed-.
  77
  78 lemma lpx_sn_inv_pair: ∀R,I1,I2,L1,L2,V1,V2.
  79                        lpx_sn R (L1.ⓑ{I1}V1) (L2.ⓑ{I2}V2) →
  80                        ∧∧ lpx_sn R L1 L2 & R L1 V1 V2 & I1 = I2.
  81 #R #I1 #I2 #L1 #L2 #V1 #V2 #H elim (lpx_sn_inv_pair1 … H) -H
  82 #L0 #V0 #HL10 #HV10 #H destruct /2 width=1 by and3_intro/
  83 qed-.
  84
  85 (* Basic forward lemmas *****************************************************)
  86
  87 lemma lpx_sn_fwd_length: ∀R,L1,L2. lpx_sn R L1 L2 → |L1| = |L2|.
  88 #R #L1 #L2 #H elim H -L1 -L2 normalize //
  89 qed-.