matita/matita/contribs/lambdadelta/delayed_updating/reduction/dbfr_ibfr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/dbfr.ma".
  16 include "delayed_updating/reduction/ibfr_unwind.ma".
  17
  18 include "delayed_updating/unwind/unwind2_prototerm_constructors.ma".
  19
  20 include "delayed_updating/syntax/prototerm_proper_constructors.ma".
  21
  22 (* DELAYED BALANCED FOCUSED REDUCTION ***************************************)
  23
  24 (* Main destructions with ibfr **********************************************)
  25
  26 theorem dbfr_des_ibfr_push (f) (t1) (t2) (r): t1 ϵ 𝐓 →
  27         t1 ➡𝐝𝐛𝐟[r] t2 → ▼[⫯f]t1 ➡𝐢𝐛𝐟[⊗r] ▼[⫯f]t2.
  28 #f #t1 #t2 #r #H0t1
  29 * #p #b #q #m #n #Hr #Hp #Hb #Hm #Hn #Ht1 #Ht2 destruct
  30 @(ex7_5_intro … (⊗p) (⊗b) (⊗q) (♭b) (♭q))
  31 [ -H0t1 -Hp -Hb -Hm -Hn -Ht1 -Ht2 //
  32 | -H0t1 -Hb -Hm -Hn -Ht1 -Ht2 /2 width=1 by path_guard_structure/
  33 | -H0t1 -Hp -Hm -Hn -Ht1 -Ht2 //
  34 | -H0t1 -Hp -Hb -Hn -Ht1 -Ht2
  35   /2 width=2 by path_closed_structure_depth/
  36 | -H0t1 -Hp -Hb -Hm -Ht1 -Ht2
  37   /2 width=2 by path_closed_structure_depth/
  38 | lapply (in_comp_unwind2_path_term (⫯f) … Ht1) -H0t1 -Hp -Hb -Hm -Ht2 -Ht1
  39   <unwind2_path_d_dx <tr_pap_succ_nap >list_append_rcons_dx >list_append_assoc
  40   <nap_unwind2_rmap_append_closed_Lq_dx //
  41 | lapply (unwind2_term_eq_repl_dx (⫯f) … Ht2) -Ht2 #Ht2
  42   @(subset_eq_trans … Ht2) -t2
  43   @(subset_eq_trans … (unwind2_term_fsubst_ppc …))
  44   [ @fsubst_eq_repl [ // | // ]
  45     @(subset_eq_trans … (unwind2_term_iref …))
  46     @(subset_eq_canc_sn … (lift_term_eq_repl_dx …))
  47     [ @unwind2_term_grafted_S /2 width=2 by ex_intro/ | skip ] -Ht1
  48     @(subset_eq_trans … (lift_unwind2_term_after …))
  49     @unwind2_term_eq_repl_sn
  50 (* Note: crux of the proof begins *)
  51     /2 width=1 by unwind2_rmap_uni_crux/
  52 (* Note: crux of the proof ends *)
  53   | //
  54   | /2 width=2 by ex_intro/
  55   | //
  56   ]
  57 ]
  58 qed-.
  59
  60 theorem dbfr_des_ibfr (f) (t1) (t2) (r): t1 ϵ 𝐓 →
  61         t1 ➡𝐝𝐛𝐟[r] t2 → ▼[f]t1 ➡𝐢𝐛𝐟[⊗r] ▼[f]t2.
  62 #f #t1 #t2 #r #Ht1 #Ht12
  63 lapply (dbfr_des_ibfr_push (𝐢) … Ht1 Ht12) -Ht1 -Ht12 #Ht12
  64 /2 width=1 by ibfr_structure_unwind_bi/
  65 qed.