matita/matita/contribs/lambdadelta/delayed_updating/reduction/dbfr_ibfr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/dbfr.ma".
  16 include "delayed_updating/reduction/ibfr.ma".
  17
  18 include "delayed_updating/unwind/unwind2_constructors.ma".
  19 include "delayed_updating/unwind/unwind2_preterm_fsubst.ma".
  20 include "delayed_updating/unwind/unwind2_preterm_eq.ma".
  21 include "delayed_updating/unwind/unwind2_prototerm_lift.ma".
  22 include "delayed_updating/unwind/unwind2_rmap_head.ma".
  23
  24 include "delayed_updating/substitution/fsubst_eq.ma".
  25 include "delayed_updating/substitution/lift_prototerm_eq.ma".
  26
  27 include "delayed_updating/syntax/prototerm_proper_constructors.ma".
  28 include "delayed_updating/syntax/path_head_structure.ma".
  29 include "delayed_updating/syntax/path_structure_depth.ma".
  30
  31 (* DELAYED BALANCED FOCUSED REDUCTION ***************************************)
  32
  33 (* Main destructions with ibfr **********************************************)
  34
  35 theorem dbfr_des_ibfr (f) (t1) (t2) (r): t1 ϵ 𝐓 →
  36         t1 ➡𝐝𝐛𝐟[r] t2 → ▼[f]t1 ➡𝐢𝐛𝐟[⊗r] ▼[f]t2.
  37 #f #t1 #t2 #r #H0t1
  38 * #p #b #q #h #k #Hr #Hb #Hh #H1k #Ht1 #Ht2 destruct
  39 @(ex6_5_intro … (⊗p) (⊗b) (⊗q) (♭b) (↑♭q))
  40 [ -H0t1 -Hb -Hh -H1k -Ht1 -Ht2 //
  41 | -H0t1 -Hh -H1k -Ht1 -Ht2 //
  42 | -H0t1 -Hb -Ht1 -H1k -Ht2
  43   >Hh in ⊢ (??%?); >path_head_structure_depth <Hh -Hh //
  44 | -H0t1 -Hb -Hh -Ht1 -Ht2
  45   >structure_L_sn
  46   >H1k in ⊢ (??%?); >path_head_structure_depth <H1k -H1k //
  47 | lapply (in_comp_unwind2_path_term f … Ht1) -Ht2 -Ht1 -H0t1 -Hb -Hh
  48   <unwind2_path_d_dx >list_append_rcons_dx >list_append_assoc
  49   lapply (unwind2_rmap_append_pap_closed f … (p●𝗔◗b) … H1k) -H1k
  50   <depth_L_sn #H2k
  51   lapply (eq_inv_ninj_bi … H2k) -H2k #H2k <H2k -H2k #Ht1 //
  52 | lapply (unwind2_term_eq_repl_dx f … Ht2) -Ht2 #Ht2
  53   lapply (path_head_refl_append_bi … Hh H1k) -Hh -H1k <nrplus_inj_sn #H1k
  54   @(subset_eq_trans … Ht2) -t2
  55   @(subset_eq_trans … (unwind2_term_fsubst_ppc …))
  56   [ @fsubst_eq_repl [ // | // ]
  57     @(subset_eq_trans … (unwind2_term_iref …))
  58     @(subset_eq_canc_sn … (lift_term_eq_repl_dx …))
  59     [ @unwind2_term_grafted_S /2 width=2 by ex_intro/ | skip ] -Ht1
  60     @(subset_eq_trans … (lift_unwind2_term_after …))
  61     @unwind2_term_eq_repl_sn
  62 (* Note: crux of the proof begins *)
  63     <list_append_rcons_sn
  64     @(stream_eq_trans … (tr_compose_uni_dx …))
  65     @tr_compose_eq_repl
  66     [ <unwind2_rmap_append_pap_closed //
  67       <depth_append <depth_L_sn
  68       <nplus_comm <nrplus_npsucc_sn <nplus_succ_sn //
  69     | >unwind2_rmap_A_dx
  70       /2 width=1 by tls_unwind2_rmap_closed/
  71     ]
  72 (* Note: crux of the proof ends *)
  73   | //
  74   | /2 width=2 by ex_intro/
  75   | //
  76   ]
  77 ]
  78 qed.