matita/matita/contribs/lambdadelta/delayed_updating/etc/lift_k/lift.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/notation/functions/uparrow_4.ma".
  16 include "delayed_updating/notation/functions/uparrow_2.ma".
  17 include "delayed_updating/syntax/path.ma".
  18 include "ground/relocation/tr_uni.ma".
  19 include "ground/relocation/tr_pap_tls.ma".
  20
  21 (* LIFT FOR PATH ************************************************************)
  22
  23 definition lift_continuation (A:Type[0]) ≝
  24            tr_map → path → A.
  25
  26 rec definition lift_gen (A:Type[0]) (k:lift_continuation A) (f) (p) on p ≝
  27 match p with
  28 [ list_empty     ⇒ k f (𝐞)
  29 | list_lcons l q ⇒
  30   match l with
  31   [ label_d n ⇒ lift_gen (A) (λg,p. k g (𝗱(f＠⧣❨n❩)◗p)) (⇂*[n]f) q
  32   | label_m   ⇒ lift_gen (A) (λg,p. k g (𝗺◗p)) f q
  33   | label_L   ⇒ lift_gen (A) (λg,p. k g (𝗟◗p)) (⫯f) q
  34   | label_A   ⇒ lift_gen (A) (λg,p. k g (𝗔◗p)) f q
  35   | label_S   ⇒ lift_gen (A) (λg,p. k g (𝗦◗p)) f q
  36   ]
  37 ].
  38
  39 interpretation
  40   "lift (gneric)"
  41   'UpArrow A k f p = (lift_gen A k f p).
  42
  43 definition proj_path: lift_continuation … ≝
  44            λf,p.p.
  45
  46 definition proj_rmap: lift_continuation … ≝
  47            λf,p.f.
  48
  49 interpretation
  50   "lift (path)"
  51   'UpArrow f p = (lift_gen ? proj_path f p).
  52
  53 interpretation
  54   "lift (relocation map)"
  55   'UpArrow p f = (lift_gen ? proj_rmap f p).
  56
  57 (* Basic constructions ******************************************************)
  58
  59 lemma lift_empty (A) (k) (f):
  60       k f (𝐞) = ↑{A}❨k, f, 𝐞❩.
  61 // qed.
  62
  63 lemma lift_d_sn (A) (k) (p) (n) (f):
  64       ↑❨(λg,p. k g (𝗱(f＠⧣❨n❩)◗p)), ⇂*[n]f, p❩ = ↑{A}❨k, f, 𝗱n◗p❩.
  65 // qed.
  66
  67 lemma lift_m_sn (A) (k) (p) (f):
  68       ↑❨(λg,p. k g (𝗺◗p)), f, p❩ = ↑{A}❨k, f, 𝗺◗p❩.
  69 // qed.
  70
  71 lemma lift_L_sn (A) (k) (p) (f):
  72       ↑❨(λg,p. k g (𝗟◗p)), ⫯f, p❩ = ↑{A}❨k, f, 𝗟◗p❩.
  73 // qed.
  74
  75 lemma lift_A_sn (A) (k) (p) (f):
  76       ↑❨(λg,p. k g (𝗔◗p)), f, p❩ = ↑{A}❨k, f, 𝗔◗p❩.
  77 // qed.
  78
  79 lemma lift_S_sn (A) (k) (p) (f):
  80       ↑❨(λg,p. k g (𝗦◗p)), f, p❩ = ↑{A}❨k, f, 𝗦◗p❩.
  81 // qed.
  82
  83 (* Basic constructions with proj_path ***************************************)
  84
  85 lemma lift_path_empty (f):
  86       (𝐞) = ↑[f]𝐞.
  87 // qed.
  88
  89 (* Basic constructions with proj_rmap ***************************************)
  90
  91 lemma lift_rmap_empty (f):
  92       f = ↑[𝐞]f.
  93 // qed.
  94
  95 lemma lift_rmap_d_sn (f) (p) (n):
  96       ↑[p](⇂*[ninj n]f) = ↑[𝗱n◗p]f.
  97 // qed.
  98
  99 lemma lift_rmap_m_sn (f) (p):
 100       ↑[p]f = ↑[𝗺◗p]f.
 101 // qed.
 102
 103 lemma lift_rmap_L_sn (f) (p):
 104       ↑[p](⫯f) = ↑[𝗟◗p]f.
 105 // qed.
 106
 107 lemma lift_rmap_A_sn (f) (p):
 108       ↑[p]f = ↑[𝗔◗p]f.
 109 // qed.
 110
 111 lemma lift_rmap_S_sn (f) (p):
 112       ↑[p]f = ↑[𝗦◗p]f.
 113 // qed.
 114
 115 (* Advanced constructions with proj_rmap and path_append ********************)
 116
 117 lemma lift_rmap_append (p2) (p1) (f):
 118       ↑[p2]↑[p1]f = ↑[p1●p2]f.
 119 #p2 #p1 elim p1 -p1 // * [ #n ] #p1 #IH #f //
 120 [ <lift_rmap_m_sn <lift_rmap_m_sn //
 121 | <lift_rmap_A_sn <lift_rmap_A_sn //
 122 | <lift_rmap_S_sn <lift_rmap_S_sn //
 123 ]
 124 qed.
 125
 126 (* Advanced constructions with proj_rmap and path_rcons *********************)
 127
 128 lemma lift_rmap_d_dx (f) (p) (n):
 129       ⇂*[ninj n](↑[p]f) = ↑[p◖𝗱n]f.
 130 // qed.
 131
 132 lemma lift_rmap_m_dx (f) (p):
 133       ↑[p]f = ↑[p◖𝗺]f.
 134 // qed.
 135
 136 lemma lift_rmap_L_dx (f) (p):
 137       (⫯↑[p]f) = ↑[p◖𝗟]f.
 138 // qed.
 139
 140 lemma lift_rmap_A_dx (f) (p):
 141       ↑[p]f = ↑[p◖𝗔]f.
 142 // qed.
 143
 144 lemma lift_rmap_S_dx (f) (p):
 145       ↑[p]f = ↑[p◖𝗦]f.
 146 // qed.
 147
 148 lemma lift_rmap_pap_d_dx (f) (p) (n) (m):
 149       ↑[p]f＠⧣❨m+n❩ = ↑[p◖𝗱n]f＠⧣❨m❩+↑[p]f＠⧣❨n❩.
 150 // qed.