matita/matita/contribs/lambdadelta/delayed_updating/reduction/dbfr_ibfr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/dbfr.ma".
  16 include "delayed_updating/reduction/ibfr.ma".
  17
  18 include "delayed_updating/unwind/unwind2_constructors.ma".
  19 include "delayed_updating/unwind/unwind2_preterm_fsubst.ma".
  20 include "delayed_updating/unwind/unwind2_preterm_eq.ma".
  21 include "delayed_updating/unwind/unwind2_prototerm_lift.ma".
  22 include "delayed_updating/unwind/unwind2_rmap_closed.ma".
  23
  24 include "delayed_updating/substitution/fsubst_eq.ma".
  25 include "delayed_updating/substitution/lift_prototerm_eq.ma".
  26
  27 include "delayed_updating/syntax/prototerm_proper_constructors.ma".
  28 include "delayed_updating/syntax/path_closed_structure.ma".
  29 include "delayed_updating/syntax/path_structure_depth.ma".
  30
  31 (* DELAYED BALANCED FOCUSED REDUCTION ***************************************)
  32
  33 (* Main destructions with ibfr **********************************************)
  34
  35 theorem dbfr_des_ibfr (f) (t1) (t2) (r): t1 ϵ 𝐓 →
  36         t1 ➡𝐝𝐛𝐟[r] t2 → ▼[f]t1 ➡𝐢𝐛𝐟[⊗r] ▼[f]t2.
  37 #f #t1 #t2 #r #H0t1
  38 * #p #b #q #m #n #Hr #Hb #Hm #Hn #Ht1 #Ht2 destruct
  39 @(ex6_5_intro … (⊗p) (⊗b) (⊗q) (♭b) (♭q))
  40 [ -H0t1 -Hb -Hm -Hn -Ht1 -Ht2 //
  41 | -H0t1 -Hm -Hn -Ht1 -Ht2 //
  42 | -H0t1 -Hb -Hn -Ht1 -Ht2
  43   /2 width=2 by path_closed_structure_depth/
  44 | -H0t1 -Hb -Hm -Ht1 -Ht2
  45   /2 width=2 by path_closed_structure_depth/
  46 | lapply (in_comp_unwind2_path_term f … Ht1) -H0t1 -Hb -Hm -Ht2 -Ht1
  47   <unwind2_path_d_dx <tr_pap_succ_nap >list_append_rcons_dx >list_append_assoc
  48   <nap_unwind2_rmap_append_closed_Lq_dx_depth //
  49 | lapply (unwind2_term_eq_repl_dx f … Ht2) -Ht2 #Ht2
  50   @(subset_eq_trans … Ht2) -t2
  51   @(subset_eq_trans … (unwind2_term_fsubst_ppc …))
  52   [ @fsubst_eq_repl [ // | // ]
  53     @(subset_eq_trans … (unwind2_term_iref …))
  54     @(subset_eq_canc_sn … (lift_term_eq_repl_dx …))
  55     [ @unwind2_term_grafted_S /2 width=2 by ex_intro/ | skip ] -Ht1
  56     @(subset_eq_trans … (lift_unwind2_term_after …))
  57     @unwind2_term_eq_repl_sn
  58 (* Note: crux of the proof begins *)
  59     <list_append_rcons_sn
  60     @(stream_eq_trans … (tr_compose_uni_dx_pap …)) <tr_pap_succ_nap
  61     @tr_compose_eq_repl
  62     [ <nap_plus_unwind2_rmap_append_closed_bLq_dx_depth //
  63     | >unwind2_rmap_A_dx
  64       /2 width=2 by tls_succ_plus_unwind2_rmap_append_closed_bLq_dx/
  65     ]
  66 (* Note: crux of the proof ends *)
  67   | //
  68   | /2 width=2 by ex_intro/
  69   | //
  70   ]
  71 ]
  72 qed.