matita/matita/contribs/lambdadelta/delayed_updating/reduction/dbfr_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/dbfr.ma".
  16
  17 include "delayed_updating/substitution/fsubst_lift.ma".
  18 include "delayed_updating/substitution/fsubst_eq.ma".
  19 include "delayed_updating/substitution/lift_constructors.ma".
  20 include "delayed_updating/substitution/lift_path_head.ma".
  21 include "delayed_updating/substitution/lift_rmap_head.ma".
  22
  23 (* DELAYED BALANCED FOCUSED REDUCTION ***************************************)
  24
  25 (* Constructions with lift **************************************************)
  26
  27 theorem dfr_lift_bi (f) (t1) (t2) (r):
  28         t1 ➡𝐝𝐛𝐟[r] t2 → ↑[f]t1 ➡𝐝𝐛𝐟[↑[f]r] ↑[f]t2.
  29 #f #t1 #t2 #r
  30 * #p #q #k #Hr #H1k #Ht1 #Ht2 destruct
  31 @(ex4_3_intro … (↑[f]p) (↑[↑[p◖𝗔◖𝗟]f]q) ((↑[p●𝗔◗𝗟◗q]f)＠⧣❨k❩))
  32 [ -H1k -Ht1 -Ht2 //
  33 | -Ht1 -Ht2
  34   <lift_rmap_L_dx >lift_path_L_sn
  35   <(lift_path_head_closed … H1k) in ⊢ (??%?); -H1k //
  36 | lapply (in_comp_lift_path_term f … Ht1) -Ht2 -Ht1 -H1k
  37   <lift_path_d_dx #Ht1 //
  38 | lapply (lift_term_eq_repl_dx f … Ht2) -Ht2 #Ht2 -Ht1
  39   @(subset_eq_trans … Ht2) -t2
  40   @(subset_eq_trans … (lift_term_fsubst …))
  41   @fsubst_eq_repl [ // | // ]
  42   @(subset_eq_trans … (lift_term_iref …))
  43   @iref_eq_repl
  44   @(subset_eq_canc_sn … (lift_term_grafted_S …))
  45   @lift_term_eq_repl_sn
  46 (* Note: crux of the proof begins *)
  47   >list_append_rcons_sn in H1k; #H1k >lift_rmap_A_dx
  48   /2 width=1 by tls_lift_rmap_closed/
  49 (* Note: crux of the proof ends *)
  50 ]
  51 qed.