matita/matita/contribs/lambdadelta/basic_2A/unfold/lstas.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_4_3.ma".
  16 include "ground/xoa/ex_4_4.ma".
  17 include "basic_2A/notation/relations/statictypestar_6.ma".
  18 include "basic_2A/grammar/genv.ma".
  19 include "basic_2A/substitution/drop.ma".
  20 include "basic_2A/static/sh.ma".
  21
  22 (* NAT-ITERATED STATIC TYPE ASSIGNMENT FOR TERMS ****************************)
  23
  24 (* activate genv *)
  25 inductive lstas (h): nat → relation4 genv lenv term term ≝
  26 | lstas_sort: ∀G,L,d,k. lstas h d G L (⋆k) (⋆((next h)^d k))
  27 | lstas_ldef: ∀G,L,K,V,W,U,i,d. ⬇[i] L ≡ K.ⓓV → lstas h d G K V W →
  28               ⬆[0, i+1] W ≡ U → lstas h d G L (#i) U
  29 | lstas_zero: ∀G,L,K,W,V,i. ⬇[i] L ≡ K.ⓛW → lstas h 0 G K W V →
  30               lstas h 0 G L (#i) (#i)
  31 | lstas_succ: ∀G,L,K,W,V,U,i,d. ⬇[i] L ≡ K.ⓛW → lstas h d G K W V →
  32               ⬆[0, i+1] V ≡ U → lstas h (d+1) G L (#i) U
  33 | lstas_bind: ∀a,I,G,L,V,T,U,d. lstas h d G (L.ⓑ{I}V) T U →
  34               lstas h d G L (ⓑ{a,I}V.T) (ⓑ{a,I}V.U)
  35 | lstas_appl: ∀G,L,V,T,U,d. lstas h d G L T U → lstas h d G L (ⓐV.T) (ⓐV.U)
  36 | lstas_cast: ∀G,L,W,T,U,d. lstas h d G L T U → lstas h d G L (ⓝW.T) U
  37 .
  38
  39 interpretation "nat-iterated static type assignment (term)"
  40    'StaticTypeStar h G L d T U = (lstas h d G L T U).
  41
  42 (* Basic inversion lemmas ***************************************************)
  43
  44 fact lstas_inv_sort1_aux: ∀h,G,L,T,U,d. ⦃G, L⦄ ⊢ T •*[h, d] U → ∀k0. T = ⋆k0 →
  45                           U = ⋆((next h)^d k0).
  46 #h #G #L #T #U #d * -G -L -T -U -d
  47 [ #G #L #d #k #k0 #H destruct //
  48 | #G #L #K #V #W #U #i #d #_ #_ #_ #k0 #H destruct
  49 | #G #L #K #W #V #i #_ #_ #k0 #H destruct
  50 | #G #L #K #W #V #U #i #d #_ #_ #_ #k0 #H destruct
  51 | #a #I #G #L #V #T #U #d #_ #k0 #H destruct
  52 | #G #L #V #T #U #d #_ #k0 #H destruct
  53 | #G #L #W #T #U #d #_ #k0 #H destruct
  54 qed-.
  55
  56 lemma lstas_inv_sort1: ∀h,G,L,X,k,d. ⦃G, L⦄ ⊢ ⋆k •*[h, d] X → X = ⋆((next h)^d k).
  57 /2 width=5 by lstas_inv_sort1_aux/
  58 qed-.
  59
  60 fact lstas_inv_lref1_aux: ∀h,G,L,T,U,d. ⦃G, L⦄ ⊢ T •*[h, d] U → ∀j. T = #j → ∨∨
  61                           (∃∃K,V,W. ⬇[j] L ≡ K.ⓓV & ⦃G, K⦄ ⊢ V •*[h, d] W &
  62                                     ⬆[0, j+1] W ≡ U
  63                           ) |
  64                           (∃∃K,W,V. ⬇[j] L ≡ K.ⓛW & ⦃G, K⦄ ⊢ W •*[h, 0] V &
  65                                     U = #j & d = 0
  66                           ) |
  67                           (∃∃K,W,V,d0. ⬇[j] L ≡ K.ⓛW & ⦃G, K⦄ ⊢ W •*[h, d0] V &
  68                                        ⬆[0, j+1] V ≡ U & d = d0+1
  69                           ).
  70 #h #G #L #T #U #d * -G -L -T -U -d
  71 [ #G #L #d #k #j #H destruct
  72 | #G #L #K #V #W #U #i #d #HLK #HVW #HWU #j #H destruct /3 width=6 by or3_intro0, ex3_3_intro/
  73 | #G #L #K #W #V #i #HLK #HWV #j #H destruct /3 width=5 by or3_intro1, ex4_3_intro/
  74 | #G #L #K #W #V #U #i #d #HLK #HWV #HWU #j #H destruct /3 width=8 by or3_intro2, ex4_4_intro/
  75 | #a #I #G #L #V #T #U #d #_ #j #H destruct
  76 | #G #L #V #T #U #d #_ #j #H destruct
  77 | #G #L #W #T #U #d #_ #j #H destruct
  78 ]
  79 qed-.
  80
  81 lemma lstas_inv_lref1: ∀h,G,L,X,i,d. ⦃G, L⦄ ⊢ #i •*[h, d] X → ∨∨
  82                        (∃∃K,V,W. ⬇[i] L ≡ K.ⓓV & ⦃G, K⦄ ⊢ V •*[h, d] W &
  83                                  ⬆[0, i+1] W ≡ X
  84                        ) |
  85                        (∃∃K,W,V. ⬇[i] L ≡ K.ⓛW & ⦃G, K⦄ ⊢ W •*[h, 0] V &
  86                                  X = #i & d = 0
  87                        ) |
  88                        (∃∃K,W,V,d0. ⬇[i] L ≡ K.ⓛW & ⦃G, K⦄ ⊢ W •*[h, d0] V &
  89                                     ⬆[0, i+1] V ≡ X & d = d0+1
  90                        ).
  91 /2 width=3 by lstas_inv_lref1_aux/
  92 qed-.
  93
  94 lemma lstas_inv_lref1_O: ∀h,G,L,X,i. ⦃G, L⦄ ⊢ #i •*[h, 0] X →
  95                          (∃∃K,V,W. ⬇[i] L ≡ K.ⓓV & ⦃G, K⦄ ⊢ V •*[h, 0] W &
  96                                    ⬆[0, i+1] W ≡ X
  97                          ) ∨
  98                          (∃∃K,W,V. ⬇[i] L ≡ K.ⓛW & ⦃G, K⦄ ⊢ W •*[h, 0] V &
  99                                    X = #i
 100                          ).
 101 #h #G #L #X #i #H elim (lstas_inv_lref1 … H) -H * /3 width=6 by ex3_3_intro, or_introl, or_intror/
 102 #K #W #V #d #_ #_ #_ <plus_n_Sm #H destruct
 103 qed-.
 104
 105 lemma lstas_inv_lref1_S: ∀h,G,L,X,i,d. ⦃G, L⦄ ⊢ #i •*[h, d+1] X →
 106                          (∃∃K,V,W. ⬇[i] L ≡ K.ⓓV & ⦃G, K⦄ ⊢ V •*[h, d+1] W &
 107                                    ⬆[0, i+1] W ≡ X
 108                          ) ∨
 109                          (∃∃K,W,V. ⬇[i] L ≡ K.ⓛW & ⦃G, K⦄ ⊢ W •*[h, d] V &
 110                                    ⬆[0, i+1] V ≡ X
 111                          ).
 112 #h #G #L #X #i #d #H elim (lstas_inv_lref1 … H) -H * /3 width=6 by ex3_3_intro, or_introl, or_intror/
 113 #K #W #V #_ #_ #_ <plus_n_Sm #H destruct
 114 qed-.
 115
 116 fact lstas_inv_gref1_aux: ∀h,G,L,T,U,d. ⦃G, L⦄ ⊢ T •*[h, d] U → ∀p0. T = §p0 → ⊥.
 117 #h #G #L #T #U #d * -G -L -T -U -d
 118 [ #G #L #d #k #p0 #H destruct
 119 | #G #L #K #V #W #U #i #d #_ #_ #_ #p0 #H destruct
 120 | #G #L #K #W #V #i #_ #_ #p0 #H destruct
 121 | #G #L #K #W #V #U #i #d #_ #_ #_ #p0 #H destruct
 122 | #a #I #G #L #V #T #U #d #_ #p0 #H destruct
 123 | #G #L #V #T #U #d #_ #p0 #H destruct
 124 | #G #L #W #T #U #d #_ #p0 #H destruct
 125 qed-.
 126
 127 lemma lstas_inv_gref1: ∀h,G,L,X,p,d. ⦃G, L⦄ ⊢ §p •*[h, d] X → ⊥.
 128 /2 width=9 by lstas_inv_gref1_aux/
 129 qed-.
 130
 131 fact lstas_inv_bind1_aux: ∀h,G,L,T,U,d. ⦃G, L⦄ ⊢ T •*[h, d] U → ∀b,J,X,Y. T = ⓑ{b,J}Y.X →
 132                           ∃∃Z. ⦃G, L.ⓑ{J}Y⦄ ⊢ X •*[h, d] Z & U = ⓑ{b,J}Y.Z.
 133 #h #G #L #T #U #d * -G -L -T -U -d
 134 [ #G #L #d #k #b #J #X #Y #H destruct
 135 | #G #L #K #V #W #U #i #d #_ #_ #_ #b #J #X #Y #H destruct
 136 | #G #L #K #W #V #i #_ #_ #b #J #X #Y #H destruct
 137 | #G #L #K #W #V #U #i #d #_ #_ #_ #b #J #X #Y #H destruct
 138 | #a #I #G #L #V #T #U #d #HTU #b #J #X #Y #H destruct /2 width=3 by ex2_intro/
 139 | #G #L #V #T #U #d #_ #b #J #X #Y #H destruct
 140 | #G #L #W #T #U #d #_ #b #J #X #Y #H destruct
 141 ]
 142 qed-.
 143
 144 lemma lstas_inv_bind1: ∀h,a,I,G,L,V,T,X,d. ⦃G, L⦄ ⊢ ⓑ{a,I}V.T •*[h, d] X →
 145                        ∃∃U. ⦃G, L.ⓑ{I}V⦄ ⊢ T •*[h, d] U & X = ⓑ{a,I}V.U.
 146 /2 width=3 by lstas_inv_bind1_aux/
 147 qed-.
 148
 149 fact lstas_inv_appl1_aux: ∀h,G,L,T,U,d. ⦃G, L⦄ ⊢ T •*[h, d] U → ∀X,Y. T = ⓐY.X →
 150                           ∃∃Z. ⦃G, L⦄ ⊢ X •*[h, d] Z & U = ⓐY.Z.
 151 #h #G #L #T #U #d * -G -L -T -U -d
 152 [ #G #L #d #k #X #Y #H destruct
 153 | #G #L #K #V #W #U #i #d #_ #_ #_ #X #Y #H destruct
 154 | #G #L #K #W #V #i #_ #_ #X #Y #H destruct
 155 | #G #L #K #W #V #U #i #d #_ #_ #_ #X #Y #H destruct
 156 | #a #I #G #L #V #T #U #d #_ #X #Y #H destruct
 157 | #G #L #V #T #U #d #HTU #X #Y #H destruct /2 width=3 by ex2_intro/
 158 | #G #L #W #T #U #d #_ #X #Y #H destruct
 159 ]
 160 qed-.
 161
 162 lemma lstas_inv_appl1: ∀h,G,L,V,T,X,d. ⦃G, L⦄ ⊢ ⓐV.T •*[h, d] X →
 163                        ∃∃U. ⦃G, L⦄ ⊢ T •*[h, d] U & X = ⓐV.U.
 164 /2 width=3 by lstas_inv_appl1_aux/
 165 qed-.
 166
 167 fact lstas_inv_cast1_aux: ∀h,G,L,T,U,d. ⦃G, L⦄ ⊢ T •*[h, d] U → ∀X,Y. T = ⓝY.X →
 168                           ⦃G, L⦄ ⊢ X •*[h, d] U.
 169 #h #G #L #T #U #d * -G -L -T -U -d
 170 [ #G #L #d #k #X #Y #H destruct
 171 | #G #L #K #V #W #U #i #d #_ #_ #_ #X #Y #H destruct
 172 | #G #L #K #W #V #i #_ #_ #X #Y #H destruct
 173 | #G #L #K #W #V #U #i #d #_ #_ #_ #X #Y #H destruct
 174 | #a #I #G #L #V #T #U #d #_ #X #Y #H destruct
 175 | #G #L #V #T #U #d #_ #X #Y #H destruct
 176 | #G #L #W #T #U #d #HTU #X #Y #H destruct //
 177 ]
 178 qed-.
 179
 180 lemma lstas_inv_cast1: ∀h,G,L,W,T,U,d. ⦃G, L⦄ ⊢ ⓝW.T •*[h, d] U → ⦃G, L⦄ ⊢ T •*[h, d] U.
 181 /2 width=4 by lstas_inv_cast1_aux/
 182 qed-.