matita/matita/contribs/lambdadelta/bin/roles/rolesUtils.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module ET = RolesTypes
  13
  14 let raise_error e =
  15   raise (ET.Error e)
  16
  17 let list_union error compare l1 l2 =
  18   let rec aux l1 l2 = match l1 with
  19   | []       -> l2
  20   | hd1::tl1 -> match l2 with
  21   | []       -> l1
  22   | hd2::tl2 ->
  23     let b = compare (snd hd1) (snd hd2) in
  24     if b > 0 then hd2 :: aux l1 tl2
  25     else if b < 0 then hd1 :: aux tl1 l2
  26     else raise_error (error (snd hd1))
  27   in
  28   aux l1 l2
  29
  30 let list_compare compare l1 l2 =
  31   let rec aux l1 l2 = match l1 with
  32   | []       ->
  33     if l2 = [] then 0 else -1
  34   | hd1::tl1 -> match l2 with
  35   | []       -> 1
  36   | hd2::tl2 ->
  37     let b = compare hd1 hd2 in
  38     if b = 0 then aux tl1 tl2 else b
  39   in
  40   aux l1 l2
  41
  42 let rec list_nth n = function
  43   | []         -> raise_error ET.ENoEntry
  44   | (_,hd)::tl -> if n = 0 then hd else list_nth (pred n) tl
  45
  46 let rec list_toggle n = function
  47   | []         -> raise_error ET.ENoEntry
  48   | (b,hd)::tl -> if n = 0 then (not b,hd)::tl else (b,hd)::list_toggle (pred n) tl
  49
  50 let rec list_toggle_all = function
  51   | []         -> []
  52   | (b,hd)::tl -> (not b,hd)::list_toggle_all tl
  53
  54 let rec list_split = function
  55   | []                -> [], []
  56   | (b,a) as hd :: tl ->
  57     let fs,ts = list_split tl in
  58     if fst hd then fs,((false,a)::ts)
  59     else (hd::fs),ts
  60
  61 let rec list_select r = function
  62   | []         -> r
  63   | (b,hd)::tl ->
  64     begin match b, r with
  65     | false, _      -> list_select r tl
  66     | true , None   -> list_select (Some hd) tl
  67     | true , Some _ -> raise_error (ET.EWrongSelect)
  68     end
  69
  70 let rec list_exists compare = function
  71   | []        -> false
  72   | (_,a)::tl ->
  73     let b = compare a in
  74     if b <= 0 then b = 0 else
  75     list_exists compare tl
  76
  77 let rec list_count s c = function
  78   | []         -> s, c
  79   | (b, _)::tl -> list_count (s + if b then 1 else 0) (succ c) tl
  80
  81 let string_of_version v =
  82   String.concat "." (List.map string_of_int v)
  83
  84 let version_of_string s =
  85   List.map int_of_string (String.split_on_char '.' s)
  86
  87 let compare_versions v1 v2 =
  88   list_compare compare v1 v2
  89
  90 let string_of_name n =
  91   String.concat "_" n
  92
  93 let name_of_string s =
  94   String.split_on_char '_' s
  95
  96 let compare_names n1 n2 =
  97   list_compare compare n1 n2
  98
  99 let names_union ns1 ns2 =
 100   let error n = ET.ENameClash n in
 101   list_union error compare_names ns1 ns2
 102
 103 let string_of_obj (v,n) =
 104   Printf.sprintf "%s/%s" (string_of_version v) (string_of_name n)
 105
 106 let obj_of_string s =
 107   match String.split_on_char '/' s with
 108   | [sv;sn] -> version_of_string sv, name_of_string sn
 109   | _       -> failwith "obj_of_string"
 110
 111 let compare_objs (v1,n1) (v2,n2) =
 112   let b = compare_versions v1 v2 in
 113   if b = 0 then compare_names n1 n2 else b
 114
 115 let objs_union os1 os2 =
 116   let error o = ET.EObjClash o in
 117   list_union error compare_objs os1 os2
 118
 119 let rec rev_objs_of_names v os = function
 120   | []        -> os
 121   | (b,n)::tl -> rev_objs_of_names v ((b,(v,n))::os) tl
 122
 123 let obj_of_role r =
 124   let n = match r.ET.n with
 125     | []        -> []
 126     | (_,n):: _ -> n
 127   in
 128   r.ET.v, n
 129
 130 let string_of_role r =
 131   string_of_obj (obj_of_role r)
 132
 133 let compare_roles r1 r2 =
 134   compare_objs (obj_of_role r1) (obj_of_role r2)
 135
 136 let roles_union rs1 rs2 =
 137   let error r = ET.ERoleClash r in
 138   list_union error compare_roles rs1 rs2
 139
 140 let exists_role_deleted v r =
 141   let o = v, [] in
 142   let compare r = compare_objs o (obj_of_role r) in
 143   list_exists compare r
 144
 145 let rec get_tops v = function
 146   | []        -> [], []
 147   | (_,r)::tl ->
 148     let ds, ts = get_tops v tl in
 149     if compare_versions v r.ET.v = 0 then begin
 150       if r.ET.n = [] then objs_union r.ET.o ds, ts else
 151       let tops = rev_objs_of_names v [] r.ET.n in
 152       ds, objs_union (List.rev tops) ts
 153     end else
 154       ds, ts
 155
 156 let rec match_names oi ni os ns =
 157   match os, ns with
 158   | _         , []        -> None
 159   | []        , _         -> None
 160   | (_,o)::otl,(_,n)::ntl ->
 161     let b = compare_names (snd o) n in
 162     if b > 0 then match_names oi (succ ni) os ntl else
 163     if b < 0 then match_names (succ oi) ni otl ns else
 164     Some (oi, ni)
 165
 166 let new_status = {
 167   ET.m = false; ET.r = []; ET.s = []; ET.t = []; ET.w = [];
 168 }
 169
 170 let string_of_pointer = string_of_version
 171
 172 let pointer_of_string = version_of_string
 173
 174 let list_visit before each visit after string_of p l =
 175   let ptr p = string_of_pointer (List.rev p) in
 176   let rec aux i = function
 177     | []         -> ()
 178     | (b, x)::tl ->
 179       each (ptr (i::p)) b (string_of x);
 180       visit (i::p) x;
 181       aux (succ i) tl
 182   in
 183   let s, c = list_count 0 0 l in
 184   let count = Printf.sprintf "%u/%u" s c in
 185   before (ptr p) count;
 186   aux 0 l;
 187   after ()
 188
 189 let string_of_error = function
 190   | ET.EWrongExt x         ->
 191     Printf.sprintf "unknown input file type %S" x
 192   | ET.EStage v            ->
 193     Printf.sprintf "current stage %S" (string_of_version v)
 194   | ET.ENoStage            ->
 195     Printf.sprintf "current stage not defined"
 196   | ET.EWaiting            ->
 197     Printf.sprintf "current stage not finished"
 198   | ET.ENameClash n        ->
 199     Printf.sprintf "name clash %S" (string_of_name n)
 200   | ET.EObjClash o         ->
 201     Printf.sprintf "object clash %S" (string_of_obj o)
 202   | ET.ERoleClash r        ->
 203     Printf.sprintf "role clash %S" (string_of_role r)
 204   | ET.ENoEntry            ->
 205     Printf.sprintf "entry not found"
 206   | ET.EWrongSelect        ->
 207     Printf.sprintf "selected role is not unique"
 208   | ET.EWrongVersion       ->
 209     Printf.sprintf "selected role is not in the current stage"
 210   | ET.ETops               ->
 211     Printf.sprintf "top objects already computed"
 212   | ET.EWrongRequest (r,a) ->
 213     Printf.sprintf "unknown request \"%s=%s\"" r a