matita/matita/contribs/lambdadelta/delayed_updating/reduction/dfr_ifr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/dfr.ma".
  16 include "delayed_updating/reduction/ifr.ma".
  17
  18 include "delayed_updating/unwind/unwind2_constructors.ma".
  19 include "delayed_updating/unwind/unwind2_preterm_fsubst.ma".
  20 include "delayed_updating/unwind/unwind2_preterm_eq.ma".
  21 include "delayed_updating/unwind/unwind2_prototerm_lift.ma".
  22 include "delayed_updating/unwind/unwind2_rmap_head.ma".
  23
  24 include "delayed_updating/substitution/fsubst_eq.ma".
  25 include "delayed_updating/substitution/lift_prototerm_eq.ma".
  26
  27 include "delayed_updating/syntax/prototerm_proper_constructors.ma".
  28 include "delayed_updating/syntax/path_head_structure.ma".
  29 include "delayed_updating/syntax/path_structure_depth.ma".
  30
  31 (* DELAYED FOCUSED REDUCTION ************************************************)
  32
  33 (* Main destructions with ifr ***********************************************)
  34
  35 theorem dfr_des_ifr (f) (t1) (t2) (r): t1 ϵ 𝐓 →
  36         t1 ➡𝐝𝐟[r] t2 → ▼[f]t1 ➡𝐢𝐟[⊗r] ▼[f]t2.
  37 #f #t1 #t2 #r #H0t1
  38 * #p #q #k #Hr #H1k #Ht1 #Ht2 destruct
  39 @(ex4_3_intro … (⊗p) (⊗q) (↑♭q))
  40 [ -H0t1 -H1k -Ht1 -Ht2 //
  41 | -H0t1 -Ht1 -Ht2
  42   >structure_L_sn
  43   >H1k in ⊢ (??%?); >path_head_structure_depth <H1k -H1k //
  44 | lapply (in_comp_unwind2_path_term f … Ht1) -Ht2 -Ht1 -H0t1
  45   <unwind2_path_d_dx <list_append_rcons_sn
  46   lapply (unwind2_rmap_append_pap_closed f … (p◖𝗔) … H1k) -H1k
  47   <depth_L_sn #H2k
  48   lapply (eq_inv_ninj_bi … H2k) -H2k #H2k <H2k -H2k #Ht1 //
  49 | lapply (unwind2_term_eq_repl_dx f … Ht2) -Ht2 #Ht2
  50   @(subset_eq_trans … Ht2) -t2
  51   @(subset_eq_trans … (unwind2_term_fsubst_ppc …))
  52   [ @fsubst_eq_repl [ // | // ]
  53     @(subset_eq_trans … (unwind2_term_iref …))
  54     @(subset_eq_canc_sn … (lift_term_eq_repl_dx …))
  55     [ @unwind2_term_grafted_S /2 width=2 by ex_intro/ | skip ] -Ht1
  56     @(subset_eq_trans … (lift_unwind2_term_after …))
  57     @unwind2_term_eq_repl_sn
  58 (* Note: crux of the proof begins *)
  59     <list_append_rcons_sn
  60     @(stream_eq_trans … (tr_compose_uni_dx …))
  61     @tr_compose_eq_repl
  62     [ <unwind2_rmap_append_pap_closed //
  63     | >unwind2_rmap_A_dx
  64       /2 width=1 by tls_unwind2_rmap_closed/
  65     ]
  66 (* Note: crux of the proof ends *)
  67   | //
  68   | /2 width=2 by ex_intro/
  69   | //
  70   ]
  71 ]
  72 qed.