matita/matita/contribs/lambdadelta/delayed_updating/reduction/dbfr_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/dbfr.ma".
  16
  17 include "delayed_updating/substitution/fsubst_lift.ma".
  18 include "delayed_updating/substitution/fsubst_eq.ma".
  19 include "delayed_updating/substitution/lift_constructors.ma".
  20 include "delayed_updating/substitution/lift_path_structure.ma".
  21 include "delayed_updating/substitution/lift_path_closed.ma".
  22 include "delayed_updating/substitution/lift_rmap_closed.ma".
  23
  24 (* DELAYED BALANCED FOCUSED REDUCTION ***************************************)
  25
  26 (* Constructions with lift **************************************************)
  27
  28 theorem dbfr_lift_bi (f) (t1) (t2) (r):
  29         t1 ➡𝐝𝐛𝐟[r] t2 → 🠡[f]t1 ➡𝐝𝐛𝐟[🠡[f]r] 🠡[f]t2.
  30 #f #t1 #t2 #r
  31 * #p #b #q #m #n #Hr #Hb #Hm #Hn #Ht1 #Ht2 destruct
  32 @(ex6_5_intro … (🠡[f]p) (🠡[🠢[f](p◖𝗔)]b) (🠡[🠢[f](p◖𝗔●b◖𝗟)]q) (🠢[f](p●𝗔◗b)＠❨m❩) (🠢[f](p●𝗔◗b●𝗟◗q)＠§❨n❩))
  33 [ -Hb -Hm -Hn -Ht1 -Ht2 //
  34 | -Hm -Hn -Ht1 -Ht2 //
  35 | -Hb -Hn -Ht1 -Ht2
  36   /2 width=1 by lift_path_closed/
  37 | -Hb -Hm -Ht1 -Ht2
  38   /2 width=1 by lift_path_rmap_closed_L/
  39 | lapply (in_comp_lift_path_term f … Ht1) -Ht2 -Ht1 -Hn
  40   <lift_path_d_dx #Ht1 //
  41 | lapply (lift_term_eq_repl_dx f … Ht2) -Ht2 #Ht2 -Ht1
  42   @(subset_eq_trans … Ht2) -t2
  43   @(subset_eq_trans … (lift_term_fsubst …))
  44   @fsubst_eq_repl [ // | // ]
  45   @(subset_eq_trans … (lift_term_iref_nap …))
  46   <list_append_rcons_sn <list_append_rcons_sn >list_append_assoc
  47   >(nap_plus_lift_rmap_append_closed_Lq_dx … Hn)
  48   @iref_eq_repl
  49   @(subset_eq_canc_sn … (lift_term_grafted_S …))
  50   @lift_term_eq_repl_sn
  51 (* Note: crux of the proof begins *)
  52   >lift_rmap_A_dx
  53   /2 width=2 by tls_succ_plus_lift_rmap_append_closed_bLq_dx/
  54 (* Note: crux of the proof ends *)
  55 ]
  56 qed.